Преобразование XLIFF с использованием XML

Я пытаюсь преобразовать файл XLIFF обратно в правильный файл xml, используя этот код:

<?xml version="1.0" encoding="ISO-8859-1"?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">

    <xsl:template match="//body">
      <xliff xmlns="urn:oasis:names:tc:xliff:document:1.1" version="1.1">
        <file source-language="en-US" datatype="plaintext" target-language="de">
            <body>
                <xsl:for-each select="//trans-unit">
                    <xsl:element name="string">
                        <xsl:attribute name="name"><xsl:value-of select="@id"/></xsl:attribute>
                        <xsl:value-of select="target"/>
                    </xsl:element>      
                </xsl:for-each>
            </body>
        </file>
    </xliff>
    </xsl:template>
</xsl:stylesheet>

Но все, что он получает в качестве возврата, - это строки, заключенные в теги <source> и <target>. Я делаю что-то ужасно неправильно или мне не хватает специального тега для этого?

Мне удалось успешно создать файл XLIFF с помощью простого сценария XSLT, но я изо всех сил пытаюсь преобразовать его обратно.

Любые идеи приветствуются.

С уважением, Томас

Вот пример файла xliff

<?xml version='1.0' encoding='utf-8'?>
<xliff xmlns="urn:oasis:names:tc:xliff:document:1.1" version="1.1">
  <file source-language="en" datatype="plaintext" target-language="de">
    <body>
      <trans-unit xmlns:xsl="http://www.w3.org/1999/XSL/Transform" xsl:space="preserve" approved="yes" id="firstrun_textview_language_array_names1">
        <source>English</source>
        <target>Englisch</target>
      </trans-unit>
      <trans-unit xmlns:xsl="http://www.w3.org/1999/XSL/Transform" xsl:space="preserve" approved="no" id="firstrun_textview_language_array_names2">
        <source>Chinese (traditional)</source>
        <target>i dont know</target>
      </trans-unit>
    </body>
  </file>
</xliff>

xml xslt xliff
person inva    schedule 16.11.2012    source источник
comment
Можно ли показать образец вашего файла XLIFF? Спасибо!   -  person Tim C    schedule 16.11.2012
comment
Этот файл XLIFF очень похож на правильный файл XML ....   -  person marc_s    schedule 16.11.2012
comment
Возможно, @marc_s - это то, что я получил на самом деле, но я обязан поместить его в другой формат xml, но все, что я получил в свой выходной файл, - это строки, заключенные в исходный и целевой теги, и я совершенно уверен, что короткий скрипт xslt, который я написал, не должен этого делать вообще, поэтому мне интересно, что идет не так   -  person inva    schedule 16.11.2012

Ответы (1)


arrow_upward
6
arrow_downward

Проблема здесь в пространствах имен. В вашем примере XLIFF вы определили пространство имен по умолчанию

<xliff xmlns="urn:oasis:names:tc:xliff:document:1.1" version="1.1">

Это означает, что все элементы под этим будут принадлежать этому пространству имен (если не переопределены другим пространством имен).

Однако вы не объявили это пространство имен в своем XSLT, и поэтому везде, где он ищет элементы, он ищет элементы в пространстве имен NO, и обнаруживает, что шкаф пуст. В этом случае срабатывают встроенные шаблоны, которые в конечном итоге просто выводят все текстовые значения.

Чтобы решить эту проблему, сначала добавьте объявление пространства имен XLIFF, которое соответствует XML

<xsl:stylesheet version="1.0" 
   xmlns:xsl="http://www.w3.org/1999/XSL/Transform"    
   xmlns:xliff="urn:oasis:names:tc:xliff:document:1.1" 
   exclude-result-prefixes="xliff">

Затем используйте этот префикс при поиске элементов. Например

<xsl:template match="//xliff:body">

Вот полный XSLT. Обратите внимание, что нет реальной необходимости использовать xsl: element со статическим именем элемента, просто выведите элемент напрямую. (Также обратите внимание на использование шаблонов значений атрибутов вместо использования xsl: attribute).

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform" xmlns:xliff="urn:oasis:names:tc:xliff:document:1.1" exclude-result-prefixes="xliff">
    <xsl:output method="xml" indent="yes"/>

    <xsl:template match="//xliff:body">
        <xliff xmlns="urn:oasis:names:tc:xliff:document:1.1" version="1.1">
            <file source-language="en-US" datatype="plaintext" target-language="de">
                <body>
                   <xsl:for-each select="//xliff:trans-unit">
                      <string name="{@id}">
                         <xsl:value-of select="xliff:target"/>
                      </string>      
                   </xsl:for-each>
                </body>
            </file>
        </xliff>
    </xsl:template>
</xsl:stylesheet>

При применении к вашему XML выводится следующее

<xliff version="1.1" xmlns="urn:oasis:names:tc:xliff:document:1.1">
   <file source-language="en-US" datatype="plaintext" target-language="de">
      <body>
        <string name="firstrun_textview_language_array_names1">Englisch</string>
        <string name="firstrun_textview_language_array_names2">i dont know</string>
     </body>
   </file>
</xliff>
person Tim C    schedule 16.11.2012
comment
вау, довольно удивительно и впечатляюще. Я догадывался, что может быть что-то не так с пространством имен, но я не могу понять самостоятельно. Спасибо за вашу поддержку. Теперь он работает - использование префикса xliff довольно круто :) Хороших выходных! - person inva; 16.11.2012