Как избежать лишних отступов в цитатах декларации Template Haskell?

[моя программа] просматривает объявления имен переменных, которые начинаются с prop_, и создает набор тестов, содержащий их. Есть ли какой-то другой чистый способ Haskell, который я мог бы сделать вместо этого, без прямого изменения исходных файлов?

Да, есть! Использование language-haskell-extract пакет.

{-# LANGUAGE TemplateHaskell #-}

import Language.Haskell.Extract
import Test.QuickCheck

prop_foo xs = reverse (reverse xs) == (xs :: [Int])
prop_bar = 2 + 2 == 4

properties = $(functionExtractorMap "^prop_"
    [|\name prop -> putStrLn name >> quickCheck prop|])

main = sequence_ properties

Запустив это, мы получим:

prop_foo
+++ OK, passed 100 tests.
prop_bar
+++ OK, passed 100 tests.

Однако, прежде чем изобретать велосипед, я также рекомендую вам взглянуть на пакет test-framework-th< /a>, который делает именно это, но также поддерживает HUnit и имеет хороший инструмент для запуска тестов (с цветами!).

{-# LANGUAGE TemplateHaskell #-}

import Test.Framework.Providers.HUnit
import Test.Framework.Providers.QuickCheck2
import Test.Framework.TH
import Test.HUnit
import Test.QuickCheck

prop_bar = 1+1 == 2
case_foo = 2+2 @?= 4

main = $(defaultMainGenerator)

Main:
  bar: [OK, passed 100 tests]
  foo: [OK]

         Properties  Test Cases  Total      
 Passed  1           1           2          
 Failed  0           0           0          
 Total   1           1           2   

Если набор тестов предназначен для QuickCheck, я советую вам вместо этого использовать новый модуль All: http://hackage.haskell.org/packages/archive/QuickCheck/2.4.1.1/doc/html/Test-QuickCheck-All.html

Он делает то же самое, за исключением того, что извлекает имена свойств, обращаясь к файловой системе и анализируя файл, в котором находится соединение (если вы используете какую-то другую тестовую среду, вы все равно можете использовать тот же подход).

Если вы действительно хотите процитировать весь файл, вы можете вместо этого использовать квазицитирование (которое не требует отступа). Вы можете легко построить свой котировщик на haskell-src-meta, но я не рекомендую этот подход, потому что он не будет поддерживать некоторые функции Haskell и, вероятно, будет выдавать плохие сообщения об ошибках.

Объединение наборов тестов — сложная задача, возможно, можно было бы расширить процедуру сбора имен, чтобы каким-то образом следовать импорту, но это требует много работы. Вот обходной путь:

Вы можете использовать эту модифицированную версию forAllProperties:

import Test.QuickCheck
import Test.QuickCheck.All
import Language.Haskell.TH
import Data.Char
import Data.List
import Control.Monad

allProperties :: Q Exp -- :: [(String,Property)]
allProperties = do
  Loc { loc_filename = filename } <- location
  when (filename == "<interactive>") $ error "don't run this interactively"
  ls <- runIO (fmap lines (readFile filename))
  let prefixes = map (takeWhile (\c -> isAlphaNum c || c == '_') . dropWhile (\c -> isSpace c || c == '>')) ls
      idents = nubBy (\x y -> snd x == snd y) (filter (("prop_" `isPrefixOf`) . snd) (zip [1..] prefixes))
      quickCheckOne :: (Int, String) -> Q [Exp]
      quickCheckOne (l, x) = do
        exists <- return False `recover` (reify (mkName x) >> return True)
        if exists then sequence [ [| ($(stringE $ x ++ " on " ++ filename ++ ":" ++ show l),
                                     property $(mono (mkName x))) |] ]
         else return []
  [|$(fmap (ListE . concat) (mapM quickCheckOne idents)) |]

Вам также нужна функция runQuickCheckAll, которая не экспортируется из All:

runQuickCheckAll :: [(String, Property)] -> (Property -> IO Result) -> IO Bool
runQuickCheckAll ps qc =
  fmap and . forM ps $ \(xs, p) -> do
    putStrLn $ "=== " ++ xs ++ " ==="
    r <- qc p
    return $ case r of
      Success { } -> True
      Failure { } -> False
      NoExpectedFailure { } -> False

В каждом тестовом модуле вы теперь определяете

propsN = $allProperties

где N — это число или другой уникальный идентификатор (или вы можете использовать то же имя и использовать полные имена на шаге ниже).

В своем основном наборе тестов вы определяете

props :: [(String,Property)]
props = concat [props1, props2 ... propsN]

Если вы действительно хотите избежать добавления члена списка для каждого модуля, вы можете создать скрипт TH, который генерирует этот список.

Чтобы запустить все ваши тесты, вы просто говорите

runTests = runQuickCheckAll quickCheckResult props