извлечь значение из массива в xslt

У меня есть переменная TemperatureQualifier, тип которой — массив. Мне нужно прочитать эту переменную массива, извлечь каждое значение из массива и использовать его в моем XSLT.

Пример ввода XML

<document>
<item>
    <gtin>1000909090</gtin>
    <flex>
        <attrGroupMany name="tradeItemTemperatureInformation">
            <row>
                <attr name="temperatureQualifier">[10, 20, 30, 40]</attr>
            </row>

        </attrGroupMany>
    </flex>
</item>
</document>

Желаемый выходной XML должен быть

<?xml version="1.0" encoding="UTF-8"?>
<CatalogItem>
<RelationshipData>
  <Relationship>
     <RelationType>Item_Master_TRADEITEM_TEMPERATURE_MVL</RelationType>
     <RelatedItems>
        <Attribute name="code">
           <Value>10</Value>
        </Attribute>
         <Attribute name="code">
           <Value>20</Value>
        </Attribute>
         <Attribute name="code">
           <Value>30</Value>
        </Attribute>
         <Attribute name="code">
           <Value>40</Value>
        </Attribute>
     </RelatedItems>
  </Relationship>
</RelationshipData>
</CatalogItem>

Я использую приведенный ниже XSLT, но он дает мне все значения только в 1 узле.

<xsl:stylesheet 
version="1.0"
xmlns:xsl="http://www.w3.org/1999/XSL/Transform">

<xsl:output indent="yes"/>


<xsl:template match="document"> 
    <CatalogItem>
        <RelationshipData>
            <Relationship>
                <RelationType>Item_Master_TRADEITEM_TEMPERATURE_MVL</RelationType>  
                <RelatedItems>      


                    <xsl:for-each select="item/flex/attrGroupMany[@name ='tradeItemTemperatureInformation']/row">                       

                        <Attribute name="code">
                            <Value>
                                <xsl:value-of select="attr[@name='temperatureQualifier']"/>
                            </Value>
                        </Attribute>


                    </xsl:for-each>
                </RelatedItems>
            </Relationship>
        </RelationshipData>
    </CatalogItem>

</xsl:template> 

</xsl:stylesheet>

Примечание. Количество значений в массиве может быть 1 или более 1. Примером массива с одним значением является [10].

Пример массива с несколькими значениями: [10, 20, 30, 40]


xslt xslt-1.0 xslt-2.0 xslt-grouping
person Victor    schedule 23.03.2016    source источник
comment
Вы пометили это xslt-2.0, но действительно ли вы можете использовать процессор XSLT 2.0? Если это так, вы сможете использовать функцию tokenize.   -  person Tim C    schedule 23.03.2016

Ответы (2)


arrow_upward
1
arrow_downward

С XST 1.0 вы можете использовать рекурсивное разделение:

<xsl:template name="split">
 <xsl:param name="str" select="."/>
  <xsl:choose>
    <xsl:when test="contains($str, ',')">
       <Attribute name="code">
       <Value>
        <xsl:value-of select="normalize-space(substring-before($str, ','))"/>
      </Value>
      </Attribute>
      <xsl:call-template name="split">
        <xsl:with-param name="str" select="substring-after($str, ',')"/>
      </xsl:call-template>
    </xsl:when>
    <xsl:otherwise>
      <Attribute name="code">
         <Value>
          <xsl:value-of select="$str"/>
        </Value>
      </Attribute>
    </xsl:otherwise>
  </xsl:choose>

</xsl:template>

И назовите это:

          <xsl:call-template name="split">
            <xsl:with-param name="str" select="substring-before(
                                               substring-after(
                                               attr[@name='temperatureQualifier'], '[' )
                                               ,']' )"/>
          </xsl:call-template>
person hr_117    schedule 23.03.2016

arrow_upward
0
arrow_downward

Используя последнюю версию Saxon, вы можете попробовать XSLT 3.0 и

                    <xsl:for-each
                        select="item/flex/attrGroupMany[@name = 'tradeItemTemperatureInformation']/row/attr[@name = 'temperatureQualifier']/json-to-xml(.)//*:number">

                        <Attribute name="code">
                            <Value>
                                <xsl:value-of select="."/>
                            </Value>
                        </Attribute>


                    </xsl:for-each>
person Martin Honnen    schedule 23.03.2016
comment
Извиняюсь!! Я забыл указать, что это было для версии 1.0. В любом случае это решение может помочь другим. Спасибо. - person Victor; 24.03.2016