Использование Automator или Applescript или обоих для рекурсивной печати документов в PDF

Попробуй это:

set appleworksFolder to choose folder
set thePath to POSIX path of appleworksFolder as string

tell application "Finder"
set folderItems to files of appleworksFolder
repeat with aFile in folderItems
    set {name:fileName, name extension:nameExtension} to aFile
    set filePath to POSIX path of (aFile as alias) as string

    if nameExtension is not "txt" then
        set theLocation to POSIX path of (aFile as text)
        set baseName to text 1 thru ((get offset of "." & nameExtension in fileName) - 1) of fileName
        set destLocation to (thePath & baseName & ".pdf")
        set theCommand to "/System/Library/Printers/Libraries/./convert -f \"" & filePath & "\"" & " -o " & "\"" & destLocation & "\"" & " -j \"application/pdf\""
        do shell script theCommand

    else
        tell application "Finder" to delete aFile
    end if
end repeat
end tell

Конвертировать с помощью страниц

Если у вас есть Pages (часть iWork), он может открывать файлы .cwk и сохранять их как PDF: просто замените свой if блок следующим:

if (the_doc's name extension is not "txt") then
    set newName to my makeNewFileName(the_doc, "pdf")
    try
        tell application "Pages"
            open (the_doc as alias)
            set thisDoc to front document
            save thisDoc as "SLDocumentTypePDF" in newName
            close thisDoc saving no
        end tell
    on error
        display dialog "Error: cannot export " & (name of the_doc) & " to PDF."
    end try
end if

(вам понадобится эта настраиваемая функция makeNewFileName):

(* prepare new file name with extension ext *)
on makeNewFileName(finderItem, ext)
    tell application "Finder"
        set fname to finderItem's name
        set thePath to (finderItem's container) as alias as text
        return (thePath & (text 1 thru ((length of fname) - (length of (finderItem's name extension as text))) of fname) & ext)
    end tell
end makeNewFileName

(полный рабочий сценарий)

Создание сценариев графического интерфейса пользователя

В качестве альтернативы вы можете создавать сценарии графического интерфейса пользователя для AppleWorks, как вы пытались, но это имеет недостаток, заключающийся в том, что вы не можете программно указать, где сохранить файл PDF.

Этот фрагмент работает для меня:

tell application "AppleWorks 6"
    open the_doc
    activate

    tell application "System Events" to tell process "AppleWorks"
        keystroke "p" using command down
        delay 1 -- or longer, if it takes longer
        click menu button "PDF" of window "Print"
        click menu item "Save as PDF…" of menu 1 of menu button "PDF" of window "Print"
        delay 1 -- or longer
        click button "Save" of window "Save"
    end tell
end tell

К сожалению, AppleWorks, похоже, неправильно слушает команду AppleScript close, поэтому вам может потребоваться закрыть файл, также имитируя нажатия клавиш cmd + W.

Мне нужно было сделать это сегодня на Mountain Lion с кучей чеков в формате RTF; вот как я это сделал:

#!/bin/bash
for file in *.rtf ; do
filename=$(basename "$file")
/usr/sbin/cupsfilter "$file" > "$filename.pdf"
done

Сработал отлично; супер просто. Никакой глупости Automator или AppleScript.