Что ж. У меня есть таблица с именем «ALL_INFO» на листе в Excel, и я сделал сводную таблицу на другом листе, ее имя «PIVOT_INFO». И я хотел бы знать, как связать таблицу и сводную таблицу с помощью слайсеров для фильтрации информации, и она будет отражена в обеих таблицах.
Кто-нибудь знает, как я могу это сделать?
Заранее спасибо.
Создайте слайсер для сводной таблицы и один для таблицы. Убедитесь, что PT Slicer виден, а Table Slicer скрыт где-то, где пользователи его не видят. Затем поместите этот код в модуль листа, соответствующий рабочему листу, на котором находится ваш PT:
Option Explicit
Private Sub Worksheet_PivotTableUpdate(ByVal Target As PivotTable)
Dim sLastUndoStackItem As String
Dim sc_Pivot As SlicerCache
Dim sc_Table As SlicerCache
Dim si_Pivot As SlicerItem
Dim si_Table As SlicerItem
With Application
.ScreenUpdating = False
.Calculation = xlCalculationManual
End With
If Target.Name = "PivotTable1" Then '<= Change name as appropriate
On Error Resume Next 'in case the undo stack has been wiped or doesn't exist
sLastUndoStackItem = Application.CommandBars(14).FindControl(ID:=128).List(1) 'Standard Commandbar, undo stack
'The above line doesn't seem to work in my version of O365 so we'll use the English language backup
If sLastUndoStackItem = "" Then sLastUndoStackItem = Application.CommandBars("Standard").Controls("&Undo").List(1)
On Error GoTo 0
If sLastUndoStackItem = "Filter" Or sLastUndoStackItem = "Slicer Operation" Then
Set sc_Pivot = ActiveWorkbook.SlicerCaches("Slicer_Data") '<= Change name as appropriate
Set sc_Table = ActiveWorkbook.SlicerCaches("Slicer_Data1") '<= Change name as appropriate
sc_Table.ClearAllFilters
On Error Resume Next 'In case items differ between Table and PT
For Each si_Pivot In sc_Pivot.SlicerItems
With si_Pivot
sc_Table.SlicerItems(.Name).Selected = .Selected
End With
Next si_Pivot
End If
End If
With Application
.ScreenUpdating = True
.Calculation = xlCalculationAutomatic
End With
End Sub
Вот как все выглядит до того, как я использую слайсер «Мастер»:
...и вот как все выглядит после использования слайсера "Мастер":
Обратите внимание, что фильтрация таблицы скрывает строки на всем листе. Таким образом, вы не хотите помещать рядом с таблицей что-либо, что вы хотите всегда видеть.
