Я не думаю, что есть очень элегантное решение.

Однако вы можете попробовать:

If Not IsError(Application.Match(x, Array("Me", "You", "Dog", "Boo"), False)) Then

или вы можете написать свою собственную функцию:

Function ISIN(x, StringSetElementsAsArray)
    ISIN = InStr(1, Join(StringSetElementsAsArray, Chr(0)), _
    x, vbTextCompare) > 0
End Function

Sub testIt()
    Dim x As String
    x = "Dog"
    MsgBox ISIN(x, Array("Me", "You", "Dog", "Boo"))
End Sub

Вы также можете попробовать оператор CASE вместо IF.

Select Case X

 Case 1 To 3   
  ' Code to do something
 Case 4, 5, 6
  ' Code to do something
 Case 7
  ' Code to do something
 Case Else  
  ' More code or do nothing

End Select

Самый быстрый метод:

Here's a method much faster and more compact than any of the other answers, and works with numeric or text values:

Function IsIn(valCheck, valList As String) As Boolean  
    IsIn = Not InStr("," & valList & ",", "," & valCheck & ",") = 0
End Function

Примеры:

Используйте IsIn с числовым значением:

Sub demo_Number()
    Const x = 2
    If IsIn(x, "1,2,3") Then
        Debug.Print "Value " & x & " was Found!"
    Else
        Debug.Print "Value " & x & " was not Found."
    End If
End Sub

Используйте IsIn со строковым значением:

Sub demo_Text()
    Const x = "Dog"
    If IsIn(x, "Me,You,Dog,Boo") Then
        Debug.Print "Value " & x & " was Found!"
    Else
        Debug.Print "Value " & x & " was not Found."
    End If
End Sub

Сравнение скорости:

Чтобы сравнить скорость, я провел тест из принятого ответа 100 000 раз:

• 0.406 sec (FASTEST) Эта функция (используя InStr):
• 1.828 sec (450% slower) Принят Ответ с функцией "ISIN"
• 1.799 sec (440% slower) Ответ с "IsInArray" из freeVBcode
• 0.838 sec (206% slower) Ответ с измененной функцией "IsInArray"

Я не включил гораздо более длинный ответ, в котором используется SELECT..CASE, поскольку целью ОП, предположительно, было упрощение и сокращение< /em> задача по сравнению с "if x=1 or x=2 or x=3 then".