Как в Perl выделить строки между двумя разделителями строк?

Вам нужен оператор триггера (также известный как оператор диапазона) ..

#!/usr/bin/env perl
use strict;
use warnings;

while (<>) {
  if (/START/../END/) {
    next if /START/ || /END/;
    print;
  }
}

Замените вызов print тем, что вы действительно хотите сделать (например, вставить строку в массив, отредактировать ее, отформатировать и т. Д.). Я next прохожу мимо строк, которые на самом деле имеют START или END, но вам может не понравиться такое поведение. См. эту статью для обсуждения этого оператора и другие полезные специальные переменные Perl.

Из ответа perlfaq6 на Как выделить линии между двумя шаблонами, которые сами находятся на разных линиях?

Вы можете использовать несколько экзотический оператор Perl .. (задокументированный в perlop):

perl -ne 'print if /START/ .. /END/' file1 file2 ...

Если вам нужен текст, а не строки, вы должны использовать

perl -0777 -ne 'print "$1\n" while /START(.*?)END/gs' file1 file2 ...

Но если вам нужны вложенные вхождения от START до END, вы столкнетесь с проблемой, описанной в вопросе в этом разделе о сопоставлении сбалансированного текста.

Вот еще один пример использования ..:

while (<>) {
    $in_header =   1  .. /^$/;
    $in_body   = /^$/ .. eof;
# now choose between them
} continue {
    $. = 0 if eof;  # fix $.
}

Как я могу захватить несколько строк после соответствующая строка в Perl?

Как это? В этом случае строка END - это $ ^, вы можете изменить ее на свою строку END.

Я тоже новичок, но решения там предоставляют довольно много методов ... дайте мне знать более конкретно, что вы хотите, что отличается от приведенной выше ссылки.

while (<>) {
    chomp;      # strip record separator
    if(/END/) { $f=0;}
    if (/START/) {
        s/.*START//g;
        $f=1;
    }
    print $_ ."\n" if $f;
}

попробуйте написать код в следующий раз

После ответа Телемаха все начало выливаться наружу. В конце концов, это работает как решение, которое я ищу.

1. Я пытаюсь выделить строки, разделенные двумя строками (одна - со строкой, заканчивающейся на «CINFILE =»; другая, со строкой, содержащей один «#»), в отдельные строки, за исключением строк-разделителей. Я могу это сделать с помощью решения Телемаха.
2. В первой строке есть пробел, который я хочу удалить. Я тоже это включаю.
3. Я также пытаюсь извлечь каждый набор строк в отдельные файлы.

У меня это работает, хотя код можно отнести к категории уродливых; это потому, что в настоящее время я практически новичок в Perl. Во всяком случае, здесь идет:

#!/usr/bin/env perl
use strict;
use warnings;

my $start='CINFILE=$';
my $stop='^#$';
my $filename;
my $output;
my $counter=1;
my $found=0;

while (<>) {
  if (/$start/../$stop/) {
    $filename=sprintf("boletim_%06d.log",$counter);
    open($output,'>>'.$filename) or die $!;
    next if /$start/ || /$stop/;
    if($found == 0) { print $output (split(/ /))[1]; }
    else { print $output $_; }
    $found=1;
  } else { if($found == 1) { close($output); $counter++; $found=0; } }
}

Я надеюсь, что это принесет пользу и другим. Ваше здоровье.

Неплохо для "виртуального новичка". Одна вещь, которую вы могли бы сделать, - это поместить «$ found = 1» внутри блока «if ($ found == 0)», чтобы вы не выполняли это присвоение каждый раз между $ start и $ stop.

Еще одна неприятная вещь, на мой взгляд, заключается в том, что вы открываете один и тот же обработчик файлов каждый раз, когда вводите блок $ start / $ stop.

Это показывает способ обойти это:

#!/usr/bin/perl

use strict;
use warnings;

my $start='CINFILE=$';
my $stop='^#$';
my $filename;
my $output;
my $counter=1;
my $found=0;

while (<>) {

    # Find block of lines to extract                                                           
    if( /$start/../$stop/ ) {

        # Start of block                                                                       
        if( /$start/ ) {
            $filename=sprintf("boletim_%06d.log",$counter);
            open($output,'>>'.$filename) or die $!;
        }
        # End of block                                                                         
        elsif ( /$end/ ) {
            close($output);
            $counter++;
            $found = 0;
        }
        # Middle of block                                                                      
        else{
            if($found == 0) {
                print $output (split(/ /))[1];
                $found=1;
            }
            else {
                print $output $_;
            }
        }

    }
    # Find block of lines to extract                                                           

}