У меня есть два уровня в текстовой сетке, и я хотел бы объединить их в один уровень. Каждый уровень — это отдельный динамик. Интервалы внутри каждого уровня не перекрываются. Это возможно? Я видел много сценариев Praat, которые будут объединяться или объединяться, но ничего, что могло бы их объединить. Я пытался использовать модуль Python tgt для этого, но это было медленно. Я копал некоторое время, поэтому любые предложения о том, как решить эту проблему, очень ценятся! Спасибо.
Праат, объединяющий два яруса в один
Ответы (1)
Некоторое время назад я написал скрипт, который использовался для найти непересекающиеся интервалы, в том числе в ярусах с разными говорящими. Хотя задача отличается, TextGrid, который создает скрипт для работы, можно использовать для того, что вы хотите.
Логика этого сценария заключается в процедуре, которая может быть включенным в любой сценарий, который вы используете (или канибализированы в него, если вам нравятся подобные вещи).
Если вы включите эту процедуру (либо физически скопировав ее, либо include
инг), вы можете сделать
old = selected("TextGrid")
@toNonOverlappingTiers()
new = selected("TextGrid")
После этого new
TextGrid будет иметь один уровень, а все интервалы из других уровней будут «сглажены». Каждый интервал в этом новом уровне с ненулевой меткой будет представлять фрагмент old
TextGrid, содержащийся в помеченных интервалах не более чем на одном уровне. Немаркированные интервалы не содержались ни в одном из помеченных интервалов в old
. Остальные метки сообщают вам номер уровня единственного помеченного интервала, который их содержит.
Итак, после запуска приведенного выше примера вы можете сделать
# Loop through intervals in the new TextGrid
selectObject: new
for i to do("Get number of intervals...", 1)
label$ = Get label of interval: 1, i
# Since your original TextGrid had no overlapping intervals
# you only want labeled intervals (there will be no zeros)
if label$ != ""
# Get the midpoint, to match to intervals in a different
# tier in the original TextGrid
tier = number(label$)
start = Get start point: 1, i
end = Get end point: 1, i
midpoint = ((end - start) / 2) + start
# Get the original label
selectObject: old
j = Get interval at time: tier, midpoint
original$ = Get label of interval: tier, j
# Apply the original label to the new TextGrid
selectObject: new
Set interval text: 1, i, original$
endif
endfor
Для архивных целей:
# This procedure is a part of the tgutils plugin
# Please see http://cpran.net/plugins/tgutils for more details
procedure toNonOverlappingIntervals ()
# Original TextGrid
.tg = selected("TextGrid")
.tiers = Get number of tiers
.start = Get start time
.end = Get end time
# Overlap TextGrid
.id = Create TextGrid: .start, .end, "overlap", ""
# Populate overlap tier with "flattened" intervals from all tiers
for .tier to .tiers
selectObject: .tg
.intervals = Get number of intervals: .tier
for .interval to .intervals-1
selectObject: .tg
.end = Get end point: .tier, .interval
# We use nocheck because there might already be a boundary there
selectObject: .id
nocheck Insert boundary: 1, .end
endfor
endfor
# Cycle through the flattened intervals to check how many spoken intervals
# align with each. A segment in the overlap tier will be considered to have no
# overlap if and only if there is one tier with a speech labeled interval which
# coincides with it.
selectObject: .id
.flat_intervals = Get number of intervals: 1
for .interval to .flat_intervals
.start = Get start point: 1, .interval
.end = Get end point: 1, .interval
.midpoint = (.end - .start) / 2 + .start
# Count how many speakers are speaking over that flattened interval
.speakers = 0
for .tier to .tiers
selectObject: .tg
.interval_number = Get interval at time: .tier, .midpoint
.label$ = Get label of interval: .tier, .interval_number
if .label$ != ""
# Increment the number of speakers for each labeled coinciding interval
# on any tier. We also save the tier number of the (last) speaker, so we
# know where to look for measurements later.
.speakers += 1
.speaker_tier = .tier
endif
endfor
# Label the overlap intervals. Blank intervals are matched by no speakers in
# any tier. Intervals labeled "0" are matched by more than one speaker, in
# more than one tier. The rest contain the tier number of the single speaker
# speaking at that time.
selectObject: .id
if .speakers = 1
Set interval text: 1, .interval, string$(.speaker_tier)
elif .speakers > 1
Set interval text: 1, .interval, "0"
else
Set interval text: 1, .interval, ""
endif
endfor
endproc