Используйте атрибут orderBy
в определении свойства отношения:
component name="user" accessors=true persistent=true{
property name="pages" fieldType="one-to-many" cfc="Page" fkColumn="userID" orderBy="date";
}
РЕДАКТИРОВАТЬ
Приведенное выше установит порядок дочерних объектов по умолчанию. Чтобы разрешить другие варианты упорядочения, вы можете создать метод упорядочения страниц в сущности пользователя, используя OrmExecuteQuery()
:
array function pagesOrdered( string column="", string direction="ASC" ){
//use an array to build up the HQL string
var hql=[ "FROM Page WHERE User.ID = :userID" ];
//only allow ordering on specified columns
if( "title,viewcount,updated".ListFindNoCase( arguments.column ) ){
hql.Append( "ORDER BY " & arguments.column );
}
if( arguments.direction IS NOT "ASC" ){
hql.Append( "DESC" );
}
hql=hql.ToList( " " );
return OrmExecuteQuery( hql, { userID: variables.ID } );
}
Или для немного более лаконичного, но менее ортодоксального подхода попробуйте фильтр гибернации:
array function pagesOrdered( string column="", string direction="ASC" ){
//use an array to build up the filter
var filterString=[ "ORDER BY" ];
//only allow ordering on specified columns
if( "title,viewcount,updated".ListFindNoCase( arguments.column ) ){
filterString.Append( arguments.column );
} else {
filterString.Append( "dateCreated" );
}
if( arguments.direction IS "DESC" ){
filterString.Append( "DESC" );
}
return OrmGetSession().createFilter( variables.pages,filterString.ToList( " " ) ).list();
}
person
CfSimplicity
schedule
28.12.2015