Отправить письмо Delphi XE5

Это не прямой ответ на проблему с Indy, но если вы решили сменить тактику и использовать встроенные параметры создания электронной почты на Android, вы можете использовать такой код:

uses
  FMX.Helpers.Android,
  Androidapi.JNIBridge,
  Androidapi.JNI.JavaTypes,
  Androidapi.JNI.GraphicsContentViewText;
...
procedure CreateEmail(const Recipient, Subject, Content: string);
var
  Intent: JIntent;
  Recipients: TJavaObjectArray<JString>;
begin
  Intent := TJIntent.JavaClass.init(TJIntent.JavaClass.ACTION_SEND);
  Recipients := TJavaObjectArray<JString>.Create(1);
  Recipients.Items[0] := StringToJString(Recipient);
  Intent.putExtra(TJIntent.JavaClass.EXTRA_EMAIL, Recipients);
  Intent.putExtra(TJIntent.JavaClass.EXTRA_SUBJECT, StringToJString(Subject));
  Intent.putExtra(TJIntent.JavaClass.EXTRA_TEXT, StringToJString(Content));
  Intent.setType(StringToJString('plain/text'));
  SharedActivity.startActivity(TJIntent.JavaClass.createChooser(Intent,
    StrToJCharSequence('Which email app?')));
end;

Я оставлю это кому-то другому, чтобы предложить решение проблемы с Инди.

пользователь 1147833;

вы должны выполнить операцию аутентификации после подключения к серверу.

Просто переключитесь на свой код;

IdSMTP1.Connect;
IdSMTP1.Authenticate;
  Try
    IdSMTP1.Send(IdMessage1);
  except
  End;

Убран ряд элементов, ни один из которых не поможет, если ваша форма на самом деле не отображается.
Приведенное ниже сообщение успешно отправлено с Nexus 7 1-го поколения с использованием SMTP-сервера, требующего аутентификации и работающего на порту 25.

Если вы действительно подключаетесь к порту 465 на серверах Google, вы должны использовать шифрование, к которому этот код не относится.

Простые присваивания IdMessage1.From.Text := 'бла-бла'; Не работали, поэтому вы увидите, что я заменил IdMessage1.From.Address и аналогичные свойства на другие свойства IdMessage1.

unit Unit1;

interface

uses
  System.SysUtils, System.Types, System.UITypes, System.Classes, System.Variants,
  FMX.Types, FMX.Controls, FMX.Forms, FMX.Graphics, FMX.Dialogs,
  IdBaseComponent, IdComponent, IdTCPConnection, IdTCPClient,
  IdExplicitTLSClientServerBase, IdMessageClient, IdSMTPBase, IdSMTP, IdMessage,
  FMX.StdCtrls, FMX.Edit;

type
  Ttestform = class(TForm)
    IdSMTP1: TIdSMTP;
    IdMessage1: TIdMessage;
    btnMessageSend: TButton;
    edtUsername: TEdit;
    edtPassword: TEdit;
    Label1: TLabel;
    Label2: TLabel;
    edtFrom: TEdit;
    Label3: TLabel;
    edtTo: TEdit;
    Label4: TLabel;
    edtServer: TEdit;
    Label5: TLabel;
    edtPort: TEdit;
    Label6: TLabel;
    procedure btnMessageSendClick(Sender: TObject);
  private
    { Private declarations }
  public
    { Public declarations }
  end;

var
  testform: Ttestform;

implementation

{$R *.fmx}

procedure Ttestform.btnMessageSendClick(Sender: TObject);
var
  intPort: Integer;
begin
  ShowMessage('In button click');
  IdSMTP1.Heloname:='test';
  IdSMTP1.Host:=edtServer.Text;
  IdSMTP1.Username:=edtUsername.Text;
  intPort := 25;
  ShowMessage('Before strtoint');
  TryStrToInt(edtPort.Text, intPort);
  ShowMessage('After strtoint');
  IdSMTP1.Port:= intPort;
  IdSMTP1.Password:=edtPassword.Text;

  if IdSMTP1.Connected=True then IdSMTP1.Disconnect;
  IdMessage1.Clear;
  IdMessage1.From.Address := edtFrom.Text;
  IdMessage1.Recipients.Add;
  IdMessage1.Recipients.Items[0].Address := edtTo.Text;
  IdMessage1.Priority := mpHigh;
  IdMessage1.Sender.Address:=edtFrom.Text;
  IdMessage1.Subject := 'Subject';
  IdMessage1.Body.Add('test');
  IdSMTP1.Connect;
  IdSMTP1.Send(IdMessage1);
end;

end.

Инди совместим с Android. Это не проблема Android, это проблема конфигурации.

Порт 465 Gmail использует неявный SSL для шифрования соединения. При подключении к порту 465 сервер ожидает, что ваше приложение инициирует рукопожатие SSL, чтобы установить сеанс SSL, прежде чем можно будет обмениваться данными SMTP.

Перед подключением необходимо прикрепить компонент TIdSSLIOHandlerOpenSSL к свойству TIdSMTP.IOHandler, а затем установить для свойства TIdSMTP.UseTLS значение utUseImplicitTLS. Без этого TIdSMTP не отправит подтверждение SSL. Он просто будет ждать SMTP-приветствия сервера, которое сервер не отправит до тех пор, пока сначала не будет установлен сеанс SSL. Таким образом, возникает взаимоблокировка, если вы не установите для свойства TIdSMTP.ReadTimeout не бесконечное значение, чтобы TIdSMTP.Connect() могло вызвать исключение, если оно не получает приветствие SMTP.

Перед развертыванием на устройстве Android запустите на платформе Win32, чтобы проверить, все ли в порядке. Не забудьте поместить OpenSSL DLL (libeay32.dll и ssleay32.dll) в один и тот же каталог, но это не подходит для Android. Вот мой код.

procedure TForm1.Button1Click(Sender: TObject);
begin
with IdMessage1 do
begin
  Recipients.EMailAddresses := '[email protected]';
  From.Address              := '[email protected]';
  From.Name                 := 'Self';
  CCList.EMailAddresses     := '';
  BccList.EMailAddresses    := '';
  Priority                  := mpNormal;
  Subject                   := 'Test Mail Subject';
  Body.Add('Test Mail Body');
end;

with IdSMTP1 do
begin
  Host      := 'smtp.gmail.com';
  Username  := 'xxxxxxx';
  Password  := 'yyyyyyy';
  IOHandler := TIdSSLIOHandlerSocketOpenSSL.Create(Self);
  Port      := 465;
  UseTLS    := utUseImplicitTLS;

  try
  Connect;
  except
  end;

  if not Connected then
  begin
    Showmessage('Error');
    Exit;
  end;

  try
  Send(IdMessage1);
  finally
  Disconnect;
  end;

 end;
end;