Рекурсивная копия папки с XQuery

MLCP было бы неплохо использовать. Однако вот моя версия:

declare option xdmp:set-transaction-mode "update";

declare variable $prefix-replace := ('C:/', '/expath_console/');

declare function local:recursive-copy($filesystem as xs:string){
   for $e in xdmp:filesystem-directory($filesystem)/dir:entry
    return 
      if($e/dir:type/text() = "file")
         then 
           let $source := $e/dir:pathname/text()
           let $dest := fn:replace($source, $prefix-replace[1], $prefix-replace[2]) 
           let $_ := xdmp:document-insert($source,
              <options xmlns="xdmp:document-load">
                <uri>{$dest}</uri>
              </options>)
           return <record>
                     <from>{$source}</from>
                     <to>{$dest}</to>
                  </record>
         else
           local:recursive-copy($e/dir:pathname)

};

let $filesystemfolder := 'C:\Temp'

return <results>{local:recursive-copy($filesystemfolder)}</results> 

Обратите внимание на следующее:

• Я изменил свой образец на каталог C:\Temp
• Выходные данные представляют собой XML только потому, что по соглашению я стараюсь делать это на случай, если мне нужно проанализировать результаты. Именно так я обнаружил ошибку, связанную с конфликтующими обновлениями.
• Я решил определить простую замену префикса в URI.
• Я не увидел необходимости в длс в вашем описании
• Я не видел необходимости в явном создании каталогов в вашем случае использования
• Причина, по которой вы получали конфликтующие обновления, заключалась в том, что вы использовали только имя файла в качестве URI. Во всей структуре каталогов эти имена не были уникальными — отсюда и конфликтующие обновления при двойной вставке одного и того же URI.
• This is not solid code:
  • You would have to ensure that a URI is valid. Not all filesystem paths/names are OK for a URI, so you would want to test for this and escape chars if needed.
  • Large filesystems would time-out, so spawning in batches may be useful.
    • A an example, I might gather the list of docs as in my XML and then process that list by spawning a new task for every 100 documents. This could be accomplished by a simple loop over xdmp:spawn-function or using a library such as taskbot by @mblakele