Как получить ранее неизвестный массив в качестве вывода функции в Фортране

Я надеюсь, что появится настоящий программист на Фортране, но в отсутствие лучшего совета я бы указал только форму, а не размер x(:), использовал временный массив temp(size(x)) и сделал вывод y allocatable. Затем после первого прохода allocate(y(j)) и скопируйте значения из временного массива. Но я не могу не подчеркнуть, что я не программист на Фортране, поэтому я не могу сказать, есть ли в языке расширяемый массив или существует ли библиотека для последнего.

program test
    implicit none
    integer:: x(10) = (/1,0,2,0,3,0,4,0,5,0/)
    print "(10I2.1)", select(x)

contains

    function select(x) result(y)
        implicit none
        integer, intent(in):: x(:) 
        integer:: i, j, temp(size(x))
        integer, allocatable:: y(:)

        j = 0
        do i = 1, size(x)
            if (x(i) /= 0) then
                j = j + 1
                temp(j) = x(i)
            endif
        enddo

        allocate(y(j))
        y = temp(:j)
    end function select

end program test

Редактировать:

Основываясь на ответе MSB, вот пересмотренная версия функции, которая увеличивает temp y при перераспределении. Как и раньше, он копирует результат в y в конце. Оказывается, мне не нужно явно выделять новый массив с окончательным размером. Вместо этого это можно сделать автоматически с присвоением.

    function select(x) result(y)
        implicit none
        integer, intent(in):: x(:) 
        integer:: i, j, dsize
        integer, allocatable:: temp(:), y(:)

        dsize = 0; allocate(y(0))

        j = 0
        do i = 1, size(x)
            if (x(i) /= 0) then
                j = j + 1

                if (j >= dsize) then         !grow y using temp
                    dsize = j + j / 8 + 8 
                    allocate(temp(dsize))
                    temp(:size(y)) = y
                    call move_alloc(temp, y) !temp gets deallocated
                endif

                y(j) = x(i)
            endif
        enddo
        y = y(:j)
    end function select

Вот пример функции Fortran, возвращающей массив переменной длины. Это функция Fortran 2003. В тестовом драйвере также используется автоматическое выделение памяти при назначении, еще одна функция Fortran 2003.

module my_subs

contains

function select(x) result(y)
    implicit none
    integer, dimension (:), intent (in) :: x
    integer, dimension (:), allocatable :: y
    integer :: i, j

    j = 0
    do i=1, size (x)
        if (x(i)/=0) j = j+1
    enddo

    allocate ( y (1:j) )

    j = 0
    do i=1, size (x)
        if (x(i)/=0) then
            j = j+1
            y(j) = x(i)
        endif
    enddo

    return

end function select

end module my_subs

program test

use my_subs

implicit none
integer, dimension (6) :: array = [ 5, 0, 3, 0, 6, 1 ]
integer, dimension (:), allocatable :: answer

answer = select (array)

write (*, *) size (array), size (answer)
write (*, *) array
write (*, *) answer

stop


end program test

Вот альтернативное решение, которое использует временный массив для «наращивания» выходного массива (возврат функции) по мере необходимости. Хотя два прохода через входной массив избегаются, требуются копии массива. Еще одна функция Fortran 2003, move_alloc, уменьшает количество необходимых копий. move_alloc также заботится о (пере)распределении выходного массива (здесь "y") и освобождении входного массива (здесь "temp"). Возможно, это более элегантно, но менее эффективно, поскольку используется несколько копий. Эта версия, вероятно, более образовательная, чем полезная. Версия @eryksun использует один проход и одну копию за счет создания полного размера временного массива.

function select(x) result(y)
    implicit none
    integer, dimension (:), intent (in) :: x
    integer, dimension (:), allocatable :: y, temp
    integer :: i, j

    j = 0
    do i=1, size (x)
        if (x(i)/=0) then
            j = j+1
            allocate (temp (1:j))
            if ( allocated (y) ) temp (1:j-1) = y
            call move_alloc (temp, y)
            y(j) = x(i)
        endif
    enddo

    return

end function select

Если пример в вашем вопросе действительно то, что вы хотите сделать, вы можете использовать встроенный пакет Fortran90:

program pack_example

implicit none

integer, dimension(6) :: x

x = (/ 1,0,2,0,0,3 /)

! you can also use other masks than 'x/=0'
write(*,*) pack(x, x/=0)

end program pack_example

Вывод программы-примера: 1 2 3