Определить тип переменной в Tcl

Переменные Tcl не имеют типов (за исключением того, являются ли они действительно ассоциативным массивом переменных — т. е. используют синтаксис $foo(bar) — для которого вы используете array exists), но значения Tcl имеют. Ну, несколько. Tcl может изменять значения между различными типами по своему усмотрению и не раскрывает эту информацию[*]; все, что вы действительно можете сделать, это проверить, соответствует ли значение определенному типу.

Такие проверки соответствия выполняются с помощью string is (где вам нужна опция -strict по уродливым историческим причинам):

if {[string is integer -strict $foo]} {
    puts "$foo is an integer!"
}

if {[string is list $foo]} {    # Only [string is] where -strict has no effect
    puts "$foo is a list! (length: [llength $foo])"
    if {[llength $foo]&1 == 0} {
        # All dictionaries conform to lists with even length
        puts "$foo is a dictionary! (entries: [dict size $foo])"
    }
}

Обратите внимание, что все значения соответствуют типу строк; Значения Tcl всегда сериализуемы.

[EDIT из комментариев]: Для сериализации JSON можно использовать грязные хаки для создания «правильной» сериализации (строго говоря, помещение всего в строку было бы правильным с точки зрения Tcl, но это не совсем полезно для других языков) с Tcl 8.6. Код для этого, изначально опубликованный на Rosetta Code:

package require Tcl 8.6

proc tcl2json value {
    # Guess the type of the value; deep *UNSUPPORTED* magic!
    regexp {^value is a (.*?) with a refcount} \
        [::tcl::unsupported::representation $value] -> type

    switch $type {
        string {
            # Skip to the mapping code at the bottom
        }
        dict {
            set result "{"
            set pfx ""
            dict for {k v} $value {
                append result $pfx [tcl2json $k] ": " [tcl2json $v]
                set pfx ", "
            }
            return [append result "}"]
        }
        list {
            set result "\["
            set pfx ""
            foreach v $value {
                append result $pfx [tcl2json $v]
                set pfx ", "
            }
            return [append result "\]"]
        }
        int - double {
            return [expr {$value}]
        }
        booleanString {
            return [expr {$value ? "true" : "false"}]
        }
        default {
            # Some other type; do some guessing...
            if {$value eq "null"} {
                # Tcl has *no* null value at all; empty strings are semantically
                # different and absent variables aren't values. So cheat!
                return $value
            } elseif {[string is integer -strict $value]} {
                return [expr {$value}]
            } elseif {[string is double -strict $value]} {
                return [expr {$value}]
            } elseif {[string is boolean -strict $value]} {
                return [expr {$value ? "true" : "false"}]
            }
        }
    }

    # For simplicity, all "bad" characters are mapped to \u... substitutions
    set mapped [subst -novariables [regsub -all {[][\u0000-\u001f\\""]} \
        $value {[format "\\\\u%04x" [scan {& } %c]]}]]
    return "\"$mapped\""
}

Внимание! Приведенный выше код не поддерживается. Это зависит от грязных взломов. Он может сломаться без предупреждения. (Но это действительно работает. Для переноса на Tcl 8.5 потребуется крошечное расширение C для считывания аннотаций типов.)

[*] Строго говоря, он предоставляет неподдерживаемый интерфейс для обнаружения аннотации текущего типа значения в 8.6 — как часть ::tcl::unsupported::representation — но эта информация представлена ​​в преднамеренно удобочитаемой форме и может быть изменена без объявления. Это для отладки, а не кода. Кроме того, Tcl использует внутри довольно много разных типов (например, кешированные имена команд и переменных), которые вы не захотите проверять в обычных обстоятельствах; под капотом все довольно сложно…

Все остальные ответы содержат очень полезную информацию, но стоит отметить то, что многие люди сначала не понимают.

В Tcl значения не имеют типа... вопрос в том, можно ли их использовать как заданный тип. Вы можете думать об этом таким образом

string is integer $a

ты не спрашиваешь

Является ли значение в $a целым числом

То, что вы спрашиваете,

Могу ли я использовать значение в $a как целое число

Полезно рассмотреть разницу между двумя вопросами, когда вы думаете о том, «является ли это целым числом». Каждое целое число также является допустимым списком (из одного элемента)... поэтому can be used как любая, так и обе string is команды вернут true (как и несколько других для целого числа).

Если вы хотите иметь дело с JSON, я настоятельно рекомендую вам прочитать страницу JSON на вики Tcl: http://wiki.tcl.tk/json.

На этой странице я разместил простую функцию, которая компилирует значения Tcl в строку JSON с заданным дескриптором форматирования. Я также нахожу обсуждение на этой странице очень информативным.

Для массивов, которые вы хотите array exists для диктов, которые вы хотите dict exists

для списка я не думаю, что есть встроенный способ до 8.5?, есть это из http://wiki.tcl.tk/440

proc isalist {string} {
  return [expr {0 == [catch {llength $string}]}]
}

Чтобы определить, является ли переменная массивом:

proc is_array {var} {
    upvar 1 $var value
    if {[catch {array names $value} errmsg]} { return 1 } 
    return 0
}   

# How to use it
array set ar {}
set x {1 2 3}
puts "ar is array? [is_array ar]"; # ar is array? 1
puts "x is array? [is_array x]";   # x is array? 0

Для конкретного случая определения того, можно ли использовать значение в качестве словаря, dicttool есть команда dict is_dict <value>, которая возвращает истинное значение, если <value> может действовать как таковое.