Сбой приложения VB.NET 2008 во время выполнения цикла

если ListBox1.Items.Count больше, чем ListBox2.Items.Count - 1, X никогда не будет равно ListBox1.Items.Count, поэтому Exit Do никогда не запустится, и код просто будет бесконечно зацикливаться в

Do While y = 1

Рассматривали ли вы, например, возможность использования Linq для упрощения управления списками?

редактировать: Кроме того, неправильно удалять элемент из списка, который вы просматриваете, с помощью for (совершенно незаконно делать это с помощью For Each), потому что каждое удаление будет смещать счетчик цикла.

edit2: вот фрагмент Linq, который выполняет задачу:

    Dim itemsFirst = (From item As String In ListBox1.Items Select item)
    Dim itemsSecond = (From item As String In ListBox2.Items Select item)

    Dim dupes = System.Linq.Enumerable.Intersect(itemsFirst, itemsSecond).ToList
    For Each item In dupes
        ListBox1.Items.Remove(item)
        ListBox2.Items.Remove(item)
    Next item

то, что он делает, в основном извлекает строки из обоих списков (это необходимо, потому что коллекция ListBox.Items немного странная)

После этого мы запускаем метод пересечения и копируем результаты в список. (часть .ToList) Копирование является обязательной частью, потому что в противном случае дубликаты были бы просто подмножеством элементов ListBox, и мы снова попытались бы подняться, потянув за шнурки.

Последняя часть представляет собой простой цикл удаления, который удаляет элементы из коллекции.

у тебя есть

ElseIf x = ListBox1.Items.Count Then
    Exit Do

когда это должно быть

ElseIf x = ListBox1.Items.Count - 1 Then
    Exit Do

потому что ваш цикл for изменит X на count, а затем выйдет без повторения этого значения.

И не только это, но почему вообще существует цикл Do? Нет необходимости повторять один и тот же внутренний список в поисках дубликатов, не так ли?

И в-третьих, вы не должны удалять вещи, пока вы их перебираете. В вашем случае циклы for повторно используют count, поэтому это «безопасно», но операция удаления будет переиндексировать вещи, поэтому вы должны вычесть 1 из ваших итераторов i и x при удалении, чтобы следующий не был пропущен при переиндексации .

Если подумать, может быть, вы поместили туда этот цикл Do, чтобы покрыть элементы, пропущенные в предыдущий раз, как упоминалось в моем третьем пункте.

Если вы используете Visual Studio 2008 или более позднюю версию:

Dim dupes = Listbox1.Items.Cast(Of String)().Intersect(Listbox2.Items.Cast(Of String)()).ToArray() 
For Each item As String in dupes
    Listbox1.Items.Remove(item)
    Listbox2.Items.Remove(item)
Next item

Я проверил три разных метода. Это Джоэлс, Свеко и мой. Я делал это для проверки производительности, но обнаружил, что результаты разные, списки разные. Вот код, который я использовал для тестирования, так что вы можете судить. Наверное, какая-то глупая ошибка с моей стороны.

Dim stpw As New Stopwatch

Private Sub Button1_Click(ByVal sender As System.Object, _
                          ByVal e As System.EventArgs) Handles Button1.Click
    Debug.WriteLine("")
    loadLBTD() ''#load test data

    doSTPW("Test 1 Start", False) ''#mine
    ''#get rid of dupes <<<<<<<<<<<<<<
    Dim dupeL As New List(Of String)
    For x As Integer = ListBox1.Items.Count - 1 To 0 Step -1
        If ListBox2.Items.Contains(ListBox1.Items(x)) Then
            dupeL.Add(ListBox1.Items(x))
            ListBox1.Items.RemoveAt(x)
        End If
    Next
    For Each s As String In dupeL
        ListBox2.Items.Remove(s)
    Next
    doSTPW("Test 1 End")

    loadLBTD() ''#load test data

    doSTPW("Test 2 Start", False) ''#sweko
    ''#get rid of dupes <<<<<<<<<<<<<<
    ''#I had to set Option Strict to Off to get this to work <<<<<<<
    Dim itemsFirst = (From item As String In ListBox1.Items Select item)
    Dim itemsSecond = (From item As String In ListBox2.Items Select item)

    Dim dupes = System.Linq.Enumerable.Intersect(itemsFirst, itemsSecond).ToList
    For Each item In dupes
        ListBox1.Items.Remove(item)
        ListBox2.Items.Remove(item)
    Next item
    doSTPW("Test 2 End")

    loadLBTD() ''#load test data

    doSTPW("Test 3 Start", False) ''#joel
    ''#get rid of dupes <<<<<<<<<<<<<<
    Dim dupes2 = ListBox1.Items.Cast(Of String)().Intersect(ListBox2.Items.Cast(Of String)()).ToArray()
    For Each item As String In dupes2
        ListBox1.Items.Remove(item)
        ListBox2.Items.Remove(item)
    Next item
    doSTPW("Test 3 End")
End Sub

Private Sub doSTPW(ByVal someText As String, Optional ByVal showTM As Boolean = True)
    stpw.Stop() ''#stop the clock
    If flip Then Debug.Write("'T ") Else Debug.Write("'F ")
    Debug.Write("LBCnts " & ListBox1.Items.Count & " " & ListBox2.Items.Count)
    Dim s As String
    If showTM Then
        s = String.Format("  {0}  {1}", someText, stpw.ElapsedTicks.ToString("N0"))
    Else
        s = String.Format("  {0}", someText)
    End If
    Debug.WriteLine(s)
    stpw.Reset() ''#reset and start clock
    stpw.Start()
End Sub

Dim flip As Boolean = False
Private Sub loadLBTD()
    ''#Create test data 
    Dim tl1() As String = New String() {"A", "X", "y", "z", "B", "w", "X", "y", "z"}
    Dim tl2() As String = New String() {"A", "y", "z", "Q", "A", "y", "z", "Q", "A", "y", "z", "Q"}
    ListBox1.Items.Clear()
    ListBox2.Items.Clear()
    ''#load listboxes
    If flip Then
        ListBox1.Items.AddRange(tl2)
        ListBox2.Items.AddRange(tl1)
    Else
        ListBox1.Items.AddRange(tl1)
        ListBox2.Items.AddRange(tl2)
    End If
    ''#end of test data setup
End Sub

Кроме того, как и ожидалось, LINQ более лаконичен, но медленнее. Если код используется нечасто, это не имеет значения. У меня был неудачный опыт работы с LINQ и решетом Эратосфена.