Добавление ограничения члена к параметру встроенной функции вызывает FS0752 в методе доступа к массиву.

Вам нужно вызвать члена Item следующим образом:

let inline transform (a: 'A) : 'a = (^A : (member get_Item: _ -> _) a, 0)

Однако вы получите предупреждение,

~vs72B.fsx(2,5): warning FS0077: Member constraints with the name 'get_Item' are given special status by the F# compiler as certain .NET types are implicitly augmented with this member. This may result in runtime failures if you attempt to invoke the member constraint from your own code.

потому что некоторые примитивные типы используют «симулированные члены». Итак, для списка это будет работать:

transform ["element"]
// val it : string = "element"

но не для массивов

transform [|"element"|]
System.NotSupportedException: Specified method is not supported.
at <StartupCode$FSI_0009>.$FSI_0009.main@()
Stopped due to error

Это связано с тем, что компилятор F# делает вид, что массивы имеют этот элемент, но на самом деле его нет.

Если это проблема, вы можете использовать более сложное решение с перегрузками, чтобы добавить специальные реализации для определенных типов, что не является прямым, но я могу показать вам, как это сделать, или вы можете рассмотреть возможность использования F#+, который имеет Индексируемая абстракция для типов, которые обычно имеют свойство Item.

Конечно, вы можете проигнорировать это предупреждение с помощью #nowarn "77", но, как вы видели, компилятор не может проверить, что кто-то вызовет вашу функцию с массивом и потерпит неудачу во время выполнения.

ОБНОВЛЕНИЕ

Поскольку вы задали дополнительный вопрос, как его использовать, вот пример:

#r "MathNet.Numerics.dll"
#r "MathNet.Numerics.FSharp.dll"
#r "FSharpPlus.dll"

open FSharpPlus
open MathNet.Numerics.LinearAlgebra

let x = item 1 [0..10]
let y = item 1 [|0..10|]
let z = item 1 (vector [0.;1.;2.])

// val x : int = 1
// val y : int = 1
// val z : float = 1.0

Я не уверен, будет ли он работать с DiffSharp, и я не знаю, какой тип вы используете из этой библиотеки, я нашел DV несколько раз.

ОБНОВЛЕНИЕ 2

Что касается вашего дополнительного вопроса для вашей общей функции transform, использования простого ограничения члена будет недостаточно, вам также нужно будет в общем решить преобразование из списка в целевой тип, а также создать другое общее умножение, которое работает в общем, но с типы, с которыми вам нужно иметь дело. Вы можете использовать перегрузки в сочетании с ограничением члена, чтобы получить желаемую функциональность:

let inline item (i:int) (a: 'A) : 'a = (^A : (member get_Item: _ -> _) a, i)

type T = T with
    static member ($) (T, _:Vector<float>) = fun (x:float list) -> vector x
    static member ($) (T, _:Matrix<float>) = fun (x:float list) -> matrix [x]
    static member ($) (T, _:DV           ) = fun (x: D list  ) -> toDV (List.toArray x)

let inline toDestType (x:'t list) :'D = (T $ Unchecked.defaultof<'D>) x

type V = V with
    static member ($) (V, x:float        ) = fun (y: float) -> x * y : float
    static member ($) (V, x:D            ) = fun (y: float) -> x * y : D

let inline mult (y:float) (x:'t)  :'t = (V $ x) y

let inline transform (a:'T) :'T =
    let x1, y1 = mult l1 (cos (item 0 a)), mult l1 (sin (item 0 a))
    let x2, y2 = x1 + mult l2 (cos ((item 0 a) + (item 1 a))), y1 + mult l2 (sin ((item 0 a) + (item 1 a)))
    let g = toDestType [x1; y1; x2; y2]
    g 

let b = transform  (DV [| 1. ;  2.|])
let a = transform  (vector [1. ; 2.])

Я по-прежнему получаю ошибку времени выполнения каждый раз, когда ссылаюсь на DiffSharp, однако intellisense показывает правильные типы.