CheckException принимает только методы с 0 параметрами; как проверить, что другие методы вызывают исключения?

Вы можете использовать StartExpectingException, чтобы окружить вызов вашего метода).

StartExpectingException(MyException);
MyMethod(MyParam);
StopExpectingException();

Я не знаю, поддерживает ли его DUnit, но это идеальный вариант использования анонимных методов, которые были введены в Delphi 2010. Если DUnit не поддерживает его, вы можете легко изменить исходный код самостоятельно.

Как уже отмечалось, это отличное место для анонимных методов.

Вот как я это делаю. Я «позаимствовал» это у Алекса Чобану:

procedure TestTMyClass.CheckException(aExceptionType: TClassOfException; aCode: TTestCode; const aMessage: String);
var
  WasException: Boolean;
begin
  WasException := False;
  try
    aCode;
  except
    on E: Exception do
    begin
      if E is aExceptionType then
      begin
        WasException := True;
      end;
    end;
  end;
  Check(WasException, aMessage);
end;

Затем вызовите его примерно так:

CheckException(ETestingException, 
             procedure begin FMyClass.RaiseTestingException end,      
             'The ETestingException exception didn''t get raised.  That is impossible!');

Использовать StartExpectingException() не лучший способ, если вы хотите протестировать более одного случая исключения. Чтобы проверить все возможные случаи в моей тестовой процедуре вместе с исключениями, я использую этот алгоритм:

uses
  Dialogs;
procedure MyTest.MyMethod_Test;
begin
  // Test for Exceptions
  try
    MyMethod(MyParam1CreatingException1);
    ShowMessage('Error! There should have been exception: Exxx here!');
    Check(false);
  except on E: Exception do Check(E is  ExceptionType1); end; // This exception is OK
  try
    MyMethod(MyParam2CreatingException2);
    ShowMessage('Error! There should have been exception: Exxx here!');
    Check(false);
  except on E: Exception do Check(E is  ExceptionType2); end; // This exception is OK
  // ... test other exceptions ...

  // Test other parameters
  CheckEquals('result1', MyMethod(MyParam1));
  CheckEquals('result2', MyMethod(MyParam2));
  // ... other tests ...
end;

Причина, по которой я использую ShowMessage('Error! There should be exception: Exxx here!'); вместо предоставленного метода Check(false, 'There should have been an EListError.');, заключается в том, что в моем случае (Delphi6) Check(boolean, 'Message') не работает - он не показывает сообщение, если проверка находится внутри блока try...except (не знаю почему).

Это рабочая и улучшенная версия ответа Ника Ходжеса, который подклассифицирует DUnit TestFramework.TTestCase:

uses
  TestFramework, System.SysUtils;
type
  TTestCode = reference to procedure;

  TTestCasePlus = class(TestFramework.TTestCase)
    procedure CheckException(
      ExceptionType: TClass; Code: TTestCode; const Message: String = '');
  end;

implementation

procedure TTestCasePlus.CheckException(
  ExceptionType: TClass; Code: TTestCode; const Message: String = '');
{ Check whether some code raises a specific exception type.

Adapted from http://stackoverflow.com/a/5615560/797744

Example:

  Self.CheckException(EConvertError,
                      procedure begin UnformatTimestamp('invalidstr') end);

@param ExceptionType: The exception class which we check if it was raised.
@param Code: Code in the form of an anonymous method that should raise the
  exception.
@param Message: Output message on check failure. }
var
  WasRaised: Boolean;
begin
  WasRaised := False;
  try
    Code;
  except
    on E: Exception do
      if E is ExceptionType then
        WasRaised := True;
  end;
  Check(WasRaised, Message);
end;

Приятным бонусом к этому методу проверки того, было ли возбуждено исключение поверх Start/StopExpectingException(), является то, что вы можете запустить testrunner в отладочной сборке, и он не будет постоянно беспокоить вас «Исключение было поднято. Прервать? Продолжить?» каждый раз, когда возникает исключение, даже если оно было обработано.