Скопируйте свойства класса Groovy

Я думаю, что ваше решение неплохое и находится в правильном направлении. По крайней мере, мне это вполне понятно.

Более лаконичная версия этого решения могла бы быть ...

def copyProperties(source, target) {
    source.properties.each { key, value ->
        if (target.hasProperty(key) && !(key in ['class', 'metaClass'])) 
            target[key] = value
    }
}

... но принципиально не отличается. Я перебираю исходные свойства, чтобы затем использовать значения для назначения цели :). Однако оно может быть менее надежным, чем ваше исходное решение, поскольку я думаю, что оно сломается, если целевой объект определит метод getAt(String).

Если вы хотите пофантазировать, вы можете сделать что-то вроде этого:

def copyProperties(source, target) {
    def (sProps, tProps) = [source, target]*.properties*.keySet()
    def commonProps = sProps.intersect(tProps) - ['class', 'metaClass']
    commonProps.each { target[it] = source[it] }
}

По сути, он сначала вычисляет общие свойства двух объектов, а затем копирует их. Это тоже работает, но я думаю, что первый более простой и понятный :)

Иногда лучше меньше, да лучше.

Я думаю, лучший и понятный способ - использовать метод InvokerHelper.setProperties.

Пример:

import groovy.transform.ToString
import org.codehaus.groovy.runtime.InvokerHelper

@ToString
class User {
    String name = 'Arturo'
    String city = 'Madrid'
    Integer age = 27
}

@ToString
class AdminUser {
    String name
    String city
    Integer age
}

def user = new User()
def adminUser = new AdminUser()

println "before: $user $adminUser"
InvokerHelper.setProperties(adminUser, user.properties)
println "after : $user $adminUser"

Вывод:

before: User(Arturo, Madrid, 27) AdminUser(null, null, null)
after : User(Arturo, Madrid, 27) AdminUser(Arturo, Madrid, 27)

Примечание. Если вам нужна более удобная читаемость, вы можете использовать категорию

use(InvokerHelper) {
    adminUser.setProperties(user.properties) 
}

Другой способ сделать:

def copyProperties( source, target ) {
  [source,target]*.getClass().declaredFields*.grep { !it.synthetic }.name.with { a, b ->
    a.intersect( b ).each {
      target."$it" = source."$it"
    }
  }
}

Которая получает общие свойства (которые не являются синтетическими полями), а затем назначает их целевому объекту.

Вы также можете (используя этот метод) сделать что-то вроде:

def user = new User()

def propCopy( src, clazz ) {
  [src.getClass(), clazz].declaredFields*.grep { !it.synthetic }.name.with { a, b ->
    clazz.newInstance().with { tgt ->
      a.intersect( b ).each {
        tgt[ it ] = src[ it ]
      }
      tgt
    }
  }
}


def admin = propCopy( user, AdminUser )
assert admin.name == 'Arturo'
assert admin.city == 'Madrid'
assert admin.age == 27

Таким образом, вы передаете методу объект, из которого нужно скопировать свойства, и класс возвращаемого объекта. Затем метод создает новый экземпляр этого класса (при условии, что конструктор без аргументов), устанавливает свойства и возвращает его.

Редактировать 2

Предполагая, что это классы Groovy, вы можете вызвать конструктор Map и установить все общие свойства следующим образом:

def propCopy( src, clazz ) {
  [src.getClass(), clazz].declaredFields*.grep { !it.synthetic }.name.with { a, b ->
    clazz.metaClass.invokeConstructor( a.intersect( b ).collectEntries { [ (it):src[ it ] ] } )
  }
}

Spring BeanUtils.copyProperties будет работать, даже если исходный / целевой классы относятся к разным типам. http://docs.spring.io/autorepo/docs/spring/3.2.3.RELEASE/javadoc-api/org/springframework/beans/BeanUtils.html