Чтение интерактивного ввода в конвейере Jenkins в переменную

Для сохранения в переменные и в файл попробуйте что-то вроде этого в зависимости от того, что у вас было:

pipeline {

    agent any

    stages {

        stage("Interactive_Input") {
            steps {
                script {

                    // Variables for input
                    def inputConfig
                    def inputTest

                    // Get the input
                    def userInput = input(
                            id: 'userInput', message: 'Enter path of test reports:?',
                            parameters: [

                                    string(defaultValue: 'None',
                                            description: 'Path of config file',
                                            name: 'Config'),
                                    string(defaultValue: 'None',
                                            description: 'Test Info file',
                                            name: 'Test'),
                            ])

                    // Save to variables. Default to empty string if not found.
                    inputConfig = userInput.Config?:''
                    inputTest = userInput.Test?:''

                    // Echo to console
                    echo("IQA Sheet Path: ${inputConfig}")
                    echo("Test Info file path: ${inputTest}")

                    // Write to file
                    writeFile file: "inputData.txt", text: "Config=${inputConfig}\r\nTest=${inputTest}"

                    // Archive the file (or whatever you want to do with it)
                    archiveArtifacts 'inputData.txt'
                }
            }
        }
    }
}

Это простейший пример использования input ().

• В виде сцены, когда вы наводите курсор на первую стадию, вы замечаете вопрос «Вы хотите продолжить?».
• Вы заметите аналогичное примечание в выводе консоли при выполнении задания.

Пока вы не нажмете «Продолжить» или «Прервать», задание будет ожидать ввода данных пользователем в приостановленном состоянии.

pipeline {
    agent any

    stages {
        stage('Input') {
            steps {
                input('Do you want to proceed?')
            }
        }

        stage('If Proceed is clicked') {
            steps {
                print('hello')
            }
        }
    }
}

Существуют более продвинутые способы отображения списка параметров, позволяющие пользователю выбрать один параметр. Основываясь на выборе, вы можете написать отличную логику для продолжения и развертывания в QA или продакшене.

Следующий скрипт отображает раскрывающийся список, из которого пользователь может выбрать

stage('Wait for user to input text?') {
    steps {
        script {
             def userInput = input(id: 'userInput', message: 'Merge to?',
             parameters: [[$class: 'ChoiceParameterDefinition', defaultValue: 'strDef', 
                description:'describing choices', name:'nameChoice', choices: "QA\nUAT\nProduction\nDevelop\nMaster"]
             ])

            println(userInput); //Use this value to branch to different logic if needed
        }
    }

}

Вы также можете использовать _3 _, _ 4_ или BooleanParameterDefinition и многие другие, как указано в вашей ссылке.

Решение. Чтобы задать, получить и получить доступ к вводу пользователя в виде переменной в конвейере jenkins, следует использовать ChoiceParameterDefinition, прикрепив быстрый рабочий фрагмент:

    script {
            // Define Variable
             def USER_INPUT = input(
                    message: 'User input required - Some Yes or No question?',
                    parameters: [
                            [$class: 'ChoiceParameterDefinition',
                             choices: ['no','yes'].join('\n'),
                             name: 'input',
                             description: 'Menu - select box option']
                    ])

            echo "The answer is: ${USER_INPUT}"

            if( "${USER_INPUT}" == "yes"){
                //do something
            } else {
                //do something else
            }
        }