Рекурсия Prolog пропускает те же результаты

У вашей программы чистое ядро, или, говоря медицинским языком, чистое сердце, но оно переплетается с раковой тканью ввода/вывода! Таким образом, сделать это правильно очень сложно, если не невозможно. Например, в качестве незначительной ошибки ваша программа завершается сбоем для kevin. Но вы, вероятно, имели в виду, что это преуспеет. С другой стороны, у вас получится таинственный господин []! Кто это?

Так давайте же отделим чистое от нечистого!

Чистая часть вашей программы заключается в сопоставлении списка симптомов с возможными диагнозами. Ваше рабочее предположение состоит в том, что если есть один симптом, который является частью показаний к заболеванию, мы диагностируем это заболевание — просто для уверенности. Так почему бы не назвать это symptoms_diagnosis/2?

symptoms_diagnosis(Symptoms, Diagnosis) :-
   member(Symptom, Symptoms),
   disease(Diagnosis, Indications),
   member(Symptom, Indications).

?- symptoms_diagnosis([sore_throat,fatigue,tiredness,rash], Diagnosis).
Diagnosis = hiv ;
Diagnosis = pregnancy ;
Diagnosis = flu ;
Diagnosis = flu ;
Diagnosis = hiv ;
false.

Обратите внимание, что даже без дальнейших церемоний у нас есть менее избыточные решения, чем в вашей исходной программе. Так как же избавиться от оставшихся избыточных решений? Это делает трюк:

?- setof(t,symptoms_diagnosis([sore_throat,fatigue,tiredness,rash], Diagnosis),_).
Diagnosis = flu ;
Diagnosis = hiv ;
Diagnosis = pregnancy.

Поэтому всякий раз, когда вы получаете избыточные решения, просто обведите свою цель setof(t, ..., _). Вы можете использовать это всякий раз, когда ответы являются наземными ответами. То есть в ответе не осталось переменной.

Может быть, вы предпочитаете получить диагноз в виде собственного списка?

?- setof(Diagnosis,symptoms_diagnosis([sore_throat,fatigue,tiredness,rash],Diagnosis),Diagnoses).
Diagnoses = [flu, hiv, pregnancy].

Итак, теперь мы готовы к клинической больнице Принстон-Плейнсборо! Это всего лишь суеверие, если доктор Хаус не примет диагноз Пролога!

Что касается нечистой части, посмотрите на подход @Mog.

В качестве альтернативы вы можете написать:

disease(hiv,[sore_throat,headache,fever,rash]).
disease(pregnancy,[fatigue,vomiting,light_headedness,increased_waistline]).
disease(flu,[fatigue,fever,tiredness,nasal_discharge]).

diagnose(Name, Symptoms) :-
    findall(D, (disease(D, S), intersection(S, Symptoms, I), I \== []), MayGot),
    atomic_concat(Name, ' has/is ', Start),
    maplist(atomic_concat(Start), MayGot, Temp),
    maplist(writeln, Temp).

Но если вы пытаетесь изучить Пролог, это не очень хорошая идея, так как он более функционален и менее прологарен, думаю, я все равно упомяну об этой возможности!

Вы должны вспомнить, какие заболевания вы уже собрали при проверке симптомов. Вам необходимо собрать (агрегировать) заболевания в список и проверить, присутствует ли заболевание в списке, прежде чем добавлять его. Затем вы можете распечатать список в конце или распечатать каждое новое заболевание по мере его добавления в список.

Я бы реализовал это так:

diagnose(Name, Symptoms) :- diagnose0(Name, Symptoms, []).

diagnose0(Name, [], Diseases) :-
    print_diseases(Name, Diseases).
diagnose0(Name, [H|T], DIn) :-
    disease(Disease, Symptoms),
    member(H, Symptoms),
    % you may want to add a cut here to avoid choicepoints
    (
        member(Disease, DIn)
    ->
        diagnose0(Name, T, DIn)
    ;
        DOut = [Disease|DIn],
        diagnose0(Name, T, DOut)
    ).

print_diseases(_Name, []).
print_diseases(Name, [H|T]) :-
    write(Name), write(' has/is '), writeln(H),
    print_diseases(Name, T).

Факты disease/2 такие же, как в вашем коде.

Это дает:

?- diagnose(kevin, [sore_throat, fatigue, tiredness, rash]).
kevin has/is flu
kevin has/is pregnancy
kevin has/is hiv
Yes (0.00s cpu, solution 1, maybe more)

Следующим шагом, очевидно, будет найти способ выразить, что некоторые диагнозы представляют альтернативы для данного симптома, и сделать выбор между этими различными альтернативами. С симптомами, перечисленными в запросе, у Кевина должен быть грипп и ВИЧ, но я сомневаюсь, что беременность является правильным диагнозом для Кевина. Это связано с комментарием о разрезе, который я вставил во второй пункт diagnose/3: без разреза вы можете получить более одного решения, каждое из которых представляет другой набор заболеваний, соответствующих набору симптомов. Если вы добавите разрез, вы получите только первое решение (включая беременность). Второй раствор содержит только грипп и ВИЧ.

Кстати, member/2 — это встроенный предикат, поэтому вам не нужно определять свой собственный.