Как получить трассировку стека из обработанного / перехваченного исключения и записать ее в журнал трассировки

Чтобы регистрировать как перехваченные, так и неперехваченные исключения с помощью JEDI JCL, вы должны установить JEDI JCL.

Затем попробуйте какой-нибудь код, подобный этому коду, взятому из jcl\examples\windows\debug\framestrack\FramesTrackDemoMain.pas:

Вы должны компилировать с полной информацией об отладке как в параметрах компилятора, так и в параметрах компоновщика в параметрах проекта delphi, чтобы это сработало.

Обратите внимание, что вам не нужно вызывать LogException, оно вызывается автоматически после того, как вы добавили обратный вызов уведомителя об исключении (JclAddExceptNotifier). не забудьте также вызвать JclRemoveExceptNotifier, когда форма или модуль данных, из которого вы его добавляете, уничтожается, как показано здесь:

procedure TForm1.LogException(ExceptObj: TObject; ExceptAddr: Pointer; IsOS: Boolean);
var
  TmpS: string;
  ModInfo: TJclLocationInfo;
  I: Integer;
  ExceptionHandled: Boolean;
  HandlerLocation: Pointer;
  ExceptFrame: TJclExceptFrame;

begin
  TmpS := 'Exception ' + ExceptObj.ClassName;
  if ExceptObj is Exception then
    TmpS := TmpS + ': ' + Exception(ExceptObj).Message;
  if IsOS then
    TmpS := TmpS + ' (OS Exception)';
  mmLog.Lines.Add(TmpS);
  ModInfo := GetLocationInfo(ExceptAddr);
  mmLog.Lines.Add(Format(
    '  Exception occured at $%p (Module "%s", Procedure "%s", Unit "%s", Line %d)',
    [ModInfo.Address,
     ModInfo.UnitName,
     ModInfo.ProcedureName,
     ModInfo.SourceName,
     ModInfo.LineNumber]));
  if stExceptFrame in JclStackTrackingOptions then
  begin
    mmLog.Lines.Add('  Except frame-dump:');
    I := 0;
    ExceptionHandled := False;
    while (chkShowAllFrames.Checked or not ExceptionHandled) and
      (I < JclLastExceptFrameList.Count) do
    begin
      ExceptFrame := JclLastExceptFrameList.Items[I];
      ExceptionHandled := ExceptFrame.HandlerInfo(ExceptObj, HandlerLocation);
      if (ExceptFrame.FrameKind = efkFinally) or
          (ExceptFrame.FrameKind = efkUnknown) or
          not ExceptionHandled then
        HandlerLocation := ExceptFrame.CodeLocation;
      ModInfo := GetLocationInfo(HandlerLocation);
      TmpS := Format(
        '    Frame at $%p (type: %s',
        [ExceptFrame.ExcFrame,
         GetEnumName(TypeInfo(TExceptFrameKind), Ord(ExceptFrame.FrameKind))]);
      if ExceptionHandled then
        TmpS := TmpS + ', handles exception)'
      else
        TmpS := TmpS + ')';
      mmLog.Lines.Add(TmpS);
      if ExceptionHandled then
        mmLog.Lines.Add(Format(
          '      Handler at $%p',
          [HandlerLocation]))
      else
        mmLog.Lines.Add(Format(
          '      Code at $%p',
          [HandlerLocation]));
      mmLog.Lines.Add(Format(
        '      Module "%s", Procedure "%s", Unit "%s", Line %d',
        [ModInfo.UnitName,
         ModInfo.ProcedureName,
         ModInfo.SourceName,
         ModInfo.LineNumber]));
      Inc(I);
    end;
  end;
  mmLog.Lines.Add('');
end;


procedure TForm1.FormCreate(Sender: TObject);
begin
  JclAddExceptNotifier(Form1.LogException);
end;

procedure TForm1.FormDestroy(Sender: TObject);
begin
  JclRemoveExceptNotifier(Form1.LogException);
end;

Это обычный код инициализации:

initialization

  JclStackTrackingOptions := JclStackTrackingOptions + [stExceptFrame];
  JclStartExceptionTracking;

Вот запущенная демонстрация JCL FramesTrackExample.dproj:

Для ваших целей измените код, который добавляет строку в TMemo.Lines, чтобы вместо этого записывать в файл журнала на диске. Если у вас уже есть система ведения журналов, это прекрасно, а если нет, рассмотрите вариант Log4D.

Каждый новый вызов веб-службы - это новый поток. Некоторые ресурсы могут быть выделены предыдущим потоком, когда поступает следующий вызов службы и новый поток пытается получить к ним доступ. Или некоторые ресурсы могут быть освобождены одним потоком, когда другой поток пытается их использовать. Вы должны использовать TCriticalSection, чтобы убедиться, что все ресурсы доступны только для одного потока. Также убедитесь, что TCriticalSection является глобальной переменной и доступна для всех экземпляров.