использование свойств против геттеров/сеттеров в бизнес-классах

Нет. Геттеры и сеттеры есть только в Java, потому что у него нет свойств. Использование свойств делает код намного чище. И затем, если вам нужен геттер или сеттер, вы можете встроить его в свойство, но вам не нужно засорять код доступа кучей вызовов функций.

Ух ты. В свойствах гораздо больше, чем «они просто обертки для методов получения и установки».

Свойства — это элегантный, но мощный способ предоставления контролируемого доступа к полям класса.

Доступ к полям

Как уже говорилось, вы можете напрямую обращаться к полям класса. Это действительно очень приятно и делает код более понятным. Это также очень хороший способ реализовать работоспособную первую версию вашего класса.

TMyClass = class
private
  FValue: String;
public
  property Value: String read FValue write FValue;
end; 

Позже вы можете перепроектировать свой класс, чтобы проверять и управлять доступом к полю с помощью методов. Публичный интерфейс останется прежним.

TMyClass = class
private
  FValue: String;
  procedure SetValue(AValue: String);
public
  property Value: String read FValue write SetValue;
end; 

procedure TMyClass.SetValue(AValue: String);
begin
  if AValue = '' 
  then FValue := 'No value!'
  else FValue := AValue;
end;

Управление доступом

Свойства дают вам простой обзор полей только для чтения/записи. Например. только для чтения/неизменяемый класс:

TClient = class
private
  FName: String;
  FSite: String;
  FMail: String;
public
  constructor Create(AName, ASite, AMail: String);
  property Name: String read FName;
  property Site: String read FSite;
  property Mail: String read FMail;
end; 

Полиморфизм

TClient = class
private
  FName: String;
protected
  function GetName: String; virtual; abstract;
public
  property Name: String read GetName write FName;
end; 

TImportantClient = class(TClient)
protected
  function GetName: String; override;
end; 

TArgumentativeClient = class(TClient)
protected
  function GetName: String; override; 
end; 

function TImportantClient.GetName: String; 
begin
  Result := '+++ ' + FName;
end; 

function TArgumentativeClient.GetName: String; 
begin
  Result := ':-( ' + FName;
end; 

{----- ----- ----- ----- -----}
var
  ClientA,
  ClientB: TClient;
begin
  ClientA := TImportantClient.Create;
  ClientB := TArgumentativeClient.Create;

  ClientA.Name := 'Mr. Nice';
  ClientB.Name := 'Mr. Dumbhead';

  ShowMessage(ClientA.Name);
  ShowMessage(ClientB.Name);
end;
{----- ----- ----- ----- -----}

Свойства по умолчанию

В вашем классе вы можете определить поля класса по умолчанию, что означает, что вы можете получить доступ к полю напрямую, не указывая имя свойства.

A := MyStringList[i]:
MyStringList[i] := B;

{ instead of }

A := MyStringList.Strings[i];
MyStringList.Strings[i] := B;

{ or }

A := MyStringList.GetString(i);
MyStringList.SetString(i, B);

Показатель

С помощью ключевого слова Index Delphi будет передавать постоянное значение в качестве аргумента методам получения/установки.

TMyRect = class
private
  FValues: Array[0..3] of Integer;
  function GetProperty(Index: Integer): Integer;
public
  property Top    : Integer  Index 0  read GetProperty;
  property Left   : Integer  Index 1  read GetProperty;
  property Width  : Integer  Index 2  read GetProperty;
  property Height : Integer  Index 3  read GetProperty;
end;


function TMyRect.GetProperty(Index: Integer): Integer;
begin
  Result := FValues[Index];
end; 

Некоторые ресурсы

Есть еще некоторые темы для обсуждения (реализация интерфейсов, хранимые значения, RTTI/свойства времени разработки и т. д.), но этот пост стал немного длинным...

Подробнее можно прочитать на этих сайтах:

• http://www.delphibasics.co.uk/RTL.asp?Name=Property
• http://delphi.about.com/od/oopindelphi/a/delphi_oop9.htm
• http://mc-computing.com/languages/Delphi/ComponentProperties.html

Свойства — большое преимущество Delphi. Я сам довольно много работал с Java и Delphi и определенно выбрал бы Properties. Практически оба подхода в конечном итоге будут делать одно и то же, с той лишь разницей, что свойства выглядят НАМНОГО лучше, чем геттеры/сеттеры.

Я предлагаю вам пойти на свойства, и в полной мере воспользоваться ими!

Это действительно дело вкуса и использования.

Для паскаль-программистов совершенно ясно, читаете вы или записываете значение, поэтому я думаю, что код будет более читаемым, если вы не используете геттеры и сеттеры в стиле java, где вы пишете GetXXX или SetXXX в каждом предложении ваша программа.

Для меня, и я предполагаю, что для большинства программистов на Паскале код будет более читаемым, если вы просто укажете имя свойства, которое вы читаете/пишете, и мы все знаем, что будет вызываться метод Getter или Setter (при необходимости) .

Кроме того, я думаю, что огромным преимуществом (и элегантностью) модели свойств delphi является то, что вы можете получить/установить значение свойства непосредственно из поля. Иметь множество методов Get/Set с помощью всего лишь строки кода, где значение назначенное или прочитанное из поля - пустая трата усилий/времени.