ДАЛЬНЕЙШЕЕ УТОЧНЕНИЕ: Как правильно писать операторы Try..Finally..Except?

Код, который вы опубликовали, кажется, работает нормально, потому что вы можете обрабатывать все возможности. Попробуйте немного изменить его, чтобы возникло исключение, которое не обрабатывается вашим кодом:

procedure TForm1.Button1Click(Sender: TObject);
begin
  try
    try
      raise Exception.Create('42');
    except
      on E: EDivByZero do
        ShowMessage('DivByZero');
    end;
  finally
    ShowMessage('Finally');
  end;
  ShowMessage('Got here');
end;

Запустите это, и вы увидите Finally, затем исключение для 42, но нет сообщения Got here. Это связано с тем, что исключение вывело вас из текущего блока, стек разматывается, а код от end до конца процедуры никогда не выполняется.

Переместите последний вызов ShowMessage с того места, где он находится, внутрь finally и запустите снова.

procedure TForm1.Button1Click(Sender: TObject);
begin
  try
    try
      raise Exception.Create('42');
    except
      on E: EDivByZero do
        ShowMessage('DivByZero');
    end;
  finally
    ShowMessage('Finally');
    ShowMessage('Got here');
  end;
  ShowMessage('Will never get here');
end;

Теперь вы увидите оба вызова ShowMessage в блоке finally, один за другим, но не вызовы после end; блока finally. Код внутри блока finally будет выполняться гарантированно, а код за его пределами может или не может.

Чтобы было еще понятнее, наличие блока try..except можно убрать:

procedure TForm1.Button1Click(Sender: TObject);
begin
  try
    raise Exception.Create('42');
  finally
    ShowMessage('Finally');
    ShowMessage('Got here');
  end;
  ShowMessage('Will never get here');
end;

Вся цель блока try..finally - обеспечить выполнение кода внутри раздела finally до завершения процедуры.

В Delphi блок finally на самом деле не обрабатывает исключение, которое произошло в блоке try. Это только гарантирует, что код в блоке finally всегда будет выполняться, независимо от того, произошло ли исключение в блоке try. Если там действительно произошло исключение, его не поймают. А когда исключение не было обнаружено, вы знаете, что случилось с кодом под ним.

Чтобы перехватить исключение, которое могло произойти, используйте вместо этого блок try...except.... Вы можете объединить эти две конструкции для выполнения этих двух действий: (1) гарантировать выполнение некоторого фрагмента кода и (2) перехватить исключения, которые могут возникнуть. Обычное использование выглядит так:

try
  try
    // do something that might cause an exception.
  finally
    // do something that must be executed WHATEVER happened.
  end;
except
  // do something ONLY IF an exception has occured.
end;

Итак, вам следует изменить свой код и переместить Screen.Cursor := crDefault; внутрь блока finally. Кроме того, добавьте блок try...except..., чтобы окружить блок try...finally.... Нравится:

procedure TForm1.Button1Click(Sender: TObject);
var
  Obj: TSomeObject;
begin
  Screen.Cursor := crHourGlass;
  Obj := TSomeObject.Create;
  try
    try
      // do something.
    finally
      Obj.Free;
      Screen.Cursor := crDefault;
    end;
  except
    ShowMessage('An error has occured!');
  end;
end;

Или, если вы не уверены, что код Obj := TSomeObject.Create; достаточно безопасен, вы должны добавить второй блок try...finally..., чтобы окружить его, например:

procedure TForm1.Button1Click(Sender: TObject);
var
  Obj: TSomeObject;
begin
  Screen.Cursor := crHourGlass;
  try
    try
      Obj := TSomeObject.Create;
      try
        // do something.
      finally
        Obj.Free;
      end;
    finally
      Screen.Cursor := crDefault;
    end;
  except
    ShowMessage('An error has occured!');
  end;
end;

Надеюсь, это поможет :)

На самом деле вы не поймаете исключение. В этом случае при возникновении исключения будет выполнен блок кода «finally», а затем исключение раскрутит стек.