Как избежать ошибки/предупреждения о глубокой рекурсии в Type::Tiny::_build_coercion

Я унаследовал следующий код, который был написан и работает с Type-Tiny-1.004004. :

package Company::Types;

use Type::Library -base, -declare => qw< TruncatedString >;
use Type::Utils -all;

declare TruncatedString, as Str,
    where { length $_ },
    inline_as {
        my ($constraint, $varname) = @_;
        
        return sprintf ( '!defined %s or %s',
            $varname,
            $constraint->parent->inline_check($varname),
        );
    },
    constraint_generator => sub {
        my ($max) = @_;
        die q{Max length must be positive!} unless int($max) > 0;
        return sub { 
            (length $_) <= $max;
        };
    },
    inline_generator => sub {
        my ($max) = @_;
        return sub { 
            my ($constraint, $varname) = @_;

            return sprintf(
                '%s and length %s <= %d', 
                $constraint->parent->inline_check($varname),
                $varname,
                $max,
            );
        };
    },
    coercion_generator => sub {
        my ($base, $derived, $max) = @_;
        # $base - TruncatedString
        # $derived - TruncatedString[<N>]
        # $max - N
        
        # Not sure if I should be adding the coercion to $base or $derived, but I suspect that 
        # $derived is the correct choice here.
        $derived->coercion->add_type_coercions(Str, 
            sub {
                return substr $_, 0, $max;
            }
        );
    };

Однако он не работает с Type-Tiny-1.012000. Я написал следующий тест, чтобы проиллюстрировать проблему:

use Test2::V0;
use Time::Out qw< timeout >;
use Company::Types qw< TruncatedString >;

subtest 'Coercing to TruncatedString->of(10)' => sub {
    timeout 2 => sub {                      # test hangs without timeout
        my $type = TruncatedString->of(10); # same as TruncatedString[10]
        ok( try_ok { $type->coerce('123456789012') }, 'should not throw an exception' );
    } || bail_out( 'Ran out of time: ' . $@ );
};

done_testing();

Это выводит следующее:

# Seeded srand with seed '20201120' from local date.
Deep recursion on subroutine "Type::Tiny::_build_coercion" at ${SRC}/company-types/.direnv/perl5/lib/perl5/Type/Tiny.pm line 399.
Deep recursion on anonymous subroutine at ${SRC}/company-types/.direnv/perl5/lib/perl5/Type/Tiny.pm line 467.
Deep recursion on anonymous subroutine at ${SRC}/company-types/.direnv/perl5/lib/perl5/Type/Tiny.pm line 1015.
not ok 1 - Coercing to TruncatedString->of(10) {
    not ok 1
    # Failed test at t/truncated-string.t line 8.
    # Exception: CODE(0x7fee0fb78998)
    not ok 2 - should not throw an exception
    # Failed test 'should not throw an exception'
    # at t/truncated-string.t line 8.
    1..2
}

# Failed test 'Coercing to TruncatedString->of(10)'
# at t/truncated-string.t line 10.
1..1
Dubious, test returned 1 (wstat 256, 0x100)
Failed 1/1 subtests 

Test Summary Report
-------------------
t/truncated-string.t (Wstat: 256 Tests: 1 Failed: 1)
  Failed test:  1
  Non-zero exit status: 1
Files=1, Tests=1,  4 wallclock secs ( 0.02 usr  0.01 sys +  3.43 cusr  0.38 csys =  3.84 CPU)
Result: FAIL

Я сузил проблему до coercion_generator (если я закомментирую ее, я потеряю эту ошибку) и отметил это в docs:

Следующие атрибуты используются для параметризованного приведения, но они не полностью задокументированы, поскольку могут измениться в ближайшем будущем:

Я предполагаю, что с тех пор это изменилось, и я надеялся на некоторую помощь в том, как обновить мой существующий код, чтобы наверстать упущенное?


perl coerce type-tiny
person j1n3l0    schedule 20.11.2020    source источник

Ответы (1)


arrow_upward
4
arrow_downward

Не уверен, должен ли я добавлять принуждение к $base или $derived

Ни один. Ты должен вернуть его.

coercion_generator => sub {
    my ($base, $derived, $max) = @_;
    return Type::Coercion->new(
        type_coercion_map => [ Str, sub { substr $_, 0, $max } ]
    );
};

См. Параметризуемые типы в Type::Tiny::Manual::Libraries — это дает довольно хорошее объяснение и пример того, как делать параметризованные типы с встраиванием и принуждением.

Я проверил вышеперечисленные работы в текущей версии Type::Tiny и даже в версиях 0.006 (выпущенных в мае 2013 года)! То, как вы делаете это в своем исходном коде, никогда не предполагалось для использования coercion_generator, и я немного удивлен, что это когда-либо работало.

Кроме того, если вам интересно, почему вы получаете предупреждение о глубоком приведении, это вызвано тем фактом, что $type->coercion действует как ленивый атрибут в Moo/Moose и вызывает ваш coderef, но ваш coderef называется $type->coercion.

person tobyink    schedule 21.11.2020