как использовать Picture.LoadFromFile() в TcustomContol

Вы должны использовать событие TPicture.OnChange, например:

type
  TSkinPanel = class(TCustomControl)
  private
    FPicture: TPicture;
    procedure PictureChanged(Sender: TObject);
    procedure SetPicture(Value: TPicture);
  protected
    procedure Paint; override;
  public
    constructor Create(Owner: TComponent); override;
    destructor Destroy; override;
  published
    property Picture: TPicture read FPicture write SetPicture;
  end;

  constructor TSkinPanel.Create(Owner: TComponent);
  begin
    inherited;
    FPicture := TPicture.Create;
    FPicture.OnChange := PictureChanged;
  end;

  destructor TSkinPanel.Destroy;
  begin
    FPicture.Free;
    inherited;
  end;

  procedure TSkinPanel.PictureChanged(Sender: TObject);
  begin
    Invalidate;
  end;

  procedure TSkinPanel.SetPicture(Value: TPicture);
  begin
    FPicture.Assign(Value);
  end;

  procedure TSkinPanel.Paint;
  begin
    if (FPicture.Graphic <> nil) and (not FPicture.Graphic.Empty) then
    begin
      // use FPicture as needed...
    end;
  end;

Если вы не получаете ошибки при вызове Picture.LoadFromFile, то, скорее всего, он сработал, но ваш элемент управления просто не реагирует на изменение. Первое, что нужно сделать, это обработать обработчик события Picture.OnChange и сделать что-нибудь: если вы рисуете сами, просто вызовите Invalidate(), если вы используете Picture для настройки какого-то другого элемента управления, который, в свою очередь, выполняет рисование, сделайте соответствующий Assign() fom По изменению.