Как обрабатывать 3 файла с помощью awk?

Обновление: приведенное ниже решение работает, если все входные файлы не пусты, но см. @Ed Morton answer для более простого и надежного способа добавления обработки файлов.

Тем не менее, этот ответ по-прежнему дает, надеюсь, полезное объяснение некоторых awk основ и почему подход ОП не сработал.

Попробуйте следующее (обратите внимание, что я сделал индексы на основе 1, так как это делает awk):

awk '

 # Increment the current-file index, if a new file is being processed.
 FNR == 1 { ++fIndex }

 # Process current line if from 1st file.
 fIndex == 1 {
    print "file 1: " FILENAME
    next
 }

 # Process current line if from 2nd file.
 fIndex == 2 {
    print "file 2: " FILENAME
    next
 }

 # Process current line (from all remaining files).
 {
    print "file " fIndex ": " FILENAME
 }

' file-1 file-2 file-3

• Шаблон FNR==1 истинен всякий раз, когда начинает обрабатываться новый входной файл (FNR содержит номер строки относительно входного файла).

• Каждый раз, когда начинается обработка нового файла, fIndex увеличивается и, таким образом, отражает отсчитываемый от 1 индекс текущего входного файла. Подсказка к полезному ответу @twalberg.

  • Note that an uninitialized awk variable used in a numeric context defaults to 0, so there's no need to initialize fIndex (unless you want a different start value).

• Затем шаблоны, такие как fIndex == 1, можно использовать для выполнения блоков строк только из определенного входного файла (при условии, что блок заканчивается на next).
• Затем последний блок выполняется для всех входных файлов, которые не имеют файловых блоков (см. выше).

Что касается почему ваш подход не сработал:

• Ваши 2-й и 3-й блоки потенциально выполняются безоговорочно для строк из всех входных файлов, поскольку им не предшествует шаблон (условие).

• Таким образом, ваш 2-й блок вводится для строк из всех последующих входных файлов, а его оператор next затем предотвращает доступ к 3-му блоку.

Возможные заблуждения:

• Возможно, вы думаете, что каждый блок функционирует как цикл, обрабатывающий один входной файл. awk работает НЕ так. Вместо этого вся awk программа обрабатывается в цикле, при этом каждая итерация обрабатывает одну входную строку, начиная со всех строк из файла 1, затем из файла 2, .. .

• Программа awk может иметь любое количество блоков (обычно им предшествуют шаблоны), и то, выполняются ли они для текущей входной строки, определяется исключительно тем, является ли шаблон истинным; если шаблона нет, блок выполняется безоговорочно (для всех входных файлов). Однако, как вы уже обнаружили, next внутри блока можно использовать для пропуска последующих блоков (пар шаблон-блок).

Если у вас есть gawk, просто протестируйте ARGIND:

awk '
ARGIND == 1 { do file 1 stuff; next }
ARGIND == 2 { do file 2 stuff; next }
' file1 file2

Если у вас нет gawk, получите его.

В других awks вы можете просто проверить имя файла:

awk '
FILENAME == ARGV[1] { do file 1 stuff; next }
FILENAME == ARGV[2] { do file 2 stuff; next }
' file1 file2

Это не работает, только если вы хотите дважды проанализировать один и тот же файл, в этом случае вам нужно добавить количество раз, когда этот файл был открыт.

Возможно, вам нужно подумать о добавлении некоторой дополнительной структуры, подобной этой:

BEGIN { file_number=1 }
FNR==1 { ++file_number }
file_number==3 && /something_else/ { ...}