Почему этот яблочный скрипт не работает должным образом?

На моей машине работает небольшая модификация скрипта @regulus6633:

-- restart the Finder
tell application "Finder" to launch      # always launch
if (app_name is equal to "Finder") then
  tell application "Finder" to activate  # activate separately
end if

Должен признаться, я не совсем уверен, почему и как — документация AppleScript для запустить и activate не подходят в случае с Finder…

Я тоже сталкивался с этим раньше. По сути, вы говорите, что когда это запускается, когда Finder находится на самом переднем плане, Finder на самом деле не самый передний. И это правда, потому что вы сказали, что это сервис-автомат. Я считаю, что автоматизатор управляется приложением под названием «Automator Runner». Так что на самом деле, как только сервис запускается, Automator Runner становится самым передним. Обратите внимание, что это безликое приложение, поэтому вы не можете видеть, что оно самое переднее, но это так. Поэтому, когда вы проверяете, является ли Finder самым передним, это никогда не бывает. Имеет ли это смысл? Я вижу то же самое при запуске яблочных скриптов, потому что они запускаются с помощью Applescript Runner.

Итак, как это исправить? Вот мысль. Сделайте это своим ПЕРВЫМ БЛОКОМ и посмотрите, поможет ли это...

tell application "System Events"
    set app_name to name of the first process whose frontmost is true
    if app_name is "Automator Runner" then
        set visible of process "Automator Runner" to false
        set app_name to name of first process whose frontmost is true
    end if
end tell

ПРИМЕЧАНИЕ. Я не уверен, что Automator Runner будет самым передним процессом. Это может быть что-то еще, например, название вашего действия автомата. Но вы можете быть уверены, что что-то еще находится на переднем плане из-за выполняемого действия автомата... поэтому, если мой код не работает, вам просто нужно выяснить имя процесса, который выполняется, когда выполняется ваше действие автомата, и поставить это в код. Вы всегда можете поместить «диалоговое окно отображения» в свой код, чтобы показать вам имя самого переднего процесса.

Еще один совет. В общем, я не люблю использовать команду KILLALL, если вместо нее можно использовать команду QUIT. Программа Quit разработана для Mac и обеспечивает корректную остановку действий. Как назло, в Finder есть команда выхода. Попробуйте это для 3-го и 4-го блоков. Вы увидите, что если Finder был самым передним, то мы активируем его, что снова делает его самым передним, но если это не так, мы запускаем его, чтобы он, по крайней мере, снова работал, но не выходил на передний план.

-- quit the Finder
tell application "Finder" to quit

-- delay until the Finder quits
repeat
    try
        tell application "System Events" to get first process whose name is "Finder"
        delay 0.1
    on error
        exit repeat
    end try
end repeat

-- restart the Finder
if (app_name is equal to "Finder") then
    tell application "Finder" to activate
else
    tell application "Finder" to launch
end if

EDIT: Кажется, ваш шаг № 2 неверен. Вам нужно использовать «ON» или «OFF» вместо 0 или 1. Попробуйте это...

if (do shell script "defaults read com.apple.finder AppleShowAllFiles") is equal to "ON" then
    do shell script "defaults write com.apple.finder AppleShowAllFiles OFF"
else
    do shell script "defaults write com.apple.finder AppleShowAllFiles ON"
end if