Более простой/чистый способ указать диапазоны при использовании большого количества именованных ячеек в VBA?

более удобочитаемый способ -- да. Объявляйте и назначайте объектные переменные по мере необходимости. Как минимум, вы можете определить диапазоны для «GS_BeginData», «SS_Unit» и «SS_BeginData», что сделает ваш код более читабельным и удобным в сопровождении.

Таким образом, если вы когда-нибудь измените имена ссылок на именованные диапазоны, вам нужно будет обновить только несколько коротких строк кода, которые присваиваются исходным объектам, а не каждой литеральной ссылке, например, на "GS_BeginData", и т.п.

Dim GSBegin as Range, SSBegin as Range, SSUnit as Range

Set GSBegin = Range("GS_BeginData")
Set SSBegin = Range("SS_BeginData")
Set SSUnit = Range("SS_Unit")

Затем ваши уродливые ссылки могут быть изменены:

Range(GSBegin.Offset((counter + m), -1), GSBegin.Offset((counter + m), 2))

Range(GSBegin.Offset(counter, 1), GSBegin.Offset((counter + fileCount), 1))

SSUnit.Offset(0, 1)

Range(SSBegin, SSBegin.End(xlDown))

Cells((SSBegin.Row + i), (SSBegin.Column + 1))

1. Используйте переменные! (Dim это небольшая цена)
2. Используйте другие свойства Range. В этих случаях полезно Resize

.

Dim GS_BeginData As Range
Set GS_BeginData = Range("GS_BeginData")
'Set r = Range(Range("GS_BeginData").Offset((counter + m), -1), Range("GS_BeginData").Offset((counter + m), 2))
Set r = GS_BeginData.Offset(counter + m, -1).Resize(, 3)

'Set r = Range(Range("GS_BeginData").Offset(counter, 1), Range("GS_BeginData").Offset((counter + fileCount), 1))
Set r = GS_BeginData.Offset(counter, 1).Resize(fileCount, 1)

Dim SS_Unit As Range
Set SS_Unit = Range("SS_Unit")
'Set r = Range("SS_Unit", Range("SS_Unit").Offset(0, 1))
Set r = SS_Unit.Resize(, 2)
Set r = SS_Unit.Resize(, SS_Unit.Columns.Count + 1) ' if SS_Unit has more than 1 column

Dim SS_BeginData As Range
Set SS_BeginData = Range("SS_BeginData")
'Set r = Range("SS_BeginData", Range("SS_BeginData").End(xlDown))
Set r = Range(SS_BeginData, SS_BeginData.End(xlDown))

'Set r = Cells((Range("SS_BeginData").Row + i), (Range("SS_BeginData").Column + 1))
Set r = SS_BeginData.Offset(i, 1).Resize(1, 1)

Если вы действительно используете его в нескольких разных Subs, вы также можете создать функцию для DRY свой код, например.

Function GSBeginOffsetRange(a As Long, b As Long, c As Long, d As Long) As Range
    Dim GSBegin As Range
    Set GSBegin = Range("GS_BeginData")
    Set GSBeginOffsetRange = Range(GSBegin.Offset(a, b), GSBegin.Offset(c, d))
End Function

Это сделает ваш пример первой строки:

GSBeginOffsetRange((counter + m), -1, (counter + m), 2)

Можете ли вы просто перечислить все Named Rnages, а затем просмотреть каждый элемент в этом списке?

http://www.mrexcel.com/forum/excel-questions/44907-list-out-named-ranges-visual-basic-applications.html

Я не использую именованные диапазоны, потому что их сложно поддерживать, и они быстро превращаются в беспорядок. Я всегда использую эти две функции:

Function RowNumber(Header As String, _
             Optional Sh As Worksheet, _
             Optional FromColumn As Integer = 1, _
             Optional IgnoreError As Boolean = False) As Integer
  If Sh Is Nothing Then Set Sh = ActiveSheet

  Dim R As Integer
  For R = 1 To Sh.UsedRange.Row + Sh.UsedRange.Rows.Count - 1
    If Sh.Cells(R, FromColumn) = Header Then RowNumber = R: Exit Function
  Next R

  If Not IgnoreError Then MsgBox "Row """ & Header & """ not found", vbCritical
End Function

Function ColumnNumber(Header As String, _
             Optional Sh As Worksheet, _
             Optional FromRow As Integer = 1, _
             Optional IgnoreError As Boolean = False) As Integer
  If Sh Is Nothing Then Set Sh = ActiveSheet

  Dim C As Integer
  For C = 1 To Sh.UsedRange.Column + Sh.UsedRange.Columns.Count - 1
    If Sh.Cells(FromRow, C) = Header Then ColumnNumber = C: Exit Function
  Next C

  If Not IgnoreError Then MsgBox "Column """ & Header & """ not found", vbCritical
End Function

Затем я получаю значение с чем-то вроде:

Value = Sh.Cells(RowNumber("Header", Sh), 2)

Иногда я использую другую версию с memoization.