Возможно, вы уже поняли, как применить ответ Алексея в предоставленной им ссылке. Но на случай, если у вас возникнут проблемы, я расскажу, как я применяю эту технику к 2D-графике.
Я обнаружил, что если вы хотите создать хороший график, вам нужно быть очень конкретным в Mathematica. По этой причине, как вы могли заметить в моем посте Растровые изображения в 3D, я создал объект, указывающий все параметры, чтобы Mathematica могла быть счастлива.
in = 72;
G2D = Graphics[{},
AlignmentPoint -> Center,
AspectRatio -> 1,
Axes -> False,
AxesLabel -> None,
BaseStyle -> {FontFamily -> "Arial", FontSize -> 12},
Frame -> True,
FrameStyle -> Directive[Black],
FrameTicksStyle -> Directive[10, Black],
ImagePadding -> {{20, 5}, {15, 5}},
ImageSize -> 5 in,
LabelStyle -> Directive[Black],
PlotRange -> All,
PlotRangeClipping -> False,
PlotRangePadding -> Scaled[0.02]
];
Я должен упомянуть здесь, что вы должны указать ImagePadding. Если вы установите значение all, ваш eps-файл будет отличаться от того, что показывает вам Mathematica. В любом случае, я думаю, что наличие этого объекта позволяет вам легко изменять свойства.
Теперь мы можем перейти к вашей проблеме:
plot = ListDensityPlot[
Table[Random[], {100}, {100}],
InterpolationOrder -> 0,
Options[G2D]
]
Следующее разделяет оси и растр и объединяет их в результат:
axes = Graphics[{}, AbsoluteOptions[plot]];
fig = Show[plot, FrameStyle -> Directive[Opacity[0]]];
fig = Magnify[fig, 5];
fig = Rasterize[fig, Background -> None];
axes = First@ImportString[ExportString[axes, "PDF"], "PDF"];
result = Show[axes, Epilog -> Inset[fig, {0, 0}, {0, 0}, ImageDimensions[axes]]]
Единственная разница здесь, которую я не могу объяснить на данный момент, это метки осей, они имеют десятичную точку. Наконец, мы экспортируем их:
Export["Result.pdf", result];
Export["Result.eps", result];
В результате получаются файлы размером 115 Кб для pdf-файла и 168 Кб для eps-файла.
ОБНОВИТЬ:
Если вы используете Mathematica 7, файл eps не будет корректно отображаться. Все, что вы увидите, это ваша основная фигура с черными сторонами. Это ошибка версии 7. Однако она исправлена в Mathematica 8.
Ранее я упоминал, что не знаю, почему маркировка осей была другой. Алексей Попков придумал это исправить. Чтобы создать axes, fig и result, используйте следующее:
axes = Graphics[{}, FilterRules[AbsoluteOptions[plot], Except[FrameTicks]]];
fig = Show[plot, FrameStyle -> Directive[Opacity[0]]];
fig = Magnify[fig, 5];
fig = Rasterize[fig, Background -> None];
axes = First@ImportString[ExportString[axes, "PDF"], "PDF"];
result = Show[axes, Epilog -> Inset[fig, {0, 0}, {0, 0}, ImageDimensions[axes]]]
person
jmlopez
schedule
01.11.2011
