Разбор выходных данных dig, экспорт csv

#!/usr/bin/awk -f
BEGIN { OFS = "," }
/^;; flags:/ {
    sub(/;; flags: /, "")
    sub(/;.*$/, "")
    $1 = $1
    flags = "," $0
    next
}
/^;/ || NF < 5 { next }
!($1 in a) {
    keys[++k] = $1
}
{
    t = $5
    sub(/[.][ \t\r]*$/, "", t)
    a[$1] = a[$1] "," t
}
END {
    for (i = 1; i <= k; ++i) {
        key = keys[k]
        t = key
        sub(/[.][ \t\r]*$/, "", t)
        print t flags a[key]
    }
}

Использование:

dig @ns1.hosangit.com djzah.com +noall +authority +comments | awk -f script.awk

Контрольная работа:

awk -f script.awk sample

Выход:

djzah.com,qr,aa,rd,ns3.eventguyz.com,ns1.eventguyz.com,ns2.eventguyz

• BEGIN { OFS = "," }: Каждый раздел в awk всегда запускается каждый раз при обработке записи. Блок BEGIN запускается только один раз при запуске. Это в основном устанавливает OFS в ,.
• /^;; flags:/ соответствует ;; flags:. Представленный им раздел в основном извлекает флаги из записи (строки). Команды sub в основном удаляют из записи ненужные части. $1 = $1 просто следит за тем, чтобы $0 обновлялся с помощью OFS. flags = "," $0 присваивает разделенные запятыми флаги переменной flags. next заставляет awk перейти к следующей записи.
• /^;/ || NF < 5 { next } в основном заставляет awk пропускать ненужные строки.
• !($1 in a) { keys[++k] = $1 } если $1 например. djzah.com. встречается впервые, добавьте в массив ключей.
• { t = $5; sub(/[.][ \t\r]*$/, "", t); a[$1] = a[$1] "," t } добавляет значение 5-го столбца, например. ns3.eventguyz.com в коллекцию с удаленным ведущим ..
• По завершении обработки выполняется блок END. Он перебирает найденные ключи и печатает связанные с ним данные.