Как работает FOR в командном файле cmd?

Ни один из ответов на самом деле не работает. Мне удалось найти решение самостоятельно. Это немного хакерски, но это решает проблему для меня:

echo off
setlocal enableextensions
setlocal enabledelayedexpansion
set MAX_TRIES=100
set P=%PATH%
for /L %%a in (1, 1, %MAX_TRIES%) do (
  for /F "delims=;" %%g in ("!P!") do (
    echo %%g
    set P=!P:%%g;=!
    if "!P!" == "%%g" goto :eof
  )
)

Ой ! Я ненавижу программирование пакетных файлов!

Обновлено

Решение Марка проще, но оно не будет работать с путями, содержащими пробелы. Это немного измененная версия решения Марка.

echo off
setlocal enabledelayedexpansion
set NonBlankPath=%PATH: =#%
set TabbedPath=%NonBlankPath:;= %
for %%g in (%TabbedPath%) do (
  set GG=%%g
  echo !GG:#= !
)

Идея Марка была хорошей, но, возможно, он забыл, что в некоторых путях есть пробелы. Замена ';' с '" "' вместо этого разрезал бы все пути на строки в кавычках.

set _path="%PATH:;=" "%"
for %%p in (%_path%) do if not "%%~p"=="" echo %%~p

Итак, здесь отображаются ваши пути.

Команда FOR в cmd имеет утомительную кривую обучения, особенно потому, что переменные реагируют на операторы ()... вы можете назначать любые переменные, но вы не можете читать их обратно в (), если только вы не используете " setlocal ENABLEDELAYEDEXPANSION", и поэтому также используйте переменные с !! вместо %% (!_var!)

Я на данный момент исключительно скрипт с cmd, по работе пришлось всему этому учиться :)

Вы правильно поняли, но for /f предназначен для работы с многострочными файлами или командами, а не с отдельными строками.

В своей простейшей форме for похоже на for в Perl или foreach в любом другом языке. Вы передаете ему список токенов, и он перебирает их, каждый раз вызывая одну и ту же команду.

for %a in (hello world) do @echo %a

Расширения просто предоставляют автоматические способы построения списка токенов. Причина, по которой ваш текущий код ничего не дает, заключается в том, что ';' является символом конца строки (комментария) по умолчанию. Но даже если вы измените это, вам придется использовать %%g, %%h, %%i, ... для доступа к отдельным токенам, что сильно ограничит ваш командный файл.

Самое близкое, что вы можете получить к тому, что вы просите, это:

set TabbedPath=%PATH:;= %
for %%g in (%TabbedPath%) do echo %%g

Но это не удастся для путей в кавычках, содержащих точки с запятой.

По моему опыту, for /l и for /r хороши для расширения существующих команд, но в остальном for крайне ограничены. Вы можете сделать его немного более мощным (и запутанным) с помощью отложенного раскрытия переменных (cmd /v:on), но на самом деле это хорошо только для списков имен файлов.

Я бы предложил использовать WSH или PowerShell, если вам нужно выполнять манипуляции со строками. Если вы пытаетесь написать whereis для Windows, попробуйте where /?.

Не мог удержаться от того, чтобы выбросить это туда, старое, как этот поток... Обычно, когда возникает необходимость перебрать каждый из файлов в PATH, все, что вы действительно хотите сделать, это найти конкретный файл... Если это так , этот однострочник выдаст первый каталог, в котором он найдет ваш файл:

(например: поиск java.exe)

for %%x in (java.exe) do echo %%~dp$PATH:x

Я знаю, что это СУПЕР старое... но просто для удовольствия я решил попробовать:

@Echo OFF
setlocal
set testpath=%path: =#%
FOR /F "tokens=* delims=;" %%P in ("%testpath%") do call :loop %%P
:loop
if '%1'=='' goto endloop
set testpath=%1
set testpath=%testpath:#= %
echo %testpath%
SHIFT
goto :loop
:endloop
pause
endlocal
exit

Это не требует подсчета и будет продолжаться до тех пор, пока не закончится. У меня была такая же проблема с пробелами, но она прошла через всю переменную. Ключом к этому являются метки циклов и функция SHIFT.

for /f выполняет итерации для каждой строки ввода, поэтому в вашей программе будет выводиться только первый путь.

ваша программа обрабатывает %PATH% как однострочный ввод и отделяет ;, помещает первый результат в %%g, затем выводит %%g (первый разделенный путь).

FOR по существу перебирает «линии» в наборе данных. В этом случае есть одна строка, содержащая путь. "delims=;" просто говорит ему разделять точки с запятой. Если вы измените тело на echo %%g,%%h,%%i,%%j,%%k, вы увидите, что он обрабатывает ввод как одну строку и разбивает ее на несколько токенов.

Это работает для меня:

@ECHO OFF
SETLOCAL ENABLEDELAYEDEXPANSION ENABLEEXTENSIONS
@REM insure path is terminated with a ;
set tpath=%path%;
echo.
:again
@REM This FOR statement grabs the first element in the path
FOR /F "delims=;" %%I IN ("%TPATH%") DO (
  echo    %%I 
  @REM remove the current element of the path
  set TPATH=!TPATH:%%I;=!
)
@REM loop back if there is more to do. 
IF DEFINED TPATH GOTO :again

ENDLOCAL

Вы должны дополнительно использовать tokens=1,2,... часть опций, которые позволяет цикл for. Это здесь сделает то, что вы, возможно, хотите:

for /f "tokens=1,2,3,4,5,6,7,8,9,10,11,12 delims=;" %a in ("%PATH%") ^
do ( ^
     echo. %b ^
   & echo. %a ^
   & echo. %c ^
   & echo. %d ^
   & echo. %e ^
   & echo. %f ^
   & echo. %g ^
   & echo. %h ^
   & echo. %i ^
   & echo. %j ^
   & echo. %k ^
   & echo. ^
   & echo.   ...and now for some more... ^
   & echo. ^
   & echo. %a ^| %b ___ %c ... %d ^
   & dir "%e" ^
   & cd "%f" ^
   & dir /tw "%g" ^
   & echo. "%h  %i  %j  %k" ^
   & cacls "%f")

В этом примере обрабатываются только первые 12 токенов (=каталоги из %path%). Он использует явное перечисление каждого из используемых токенов. Обратите внимание, что имена токенов чувствительны к регистру: %a отличается от %A.

Чтобы избежать путей с пробелами, заключите все %x в кавычки, подобные этому "%i". Я не делал этого здесь, где я только повторяю токены.

Вы также можете сделать что-н. так:

for /f "tokens=1,3,5,7-26* delims=;" %a in ("%PATH%") ^
do ( ^
     echo. %c ^
   & echo. %b ^
   & echo. %a ^
   & echo. %d ^
   & echo. %e ^
   & echo. %f ^
   & echo. %g ^
   & echo. %h ^
   & echo. %i ^
   & echo. %j ^
   & echo. %k )

Он пропускает токены 2,4,6 и использует небольшое сокращение ("7-26") для обозначения остальных. Обратите внимание, как на этот раз %c, %b, %a обрабатываются в обратном порядке и как теперь они «означают» разные токены по сравнению с первым примером.

Так что это определенно не то краткое объяснение, которое вы просили. Но, возможно, примеры помогут прояснить ситуацию немного лучше...

Вот хорошее руководство:

FOR /F — команда цикла: для набора файлов.

FOR /F — Команда цикла: против результатов другой команды.

FOR - Команда цикла: все параметры Файлы, Каталог, Список.

[Все руководство (команды Windows XP):

http://www.ss64.com/nt/index.html

Редактировать: Извините, я не заметил, что ссылка уже была в OP, так как мне она показалась частью ссылки Amazon.

У меня работает, попробуй.

for /f "delims=;" %g in ('echo %PATH%') do echo %g%

У меня работает, попробуй.

for /f "токены=* разделители=;" %g in ('echo %PATH%') сделать echo %g%