Как передать массив, разделенный запятыми, на ресурс в terraform v0.12.0?

Вы могли сделать это:

locals {
  arr = ["host1", "host2", "host3"]
}

output "test" {
  value = jsonencode(
    {
      "consul" = {
        "servers" = local.arr
      }
    })
}

И это дает как результат:

Outputs:

test = {"consul":{"servers":["host1","host2","host3"]}}

Используйте функцию соединения и heredoc

В документации Chef Provider предлагается использовать heredoc для строки JSON, поэтому вы также можете сделать это:

locals {
  arr = ["host1", "host2", "host3"]
  sep = "\", \""
}

output "test" {
  value = <<-EOF
    {
      "consul": {
        "servers": ["${join(local.sep, local.arr)}"]
      }
    }
  EOF
}

Если я применяю это:

Outputs:

test = {
  "consul": {
    "servers": ["host1", "host2", "host3"]
  }
}

Здесь есть на что обратить внимание:

• Вы пытаетесь присоединиться к своим хостам, чтобы они стали действительными JSON в контексте массива JSON. Их нужно соединять с помощью ",", а не просто запятой. Вот почему я определил локальную переменную sep = "\", \"".

• Кажется, вы пытаетесь split там, когда вам очевидно нужно join.

Проблема с циклической зависимостью

Причина сообщения об ошибке:

Error: Cycle: aws_instance.consul-server[1], aws_instance.consul-server[0]

Разве что у вас циклическая зависимость. Рассмотрим этот упрощенный пример:

resource "aws_instance" "example" {
  count         = 3
  ami           = "ami-08589eca6dcc9b39c"
  instance_type = "t2.micro"
  user_data     = <<-EOF
    hosts="${join(",", aws_instance.example[count.index].id)}"
  EOF
}

Или вы можете использовать обозначение splat для того же результата, то есть aws_instance.example.*.id.

Тогда план Terraform дает:

▶ terraform012 plan 
...
Error: Cycle: aws_instance.example[2], aws_instance.example[1], aws_instance.example[0]

Таким образом, вы получаете ошибку цикла, потому что aws_instance.example.*.id зависит от создаваемого aws_instance.example, поэтому ресурс зависит от самого себя. Другими словами, вы не можете использовать экспортированные значения ресурсов внутри самого ресурса.

Что делать

Я мало что знаю о Consul, но все же я немного сбит с толку, потому что вам нужны идентификаторы экземпляров EC2 в поле servers. Разве конфигурация Consul не ожидала бы там IP-адресов или имен хостов?

В любом случае вам, вероятно, потребуется вычислить имена хостов самостоятельно за пределами этого ресурса, либо как статический входной параметр, либо как что-то, что вы можете вычислить каким-либо образом. И я полагаю, у вас получится что-то вроде:

variable "host_names" {
  type    = list
  default = ["myhost1"]
}

resource "aws_instance" "consul_server" {
  ...
  provisioner "chef" {
    attributes_json = jsonencode(
      {
        "consul" = {
          "servers" = var.host_names
        }
      })
  }
}