AS3 Как объявить объект без страшной ошибки Conflict Exists?

Отказ от ответственности: мой AS3 немного заржавел ;)

Какого типа будет переменная Pow после оператора switch? objectOne или objectTwo? С точки зрения компилятора objectOne и objectTwo могут полностью отличаться друг от друга (читай: методы, поля,...)

Итак:
A) Сохранить имя переменной для обоих назначений, но объявить его перед оператором switch И использовать общий базовый тип (object, MovieClip,...)
B) Иметь 2 разные переменные: var PowOne: objectOne и var PowTwo: objectTwo

Я думаю, что вариант А был бы предпочтительнее...

Помимо ошибки компилятора, с которой вы столкнулись, еще одна проблема заключается в том, что вы планируете использовать переменную pow позже в своем коде, хотя они относятся к разным типам. Я предлагаю использовать преимущества наследования в ООП и создать базовый класс, от которого могут наследоваться ваши два пользовательских класса. Таким образом, они оба технически относятся к одному и тому же базовому типу, но при этом дают вам свободу настраивать каждый пользовательский класс, сохраняя при этом аналогичную функциональность в базовом классе.

Помните, ООП здесь, чтобы всегда помочь вам и избежать проблем, подобных той, с которой вы столкнулись, но вот как я бы это сделал, и я протестировал следующую реализацию во Flash CC 2014, и она успешно скомпилирована:

Пример .FLA:

var pow:BaseClass;
var power = 1;

switch(power){
    case 1:
        pow = new ObjectOne();
        break;
    case 2:
        pow = new ObjectTwo();
        break;
}

pow.whichObjectAmI();    // this will simply trace what object pow is

Базовый класс

package  {

    public class BaseClass {

        public function BaseClass() {
            // constructor code
        }

        public function whichObjectAmI() {
            trace("I am the base class");
        }

    }

}

Объект первый

package  {

    public class ObjectOne extends BaseClass {

        public function ObjectOne() {
            // constructor code
        }

        override public function whichObjectAmI() {
            trace("I am Object One!");
        }

    }

}

Объект второй

package  {

    public class ObjectTwo extends BaseClass {

        public function ObjectTwo() {
            // constructor code
        }

        override public function whichObjectAmI() {
            trace("I am Object Two!");
        }

    }

}

Вы всегда можете наследовать от любого из классов ActionScript, таких как MovieClip, Button и т. д. И тем самым вы добавляете пользовательские функции поверх их функций, поэтому 1) вам не нужно перестраивать кучу функций и 2) дает вам возможность повторно использовать их функциональность, добавляя свой собственный код!