Свойство DoubleBuffered, добавляемое в dfm в Delphi 2009, не существует в Delphi 2007

да. Это невозможно, если вы не удалите из DFM свойства, не опубликованные в Delphi 2007.

DoubleBuffered уже некоторое время присутствует в TWinControl. Отличие Delphi 2009 в том, что он опубликован сейчас. Если вы можете жить, игнорируя только ошибки (и не заставляя вместо этого работать свойства), вот возможное решение:

unit Delphi2009Form;

interface

uses
  Windows, Classes, SysUtils, Controls, Forms;

type
{$IFDEF VER200}
  TDelphi2009Form = class(TForm);
{$ELSE}
  TDelphi2009Form = class(TForm)
  private
    procedure ReaderError(Reader: TReader; const Message: string; var Handled: Boolean);
  protected
    procedure ReadState(Reader: TReader); override;
  end;

  TReaderErrorProc = procedure(const Message: string);

var
  ReaderErrorProc: TReaderErrorProc = nil;
{$ENDIF}

implementation

{$IFNDEF VER200}
type
  THackReader = class(TReader);

procedure TDelphi2009Form.ReaderError(Reader: TReader; const Message: string; var Handled: Boolean);
begin
  with THackReader(Reader) do
    Handled := AnsiSameText(PropName, 'DoubleBuffered') or AnsiSameText(PropName, 'ParentDoubleBuffered');
  if Handled and Assigned(ReaderErrorProc) then
    ReaderErrorProc(Message);
end;

procedure TDelphi2009Form.ReadState(Reader: TReader);
begin
  Reader.OnError := ReaderError;
  inherited ReadState(Reader);
end;
{$ENDIF}

end.

Затем измените объявления форм в вашем проекте, чтобы они унаследовали от TDelphi2009Form, например:

type
  TFormMain = class(TDelphi2009Form)
  ...

Это будет работать во время выполнения - ошибки свойств будут проигнорированы. Чтобы он работал и во время разработки, создайте пакет только для дизайна, добавьте designide.dcp в его раздел requires и добавьте к нему следующий модуль:

unit Delphi2009FormReg;

interface

uses
  Delphi2009Form;

procedure Register;

implementation

uses
  DesignIntf, DesignEditors, ToolsAPI;

procedure ShowReaderError(const Message: string);
begin
  with BorlandIDEServices as IOTAMessageServices do
    AddTitleMessage(Message);
end;

procedure Register;
begin
  RegisterCustomModule(TDelphi2009Form, TCustomModule);
  ReaderErrorProc := ShowReaderError;
end;

initialization

finalization
  ReaderErrorProc := nil;

end.

Установите пакет в IDE Delphi 2007, и ошибки свойств для свойств DoubleBuffered и ParentDoubleBuffered будут автоматически игнорироваться при открытии форм в среде IDE. Значения свойств будут потеряны при сохранении формы в Delphi 2007, поэтому вместо этого вам следует инициализировать их в коде.

РЕДАКТИРОВАТЬ: я добавил код для вывода сообщений об ошибках читателя в окно сообщений IDE:

Проекты Delphi всегда было очень легко переносить на новые версии. Вы должны быть более осторожными, но использовать текущий код со старыми компиляторами тоже довольно просто. Я поддерживал код в Delphi 2005/2006/2007, который другим людям все еще нужно было использовать в Delphi 6 и 7.

Если вы удалите несовместимые свойства из DFM, они должны правильно работать в более старых версиях, не портя их для Delphi 2009. Самым ярким примером являются явные * свойства, представленные в Delphi 2006. У меня есть домашний «скруббер DFM», который удаляет их. вне. Помните, что эти свойства существуют по какой-то причине, поэтому вы должны очищать только те, которые вы хотите обеспечить обратной совместимостью.

Вы также можете подумать об инвестициях в инструменты статического анализа кода, такие как CodeHealer или Pascal Analyzer. Помимо выявления проблем (особенно CodeHealer) и помощи в очистке кода, вы можете выбрать, с какой версией Delphi анализировать, что упрощает поиск несовместимостей, помимо свойств DFM. И их можно автоматизировать как часть процесса сборки.

Просто примечание. Поделитесь исходным кодом, но сохраните отдельные проекты для каждой версии. Это особенно важно между Delphi 2007 и Delphi 2009. Более поздний файл .dproj использует то же расширение, но несовместим с Delphi 2007. Вы также можете столкнуться с некоторыми проблемами с несовместимыми ресурсами.

У каждой формы есть файл dfm, который содержит настройки свойств формы и ее компонентов. Некоторые значения свойств имеют значения по умолчанию, поэтому они не сохраняются, если сохраняется значение по умолчанию. Просто сделал небольшой тест:

• Создать форму в 2009 году
• Добавьте пару стандартных элементов управления
• Сохрани это
• Откройте его в 2006 году (извините, на этом компьютере нет 2007 года)

И это работало без сообщений. Но может тебе не так повезло.

В Delphi обмен данными между версиями часто затруднен. Возможности обновления - это здорово, но переход на более раннюю версию проблематичен. Поэтому я не рекомендую делиться файлами форм между разными версиями.

Насколько мне известно, добавить условные определения в файл dfm невозможно. Но опять же, действительно ли мы этого хотим ... Я бы предпочел механизм, который игнорирует неизвестные свойства.

Вы можете безопасно добавить свойства в код в методе OnCreate для формы и обернуть их {$ IFDEF VER200} // NEW PROPERTIES {$ ENDIF} вокруг них. Вы можете оставить DoubleBuffered вне ifdefs, как это было в Delphi 2007, просто недоступным для инспектора свойств.

Вам придется беспокоиться ТОЛЬКО о свойствах, которые вы установили отличными от значений по умолчанию. Для doublebuffered вам нужно беспокоиться об этом, только если для него установлено значение true.

При загрузке формы Delphi 2009 в Delphi 2007 вы получите предупреждение о том, что свойство будет уничтожено, просто запишите эти свойства, так как это те, с которыми вам нужно будет иметь дело.

Я использую именно такой метод для переноса моего кода на Delphi 2009 из Delphi 2006. Большинство моих проектов содержат несколько общих модулей и должны компилироваться в Delphi 2006 для поставляемой версии и Delphi 2009 для «следующей» версии. Я также часто использую определение {$ IFDEF UNICODE}, где мне нужно гарантировать, что строка является широкой строкой или строкой ответа, в зависимости от процедуры.