Вызов исключения в TThread Execute?

Вот мой очень, очень краткий «взгляд» на проблему. Он работает только в Delphi 2010+ (потому что в этой версии появились анонимные методы). В отличие от уже опубликованных более сложных методов, мой показывает только сообщение об ошибке, ни больше, ни меньше.

procedure TErrThread.Execute;
var ErrMsg: string;
begin
  try
    raise Exception.Create('Demonstration purposes exception');
  except on E:Exception do
    begin
      ErrMsg := E.ClassName + ' with message ' + E.Message;
      // The following could be all written on a single line to be more copy-paste friendly  
      Synchronize(
        procedure
        begin
          ShowMessage(ErrMsg);
        end
      );
    end;
  end;
end;

Что-то очень важное, что вам нужно понять о многоуровневой разработке:

Каждый поток имеет свой собственный стек вызовов, почти, как будто это отдельные программы. Это включает в себя основной поток вашей программы.

Потоки могут взаимодействовать друг с другом только определенным образом:

• Они могут работать с общими данными или объектами. Это может привести к проблемам параллелизма, "условиям гонки", и поэтому вам нужно помочь им "хорошо обмениваться данными". Что подводит нас к следующему пункту.
• They can "signal each other" using a variety of OS support routines. These include things like:
  • Mutexes
  • Критические секции
  • События
• И, наконец, вы можете отправлять сообщения в другие потоки. При условии, что цепочка каким-то образом написана как получатель сообщений.

Примечание. Обратите внимание, что потоки не могут строго говоря напрямую вызывать другие потоки. Если, например, поток A попытается вызвать поток B напрямую, это будет шагом в стеке вызовов потока A!

Это подводит нас к теме вопроса: "в моих темах не возникают исключения"

Причина этого в том, что все, что делает исключение, это:

• Запишите ошибку
• И раскрутите стек вызовов. ‹-- NB: Ваш экземпляр TThread не может развернуть стек вызовов основного потока и не может произвольно прерывать выполнение основного потока.

Таким образом, TThread не будет автоматически сообщать об исключениях вашему основному приложению.

Вы должны принять четкое решение о том, как вы хотите обрабатывать ошибки в потоках, и реализовать его соответствующим образом.

Решение

• The first step is the same as within a single threaded application. You need to decide what the error means and how the thread should react.
  • Should the thread continue processing?
  • Должен ли поток прерваться?
  • Должна ли ошибка быть зарегистрирована/сообщена?
  • Требуется ли для ошибки решение пользователя? ‹-- Это, безусловно, сложнее всего реализовать, поэтому мы пока его пропустим.
• Как только это будет решено, реализуйте соответствующий обработчик исключений.
• TIP: Make sure the exception doesn't escape the thread. The OS won't like you if it does.
• If you need the main program (thread) to report the error to the user, you have a few options.
  • If the thread was written to return a result object, then it's easy: Make a change so that it can return the error in that object if something went wrong.
  • Отправьте сообщение в основной поток, чтобы сообщить об ошибке. Обратите внимание, что основной поток уже реализует цикл сообщений, поэтому ваше приложение сообщит об ошибке, как только обработает это сообщение.

РЕДАКТИРОВАТЬ: пример кода для указанного требования.

Если все, что вы хотите сделать, это уведомить пользователя, то Cosmind Prund answer должен отлично работать в Delphi 2010. Над старыми версиями Delphi нужно немного доработать. Следующее концептуально похоже на собственный ответ Джеффа, но без ошибок :

procedure TUpdaterThread.ShowException;
begin
  MessageDlg(FExceptionMessage, mtError, [mbOk], 0);
end;

procedure TUpdaterThread.Execute;
begin
  try

    raise Exception.Create('Test Exception');
    //The code for your thread goes here
    //
    //

  except
    //Based on your requirement, the except block should be the outer-most block of your code
    on E: Exception do
    begin
      FExceptionMessage := 'Exception: '+E.ClassName+'. '+E.Message;
      Synchronize(ShowException);
    end;
  end;
end;

Некоторые важные исправления в собственном ответе Джеффа, включая реализацию, показанную в его вопросе:

Вызов Terminate актуален только в том случае, если ваш поток реализован в цикле while not Terminated do .... Посмотрите, что на самом деле делает метод Terminate.

Вызов Exit — ненужная трата времени, но вы, вероятно, сделали это из-за своей очередной ошибки.

В вашем вопросе вы оборачиваете каждый шаг в свой собственный try...except для обработки исключения. Это абсолютное нет-нет! Делая это, вы делаете вид, что даже при возникновении исключения все в порядке. Ваш поток пытается выполнить следующий шаг, но на самом деле это гарантированно потерпит неудачу! Это не способ обработки исключений!

Потоки не распространяют автоматически исключения в другие потоки. Поэтому вы должны справиться с этим сами.

Рафаэль изложил один подход, но есть и альтернативы. Решение Рафаэль указывает на синхронную обработку исключения путем его сортировки в основной поток.

В одном из моих собственных применений потоковой передачи, пуле потоков, потоки перехватывают и берут на себя ответственность за исключения. Это позволяет управляющему потоку обрабатывать их по своему усмотрению.

Код выглядит так.

procedure TMyThread.Execute;
begin
  Try
    DoStuff;
  Except
    on Exception do begin
      FExceptAddr := ExceptAddr;
      FException := AcquireExceptionObject;
      //FBugReport := GetBugReportCallStackEtcFromMadExceptOrSimilar.
    end;
  End;
end;

Если управляющий поток решит вызвать исключение, он может сделать это следующим образом:

raise Thread.FException at Thread.FExceptAddr;

Иногда у вас может быть код, который не может вызывать Synchronize, например. некоторые библиотеки DLL, и этот подход полезен.

Обратите внимание, что если вы не вызываете захваченное исключение, его необходимо уничтожить, иначе возникнет утечка памяти.

Что ж,

Без вашего исходного кода будет сложно, но я проверил это:

Как обрабатывать исключения в объектах TThread

И это работает нормально. Возможно, вам стоит взглянуть на это.

РЕДАКТИРОВАТЬ:

Вы не следуете тому, о чем говорят нам ссылки, которые вы указываете. Проверьте мою ссылку, и вы увидите, как это сделать.

РЕДАКТИРОВАТЬ 2:

Попробуйте это и скажите мне, если это сработало:

 TUpdaterThread= class(TThread)
 private
   FException: Exception;
   procedure DoHandleException;
 protected
   procedure Execute; override;
   procedure HandleException; virtual;
 end;

procedure TUpdaterThread.Execute;
begin
  inherited;
  FreeOnTerminate := True;
  if Terminated then
    Exit;
  FileGrabber := THtmlExtractor.Create;
  HTTP := TIdHTTP.Create(Nil);
  try
    Try
      FileGrabber.Grab('http://jeffijoe.com/xSky/Updates/CheckForUpdates.php');
    Except
      HandleException;
    End;
    Try
      AppMajor := StrToInt(FileGrabber.ExtractValue('AppMajor[', ']'));
      AppMinor := StrToInt(FileGrabber.ExtractValue('AppMinor[', ']'));
      AppRelease := StrToInt(FileGrabber.ExtractValue('AppRelease[[', ']'));
    Except
      HandleException;
    End;
    if (APP_VER_MAJOR < AppMajor) or (APP_VER_MINOR < AppMinor) or (APP_VER_RELEASE < AppRelease) then begin
      VersionStr := Format('%d.%d.%d', [AppMajor, AppMinor, AppRelease]);
      UpdateText := 'Downloading Version ' + VersionStr;
      Synchronize(SyncUpdateLbl);
    end;
  finally
    FileGrabber.Free;
    HTTP.Free;
  end;
  Synchronize(SyncFinalize);

end;

procedure TUpdaterThread.HandleException;
begin
  FException := Exception(ExceptObject);
  try
    Synchronize(DoHandleException);
  finally
    FException := nil;
  end;
end;

procedure TMyThread.DoHandleException;
begin
  Application.ShowException(FException);
end;

РЕДАКТИРОВАТЬ 3:

Вы сказали, что не можете поймать EIdHTTPProtocolException. Но это работает для меня. Попробуйте этот образец и убедитесь в этом сами:

procedure TUpdaterThread.Execute;
begin
  Try
    raise EIdHTTPProtocolException.Create('test');
  Except
    HandleException;
  End;
end;

Ранее я использовал SendMessge для обмена данными между потоками с использованием TWMCopyData, поэтому я думаю, что должно работать следующее:

Const MyAppThreadError = WM_APP + 1;

constructor TUpdaterThread.Create(ErrorRecieverHandle: THandle);
begin
    Inherited Create(False);
    FErrorRecieverHandle := Application.Handle;
end;

procedure TUpdaterThread.Execute;
var
    cds: TWMCopyData;
begin
  try
     DoStuff;
  except on E:Exception do
    begin
        cds.dwData := 0;
        cds.cbData := Length(E.message) * SizeOf(Char);
        cds.lpData := Pointer(@E.message[1]);         
        SendMessage(FErrorRecieverHandle, MyAppThreadError, LPARAM(@cds), 0);
    end;
  end;
end;

Я использовал его только для отправки простых типов данных или строк, но я уверен, что его можно адаптировать для отправки дополнительной информации по мере необходимости.

Вам нужно будет добавить Self.Handle в конструктор в форме, созданной потоком, и обработать сообщение в форме, которая его создала.

procedure HandleUpdateError(var Message:TMessage); message MyAppThreadError;
var
    StringValue: string;
    CopyData : TWMCopyData; 
begin
    CopyData := TWMCopyData(Msg);
    SetLength(StringValue, CopyData.CopyDataStruct.cbData div SizeOf(Char));
    Move(CopyData.CopyDataStruct.lpData^, StringValue[1], CopyData.CopyDataStruct.cbData);
    Message.Result := 0;
    ShowMessage(StringValue);
end;

Странно, что все ответили на этот вопрос, но не заметили очевидной проблемы: учитывая, что исключения, вызванные в фоновом потоке, являются асинхронными и могут возникнуть в любое время, это означает, что отображение исключений из фонового потока вызовет случайное всплывающее диалоговое окно. раз пользователю, вполне возможно, показывая исключение, которое не имеет ничего общего с тем, что пользователь делает в данный момент. Я сомневаюсь, что это может улучшить пользовательский опыт.