Tcl/Tk — как получить приглашение после выполнения команды с помощью eval?

Приглашение % пришло от интерпретатора tcl и показано в терминале только потому, что оно находится в интерактивном режиме. Если вы запустите свой скрипт как wish test.tcl, вы никогда не получите %.

Вы можете реализовать свой собственный интерактивный режим и вызывать его после всех шагов инициализации вашего приложения. Вот пример, как это можно сделать:

proc Gui::interactive {} {
  set prompt1 "tcl>"
  set prompt2 "?"
  set cmd {}
  set prompt "$prompt1 "
  fconfigure stdin -blocking false -buffering line
  fileevent stdin readable {set Gui::stdinReady 1}
  while true {
    puts -nonewline $prompt
    flush stdout
    vwait Gui::stdinReady
    set str [gets stdin]
    lappend cmd $str
    set cmdStr [join $cmd "\n"]
    if {[info complete $cmdStr]} {
      set cmd {}
      if {$cmdStr != ""} {
        if {[catch {eval $cmdStr} result]} {
          puts stderr "ERROR: $result"
        } elseif {$result != ""} {
          puts $result
        }
      }
      set prompt "$prompt1 "
    } else {
      set prompt "$prompt2 "
    }
    if {[eof stdin]} {
      puts ""
      break
    }
  }
}

Просто вызовите эту функцию после Gui::test выполнения, и вы получите собственное приглашение. Но даже в этом примере подсказка не будет перерисована, если текст будет напечатан на терминал из какой-то другой процедуры.

Вы никогда не теряли подсказку %. Вот что происходит:

У вас есть подсказка:

%

Затем вы печатаете строку в той же строке:

% hello world!

Ваша «текущая» подсказка по-прежнему такая же. Следующая команда включена в этом приглашении:

puts "hi"

Который, поскольку он работает в tclsh и поскольку вы только что вставили новую строку, появляется на следующей строке:

hi

И вы получаете еще одну подсказку:

%

Вы не получили «другое» приглашение от своего графического интерфейса, потому что puts "hello world" не обрабатывалось tclsh напрямую. По сути, что касается tclsh, «привет, мир» пришел с Марса и испортил ваш терминал. Он даже не знает, что там.

Может быть, лучше объяснить это следующим образом: если бы ваш puts "hello world" печатал в файл, то у вас все еще было бы приглашение %. Но кто-то взял эти символы и поместил их на ваш дисплей (включая новую строку).