Как использовать переменную для извлечения значения из ответа JSON с помощью Groovy?

Я пытаюсь извлечь марку велосипеда «Cannondale» из ответа JSON, используя местоположение значения, хранящегося в переменной с именем «jsonFieldName».

В качестве альтернативы я могу успешно извлечь ценность бренда, используя следующий синтаксис:

def brand = json.store.bicycle.brand

однако я хочу сохранить местоположение элемента в переменной. Причина в том, что я хочу иметь возможность повторять несколько утверждений в ответе Json как часть моего пакета автоматизации.

Может кто-нибудь любезно посоветовать, как это сделать?

Ниже приведен фрагмент, который у меня сейчас есть, сохраняя местоположение в переменной. Но он не работает и всегда возвращает бренд как «Null» :( Спасибо.

def response = ('''{
   "store": {
  "book": [
     {
        "title": "Sword of Honour",
        "category": "fiction",
        "author": "Evelyn Waugh",
        "@price": 12.99
     },
     {
        "title": "Moby Dick",
        "category": "fiction",
        "author": "Herman Melville",
        "isbn": "0-553-21311-3",
        "@price": 8.99
     },
     {
        "title": "Sayings of the Century",
        "category": "reference",
        "author": "Nigel Rees",
        "@price": 8.95
     },
     {
        "title": "The Lord of the Rings",
        "category": "fiction",
        "author": "J. R. R. Tolkien",
        "isbn": "0-395-19395-8",
        "@price": 22.99
     }
  ],
  "bicycle": {
     "brand": "Cannondale",
     "color": "red",
     "price": 19.95
  }
 }
}''').toString()

//store location of json property I want to extract in property called jsonFieldName
def jsonFieldName = "store.bicycle.brand"
def json = new JsonSlurper().parseText (response)
//perform extraction
brand = json."${jsonFieldName}"

json soapui groovy assertion jsonslurper
person fambo    schedule 12.10.2016    source источник

Ответы (2)


arrow_upward
0
arrow_downward

Проблема в том, что использование строки для доступа к свойству; строка считается полным именем свойства, поэтому ее нельзя использовать для доступа более чем к одному свойству глубины; другими словами, . считается частью имени свойства.

Возможный обходной путь может состоять в том, чтобы разделить вашу строку на символ . и получить доступ к свойствам один за другим:

def jsonFieldName = "store.bicycle.brand"
def json = new JsonSlurper().parseText (response)

jsonFieldName.split("\\.").each{json = json[it]}

assert json == 'Cannondale'
person albciff    schedule 12.10.2016

arrow_upward
3
arrow_downward

new JsonSlurper().parseText(response) возвращает карту, таким образом, поиск "store.bicycle.brand" будет искать ключ с именем store.bicycle.brand в переменной json, в то время как вы хотели искать сначала в json['store'], а затем в индексе ['bicycle'] и так далее.

Я использовал стратегию inject, чтобы сделать то, что вы хотели:

def response = '''{
   "store": {
  "bicycle": {
     "brand": "Cannondale",
     "color": "red",
     "price": 19.95
  }
 }
}'''

def jsonFieldName = "store.bicycle.brand"
def json = new groovy.json.JsonSlurper().parseText (response)

get = { field, json2 ->
    field.tokenize(".").inject(json2) { map, f -> map[f] }
}

brand = get jsonFieldName, json
assert brand == 'Cannondale'
person Will    schedule 12.10.2016
comment
на самом деле более функциональный подход сделает ваш ответ приятным, +1! - person albciff; 13.10.2016