опубликовать параметры с помощью groovy httpbuilder в mailgun

Я пытаюсь вызвать API отправки сообщения mailgun. Следующий код работает, если я передаю параметры вместе с URL-адресом:

String targetUrl = "https://api.mailgun.net/v2/my_domain_name/messages?from=fromAddress&to=toAddress&subject=sub&text=random+message"

Но когда я пытаюсь добавить эти параметры в тело, это не работает. Я продолжаю получать плохие запросы от mailgun. -

String targetUrl = "https://api.mailgun.net/v2/my_domain_name/messages
body = [from:"fromAddress", to:"toAddress", subject:"sub", text:"random message"]

Вот полный код -

def sendEmail(String mailBody, String sub, String toIds) {
    String targetUrl = "https://api.mailgun.net/v2/my_domain_name/messages"
    def http = new HTTPBuilder(targetUrl)

    http.request( groovyx.net.http.Method.POST, groovyx.net.http.ContentType.JSON) {

        body = [from:"fromAddress", to:"toAddress", subject:"sub", text:"random message"]

        headers = ['Authorization':"Basic " + "api:my_api_key".bytes.encodeBase64().toString()]

        response.success = { resp, reader ->
            println "valid response: " + reader
        }
    }
}

Спасибо!


groovy mailgun httpbuilder
person saurabh    schedule 28.03.2015    source источник
comment
Не могу найти документы, но вы отправляете параметры запроса в виде тела, это неправильно - используйте параметры запроса. Насколько я помню, его нужно отправлять как карту params, просто измените body на params.   -  person Opal    schedule 28.03.2015
comment
@Opal Вот что я тоже сначала подумал. Я попробовал параметры вместо тела. Но похоже, что у httpbuilder нет свойства с именем params.   -  person saurabh    schedule 28.03.2015
comment
Попробуйте uri.query = <map with params>.   -  person Opal    schedule 28.03.2015

Ответы (1)


arrow_upward
4
arrow_downward

Ваш код не работает, потому что вы сообщаете HTTPBuilder, что параметры запроса закодированы в JSON

http.request(Method.POST, ContentType.JSON)

так что вы кодируете свои параметры в теле запроса в JSON, а mailgun API ожидает их с Content-Type: application/x-www-form-urlencoded.

curl -s --user 'api:YOUR_API_KEY' \
    https://api.mailgun.net/v2/YOUR_DOMAIN_NAME/messages \
    -F from='Excited User <mailgun@YOUR_DOMAIN_NAME>' \
    -F to=YOU@YOUR_DOMAIN_NAME \
    -F [email protected] \
    -F subject='Hello' \
    -F text='Testing some Mailgun awesomness!'

Вы можете увидеть это, используя как targetURL http://echo.httpkit.com, который возвращает HTTP-запрос в формате JSON. .

Делая это, он дает:

{
    "body": "\"from\":\"fromAddress\",\"to\":\"toAddress\",\"subject\":\"sub\",\"text\":\"random message\"}",
"docs": "http://httpkit.com/echo",
[...]

Таким образом, вы должны использовать ContentType.URLENC вместо ContentType.JSON (и, возможно, использовать заголовок Accept для типа application/json):

import groovy.json.*

import groovyx.net.*
import groovyx.net.http.*

import static groovy.json.JsonOutput.*

import static groovyx.net.http.ContentType.*
import static groovyx.net.http.Method.*

String targetUrl = 'http://echo.httpkit.com'
def http = new HTTPBuilder(targetUrl)

http.request(POST) {
    uri.path = '/'
    requestContentType = URLENC

    body = [from: 'fromAddress', to: 'toAddress', subject: 'sub', text: 'random message']

    headers.'Authorization' = "Basic " + "api:my_api_key".bytes.encodeBase64().toString()
    headers.'Accept' = 'application/json'

    response.success = { resp, json ->
        println prettyPrint(toJson(json))
    }
}

Это дает этот ответ «эхо» (т. Е. Отправлен запрос POST с параметрами, закодированными в urlencode):

{
    "body": "from=fromAddress&to=toAddress&subject=sub&text=random+message",
    "docs": "http://httpkit.com/echo",
    "headers": {
        "accept": "application/json",
        "authorization": "Basic YXBpOm15X2FwaV9rZXk=",
        "content-length": "61",
        "content-type": "application/x-www-form-urlencoded",
        "host": "echo.httpkit.com",
        "x-forwarded-for": "195.235.15.200"
    },
    "ip": "127.0.0.1",
    "method": "POST",
    "path": {
        "name": "/",
        "params": {

        },
        "query": ""
    },
    "powered-by": "http://httpkit.com",
    "uri": "/"
}
person jalopaba    schedule 30.03.2015