Prolog - вернуть результат вместо печати в алгоритме

Как и вы, я часто вижу эту закономерность среди новичков в Прологе, особенно если они используют плохие книги и другие материалы:

solve :-
     .... some goals ...
     compute(A),
     write(A).

Почти каждая строка в приведенном выше примере вызывает проблемы по следующим причинам:

1. «решить» обязательно. Это не имеет смысла в декларативном языке, таком как Пролог, потому что вы можете использовать предикаты в нескольких направлениях.
2. «вычислить» также обязательно.
3. write/1 является побочным эффектом, и его вывод доступен только на системном терминале. Это не дает нам простого способа фактически проверить предикат.

Такие шаблоны всегда должны выглядеть примерно так:

solution(S) :-
     condition1(...),
     condition2(...),
     condition_n(S).

где condition1 и т. д. — это просто чистые цели, которые описывают, что означает, что S является решением.

При запросе

?- solution(S).

тогда привязки для S будут автоматически печататься на верхнем уровне. Позвольте верхнему уровню сделать печать за вас!

В вашем случае есть прямое исправление: просто сделайте NewOutput одним из аргументов и удалите последний побочный эффект:

route(X, Y, Lines, Output, NewOutput) :- 
    line(Line, Stations),
    \+ member(Line, Lines),
    member(X, Stations),
    member(Y, Stations),
    append(Output, [[X,Line,Y]], NewOutput).

Также обратите внимание, что я изменил имя на просто route/5, потому что предикат имеет смысл также, если все аргументы уже созданы, что полезно для тестирования и т. д.

Кроме того, при описании списков вы часто получаете большую пользу от использования dcg обозначение.

Код будет выглядеть примерно так:

route(S, S, _) --> [].          % case 1: already there
route(S0, S, Lines) -->         % case 2: needs intermediate stop
    { line_stations(Line, Stations0),
      maplist(dif(Line), Lines),
      select(S0, Stations0, Stations),
      member(S1, Stations) },
    [link(S0,Line,S1)],
    route(S1, S, [Line|Lines]).

Удобно, что вы можете использовать это для описания конкатенации списков, не нуждаясь в append/3 так много. Я также сделал несколько других изменений, чтобы улучшить чистоту и удобочитаемость, и я оставляю выяснение точных различий в качестве простого упражнения.

Вы вызываете это, используя предикат интерфейса DCG phrase/2, используя:

?- phrase(route(X,Y,[]), Rs).

где Rs — найденный маршрут. Заметьте также, что я использую термины формы link/3 для обозначения звеньев маршрута. Хорошей практикой является использование специальных терминов, когда известна арность. Списки хороши, например, если вы заранее не знаете, сколько элементов вам нужно представить.