Передача выделенного C_PTR в массив Fortran на C

Переменная HESS_COPY - это локальная несохраненная переменная, доступная для размещения в процедуре Fortran GET_POINTER_IN_C.

Следовательно, всякий раз, когда процедура начинает выполнение, она всегда не распределяется. Таким образом, проверка его статуса распределения в первом исполняемом операторе этой процедуры является излишней.

Следовательно, также в конце выполнения процедуры эта несохраненная локальная переменная автоматически освобождается. Таким образом, ссылка C_LOC ближе к концу процедуры получает адрес объекта, который вот-вот прекратит свое существование.

Затем код C работает с адресом несуществующего объекта, и программа терпит неудачу.

Если переменная HESS_COPY была сохранена как локальная или сохраненная переменная модуля, она продолжала бы существовать между вызовами процедур.

(Все переменные модуля сохраняются, начиная с Fortran 2008, предыдущие языковые версии формально требовали явной специфики SAVE для соответствующих переменных модуля, если на модуль не постоянно ссылались в активной области.)

(Кстати, правила языка, начиная с Fortran 2003, также означают, что выделенный тест, оператор выделения и последующее присваивание можно просто заменить одним оператором HESS_COPY = HESS.)

Кроме того, в коде C делается попытка вернуть информацию в указателе, который не существует. В исходном коде hessian объявлен как указатель на указатель на double - обратите внимание на два уровня косвенности. Без какой-либо инициализации первый уровень косвенного обращения будет указывать «случайным образом» в памяти, а затем код Fortran будет пытаться сохранить свой результат в этом случайном месте.

В качестве альтернативы рассмотрите:

#include <stdio.h>

void get_pointer(double ** hessian);

void print_hess(int *arr_size) {
   // A pointer to double (one level of indirection).
   double *hessian;

   // Pass the address of that pointer.
   get_pointer(&hessian);

   // print the value of the double being pointed at.
   printf("%8.3f\n", *hessian);

   // print the value of the next double in the array
   // (assuming that there is more than one).
   printf("%8.3f\n", *(hessian+1));
   // (or equivalently, `hessian[1]`)
}

Метод указателя Fortran, на который ссылается Владимир Ф в комментариях, требует двух процедур Fortran: одна аналогична той, что у вас есть, которая выделяет указатель Fortran и копирует данные, а вторая освобождает этот указатель. Каждый вызов процедуры выделения должен соответствовать соответствующему вызову процедуры освобождения, передавая тот же указатель. Что-то вроде:

   SUBROUTINE GET_POINTER(ARRAY_PTR) BIND(C, NAME='get_pointer')
   !  C signature: void get_pointer(double **);
      USE, INTRINSIC :: ISO_C_BINDING, ONLY: C_LOC, C_PTR, C_DOUBLE

      TYPE(C_PTR), INTENT(OUT) :: ARRAY_PTR
      REAL(C_DOUBLE), POINTER :: HESS_COPY(:,:)

      ! See also the SOURCE= specifier.
      ALLOCATE(HESS_COPY(SIZE(HESS,1), SIZE(HESS,2))
      HESS_COPY = HESS
      ARRAY_PTR = C_LOC(HESS_COPY)
   END SUBROUTINE GET_POINTER

   SUBROUTINE RELEASE_POINTER(ARRAY_PTR) BIND(C, NAME='release_pointer')
   ! C signature: void release_pointer(double*);
     USE, INTRINSIC :: ISO_C_BINDING, ONLY: C_PTR, C_F_POINTER, C_DOUBLE

     TYPE(C_PTR), INTENT(IN), VALUE :: ARRAY_PTR
     REAL(C_DOUBLE), POINTER :: HESS_COPY(:,:)

     CALL C_F_POINTER(ARRAY_PTR, HESS_COPY, SHAPE(HESS))
     DEALLOCATE(HESS_COPY)
   END SUBROUTINE RELEASE_POINTER