Как использовать функцию GOOGLEFINANCE ((CURRENCY: EURAUD))

Ну вот:

https://support.google.com/docs/answer/3093281

Это вся документация, которую предоставляет Google.

Конкретные инструкции для того, что вы ищете, находятся здесь: https://support.google.com/docs/answer/3093281

Помните, что в формулах таблиц Google может использоваться точка с запятой (;) вместо запятой (,) в зависимости от региональных настроек.

После того, как замена на некоторых примерах будет выглядеть так:

=GoogleFinance("CURRENCY:USDEUR")
=INDEX(GoogleFinance("USDEUR","price",today()-30,TODAY()),2,2)
=SPARKLINE(GoogleFinance("USDEUR","price",today()-30,today()))

Курс обмена евро на норвежскую крону на первое января 2016 года:

=INDEX(GOOGLEFINANCE("CURRENCY:EURNOK"; "close"; DATE(2016;1;1)); 2; 2)

Функция INDEX() используется потому, что функция GOOGLEFINANCE() фактически распечатывает в 4 отдельных ячейках (2x2), когда вы вызываете ее с этими аргументами, с ее помощью результатом будет только одна ячейка.

Некоторые валютные пары не имеют исторических данных за определенные дни.

Сравните =GOOGLEFINANCE("CURRENCY:EURNOK", "close", DATE(2016,1,1), DATE(2016,1,12):

Date                Close
1/1/2016 23:58:00   9.6248922
1/2/2016 23:58:00   9.632922114
1/3/2016 23:58:00   9.579957264
1/4/2016 23:58:00   9.609146435
1/5/2016 23:58:00   9.573877808
1/6/2016 23:58:00   9.639368875
1/7/2016 23:58:00   9.707103569
1/8/2016 23:58:00   9.673324479
1/9/2016 23:58:00   9.702379872
1/10/2016 23:58:00  9.702721875
1/11/2016 23:58:00  9.705679083

и =GOOGLEFINANCE("CURRENCY:EURRUB", "close", DATE(2016,1,1), DATE(2016,1,12):

Date                Close
1/1/2016 23:58:00   79.44402768
1/4/2016 23:58:00   79.14048175
1/5/2016 23:58:00   80.0452446
1/6/2016 23:58:00   80.3761125
1/7/2016 23:58:00   81.70830185
1/8/2016 23:58:00   81.70680013
1/11/2016 23:58:00  82.50853122

Итак, =INDEX(GOOGLEFINANCE("CURRENCY:EURRUB", "close", DATE(2016,1,1)), 2, 2) дает

79.44402768

Но =INDEX(GOOGLEFINANCE("CURRENCY:EURRUB", "close", DATE(2016,1,2)), 2, 2) дает

#N/A

Следовательно, при работе с валютными парами, для которых нет обменных курсов на выходные / праздничные дни, можно использовать следующую формулу для получения обменного курса на первый следующий рабочий день:

=INDEX(GOOGLEFINANCE("CURRENCY:EURRUB", "close", DATE(2016,1,2), 4), 2, 2)

Имейте в виду, что функция GoogleFinance() не работает на 100% в новой версии Google Таблиц. Например, преобразование из USD в GBP с использованием формулы GoogleFinance("CURRENCY:USDGBP") дает 0.603974 в старой версии, но только 0,6 в новой. Похоже, произошла ошибка округления.

=INDEX(GoogleFinance("CURRENCY:" & "EUR" & "USD", "price", A2), 2, 2)

где A2 - это ячейка с датой в формате date.

Замените «EUR» и «USD» своей валютной парой.

Синтаксис:

= GOOGLEFINANCE (тикер, [атрибут], [начальная_дата], [число_дней | конечная_дата], [интервал])

Пример использования:

=GOOGLEFINANCE("GOOG", "price", DATE(2014,1,1), DATE(2014,12,31), "DAILY")
=GOOGLEFINANCE("GOOG","price",TODAY()-30,TODAY())
=GOOGLEFINANCE(A2,A3)
=117.80*Index(GOOGLEFINANCE("CURRENCY:EURGBP", "close", DATE(2014,1,1)), 2, 2)

Например, если вы хотите конвертировать курс на определенную дату, вот более сложный пример:

=IF($C2 = "GBP", "", Index(GoogleFinance(CONCATENATE("CURRENCY:", C2, "GBP"), "close", DATE(year($A2), month($A2), day($A2)), DATE(year($A2), month($A2), day($A2)+1), "DAILY"), 2))

где $A2 - ваша дата (например, 01/01/2015), а C2 - ваша валюта (например, EUR).

Дополнительные образцы см. В Справке редакторов документов в Google.

Вы должны использовать знак равенства в поле формулы

=GOOGLEFINANCE("GOOG", "price", DATE(2014,1,1), DATE(2014,12,31), "DAILY")