Как использовать XSLT для создания страниц разного размера для файла XML?

Я дошел до того, что вставил статический номер страницы, используя следующий XSL

Я не вижу этого нигде в таблице стилей, которую вы разместили. Предполагая, что под нумерацией страниц вы подразумеваете присвоение каждой записи номера страницы, попробуйте:

XSLT 1.0

<?xml version="1.0" encoding="utf-8"?>
<xsl:stylesheet version="1.0"
xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output method="xml" version="1.0" encoding="UTF-8" indent="yes"/>

<xsl:param name="pagesize" select="25" />

<xsl:key name="record" match="record" use="@poNumber" />

<xsl:template match="/data">
    <xsl:copy>
        <xsl:copy-of select="@*" />  
            <xsl:call-template name="paginate">
                <xsl:with-param name="orders" select="record[@total=1]"/>
                <xsl:with-param name="page" select="1"/>
                <xsl:with-param name="existing-lines" select="0"/>
        </xsl:call-template>    
    </xsl:copy>
</xsl:template>

<xsl:template name="paginate">
    <xsl:param name="orders" />
    <xsl:param name="page"/>
    <xsl:param name="existing-lines"/>
    <xsl:param name="current-order-records" select="key('record', $orders[1]/@poNumber)"/>
    <xsl:param name="added-lines" select="count($current-order-records)"/>
    <xsl:choose>
        <xsl:when test="$existing-lines + $added-lines > $pagesize">
            <xsl:call-template name="paginate">
                <xsl:with-param name="orders" select="$orders"/>
                <xsl:with-param name="page" select="$page + 1"/>
                <xsl:with-param name="existing-lines" select="0"/>
            </xsl:call-template>
        </xsl:when>
        <xsl:otherwise>
            <xsl:for-each select="$current-order-records">
                <record page="{$page}">
                    <xsl:copy-of select="@*"/>  
                </record>
            </xsl:for-each>
            <xsl:if test="count($orders) > 1">
                <xsl:call-template name="paginate">
                    <xsl:with-param name="orders" select="$orders[position() > 1]"/>
                    <xsl:with-param name="page" select="$page"/>
                    <xsl:with-param name="existing-lines" select="$existing-lines + $added-lines "/>
                </xsl:call-template>
            </xsl:if>
        </xsl:otherwise>
    </xsl:choose>
</xsl:template>

</xsl:stylesheet>

Ваш ввод слишком мал, чтобы проверить это, поэтому... Обратите внимание, что это приведет к сбою, если какой-либо poNumber имеет более 25 записей.

Редактировать:

Создать элемент-контейнер для каждой страницы значительно сложнее: потребуется проход предварительной обработки. Пытаться:

<?xml version="1.0" encoding="utf-8"?>
<xsl:stylesheet version="1.0"
xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
xmlns:exsl="http://exslt.org/common"
extension-element-prefixes="exsl">
<xsl:output method="xml" version="1.0" encoding="UTF-8" indent="yes"/>

<xsl:param name="pagesize" select="25" />

<xsl:key name="record" match="record" use="@poNumber" />
<xsl:variable name="root" select="/" />

<xsl:template match="/data">
    <!-- first-pass -->
    <xsl:variable name="index">
        <xsl:call-template name="paginate">
            <xsl:with-param name="orders" select="record[@total=1]"/>
            <xsl:with-param name="page" select="1"/>
            <xsl:with-param name="existing-lines" select="0"/>
        </xsl:call-template>    
    </xsl:variable>
    <xsl:variable name="index-entry" select="exsl:node-set($index)/entry" />
    <!-- output -->
    <xsl:copy>
        <xsl:copy-of select="@*" />  
        <xsl:for-each select="$index-entry[@page-start='true']">
            <record jsxid="{@page}">
                <xsl:variable name="poNumbers" select="$index-entry[@page=current()/@page]/@poNumber" />
                <xsl:for-each select="$root">
                    <xsl:copy-of select="key('record', $poNumbers)"/>
                </xsl:for-each>
            </record>
        </xsl:for-each>
    </xsl:copy>
</xsl:template>

<xsl:template name="paginate">
    <xsl:param name="orders" />
    <xsl:param name="page"/>
    <xsl:param name="existing-lines"/>
    <xsl:param name="current-order-records" select="key('record', $orders[1]/@poNumber)"/>
    <xsl:param name="added-lines" select="count($current-order-records)"/>
    <xsl:choose>
        <xsl:when test="$existing-lines + $added-lines > $pagesize">
            <xsl:call-template name="paginate">
                <xsl:with-param name="orders" select="$orders"/>
                <xsl:with-param name="page" select="$page + 1"/>
                <xsl:with-param name="existing-lines" select="0"/>
            </xsl:call-template>
        </xsl:when>
        <xsl:otherwise>
            <entry page="{$page}" page-start="{$existing-lines = 0}">
                <xsl:copy-of select="$orders[1]/@*"/> 
            </entry>
            <xsl:if test="count($orders) > 1">
                <xsl:call-template name="paginate">
                    <xsl:with-param name="orders" select="$orders[position() > 1]"/>
                    <xsl:with-param name="page" select="$page"/>
                    <xsl:with-param name="existing-lines" select="$existing-lines + $added-lines "/>
                </xsl:call-template>
            </xsl:if>
        </xsl:otherwise>
     </xsl:choose>
</xsl:template>

</xsl:stylesheet>

Редактировать 2:

Чтобы рассчитать минимальный размер страницы в соответствии с требованиями самого крупного заказа на покупку, добавьте это на верхний уровень вашей таблицы стилей (вне любого шаблона):

<xsl:variable name="largestPO">
    <xsl:for-each select="/data/record[@total = 1]">
        <xsl:sort select="count(key('record', @poNumber))" data-type="number" order="descending"/>
        <xsl:if test="position()=1">
            <xsl:value-of select="count(key('record', @poNumber))" />  
        </xsl:if>
    </xsl:for-each>
</xsl:variable>

Теперь вам просто нужно сравнить это с размером страницы по умолчанию и выбрать больший из двух.