Как правильно писать инструкции Try..Finally..Except?

Вам просто нужно два try/finally блока:

Screen.Cursor:= crHourGlass;
try
  Obj:= TSomeObject.Create;
  try
    // do something
  finally
    Obj.Free;
  end;
finally
  Screen.Cursor:= crDefault;
end;

Руководствуйтесь тем, что вы должны использовать finally, а не except для защиты ресурсов. Как вы заметили, если вы попытаетесь сделать это с помощью except, вам придется дважды написать код завершения.

Как только вы войдете в блок try/finally, код в разделе finally гарантированно запустится, независимо от того, что происходит между try и finally.

Итак, в приведенном выше коде внешний try/finally гарантирует, что Screen.Cursor будет восстановлен при любых исключениях. Точно так же внутренний try/finally гарантирует, что Obj будет уничтожен в случае возникновения каких-либо исключений в течение его времени жизни.

Если вы хотите обработать исключение, вам нужен отдельный блок try/except. Однако в большинстве случаев вам не следует пытаться обрабатывать исключения. Просто позвольте ему распространиться до основного обработчика исключений приложения, который покажет сообщение пользователю.

Если вы обрабатываете исключение в нижней части цепочки вызовов, вызывающий код не будет знать, что вызванный им код отказал.

Ваш исходный код не совсем так плох, как вы думаете (хотя и плохой):

procedure TForm1.Button1Click(Sender: TObject);
var
  Obj: TSomeObject;
begin
  Screen.Cursor := crHourGlass;

  Obj := TSomeObject.Create;
  try
    // do something
  finally
    Obj.Free;
  end;

  Screen.Cursor := crDefault;
end;

Obj.Free будет выполняться независимо от того, что произойдет, когда вы // do something. Даже если возникнет исключительная ситуация (после try), блок finally будет выполнен! В этом весь смысл конструкции try..finally!

Но вы также хотите восстановить курсор. Лучше всего использовать две конструкции try..finally:

procedure TForm1.Button1Click(Sender: TObject);
var
  Obj: TSomeObject;
begin

  Screen.Cursor := crHourGlass;
  try
    Obj := TSomeObject.Create;
    try
      // do something
    finally
      Obj.Free;
    end;
  finally
    Screen.Cursor := crDefault;
  end;

end;

Как объясняли другие, вам нужно защитить изменение курсора с помощью блока try finally. Чтобы их не писать, я использую такой код:

unit autoCursor;

interface

uses Controls;

type
  ICursor = interface(IInterface)
  ['{F5B4EB9C-6B74-42A3-B3DC-5068CCCBDA7A}']
  end;

function __SetCursor(const aCursor: TCursor): ICursor;

implementation

uses Forms;

type
  TAutoCursor = class(TInterfacedObject, ICursor)
  private
    FCursor: TCursor;
  public
    constructor Create(const aCursor: TCursor);
    destructor Destroy; override;
  end;

{ TAutoCursor }
constructor TAutoCursor.Create(const aCursor: TCursor);
begin
  inherited Create;
  FCursor := Screen.Cursor;
  Screen.Cursor := aCursor;
end;

destructor TAutoCursor.Destroy;
begin
  Screen.Cursor := FCursor;
  inherited;
end;

function __SetCursor(const aCursor: TCursor): ICursor;
begin
  Result := TAutoCursor.Create(aCursor);
end;

end.

Теперь ты просто используешь это как

uses
   autoCursor;

procedure TForm1.Button1Click(Sender: TObject);
var
  Obj: TSomeObject;
begin
  __SetCursor(crHourGlass);

  Obj:= TSomeObject.Create;
  try
    // do something
  finally
    Obj.Free;
  end;
end;

а механизм интерфейса Delphi с подсчетом ссылок заботится о восстановлении курсора.

Я думаю, что наиболее "правильная" версия будет такая:

procedure TForm1.Button1Click(Sender: TObject);
var
  Obj: TSomeObject;
begin
  Obj := NIL;
  Screen.Cursor := crHourGlass;
  try
    Obj := TSomeObject.Create;
    // do something
  finally
    Screen.Cursor := crDefault;
    Obj.Free;
  end;
end;

Написав много кода в сервисах / серверах, который должен обрабатывать исключения, а не убивать приложение, я обычно делаю что-то вроде этого:

procedure TForm1.Button1Click(Sender: TObject);
var
   Obj: TSomeObject;
begin  
     try
        Obj := NIL;
        try
          Screen.Cursor := crHourGlass;
          Obj := TSomeObject.Create;
          // do something
        finally
          Screen.Cursor := crDefault;
          if assigned(Obj) then FreeAndNil(Obj);
        end;
     except
        On E: Exception do ; // Log the exception
     end;
end;

Обратите внимание на попытку, наконец; внутри try except; и размещение создания Obj.

если Obj создает другие вещи внутри своего конструктора, он может работать наполовину и завершиться ошибкой с исключением внутри .create (); но все же быть созданным Obj. Поэтому я убеждаюсь, что Obj всегда уничтожается, если он был назначен ...

Я бы сделал это так:

var
  savedCursor: TCursor;
  Obj: TSomeObject;
begin
  savedCursor := Screen.Cursor;
  Screen.Cursor := crHourGlass;
  Obj:= TSomeObject.Create;
  try
    try
      // do something
    except
      // record the exception
    end;
  finally
    if Assigned(Obj) then
      Obj.Free;
    Screen.Cursor := savedCursor;
  end;
end;

Если вы нашли здесь свой путь и искали, как создать конструкцию try-except-finally из C # в Delphi:

// C#
try
{
    // Do something
}
catch
{
    // Exception!
}
finally
{
    // Always do this...
}

Ответ в том, что вы не можете сделать это напрямую. Вместо этого, как намекает @sacconago, вложите блоки try следующим образом:

// Delphi
try
    try
        // Do something
    except
        // Exception!
    end;
finally
    // Always do this...
end;

Одной из приятных особенностей Delphi является то, что вы можете вкладывать блоки как try...except...finally или try...finally...except, хотя первое будет более распространенным.