Перетащите текст в элемент управления SynEdit.

У меня есть элемент управления TSynEdit в форме, и я хочу перетащить выделенный текст узла из TVirtualStringTree. Я хотел бы, чтобы он вел себя так же, как при перетаскивании выделенного текста в элементе управления TSynEdit:

  • При перетаскивании TSynEdit курсор должен отметить текущую позицию перетаскивания.
  • Когда текст удаляется, он должен заменить любой текст, который в данный момент выделен.
  • Положение перетаскивания должно корректно обрабатывать вкладки.

Я просмотрел код в событии TSynEdit DragOver, но он использует несколько переменных и процедур, к которым я не могу получить доступ в классе-потомке, поскольку они объявлены частный.

Я проверил все демонстрационные версии TSynEdit и не нашел ни одной, отвечающей моим требованиям.

Кому-нибудь удалось это сделать успешно?


drag-and-drop delphi synedit
person norgepaul    schedule 19.06.2012    source источник

Ответы (2)


arrow_upward
1
arrow_downward

Я думаю, что вы можете достичь своей цели, назначив вашему редактору два события: DragOver/DragDrop.

1/ вы проверяете правильность в событии DragOver, вы также перемещаете курсор, вызывая GetPositionOfMouse

Procedure TForm1.EditorDragOver(Sender,Source: TObject;X,Y: Integer; State: TDragState; Var Accept: Boolean);
Var
  LCoord: TBufferCoord;
  LMemo: TSynMemo;
Begin
  LMemo := TSynMemo(Sender);
  // In your case you would rather test something with your tree...
  Accept := Clipboard.AsText <> '';
  // "As you drag over the TSynEdit, the caret should mark the current drop position": OK
  If LMemo.GetPositionOfMouse(LCoord) Then
    LMemo.CaretXY := LCoord;
End;

2/ Вы используете команды редактора в событии DragDrop, чтобы очистить выделение и вставить символы

Procedure TForm1.EditorDragDrop(Sender, Source: TObject; X,Y: Integer);
Var
  LMemo: TSynMemo;
Begin
  LMemo := TSynMemo(Sender);
  // "When the text is dropped, it should replace any text that is currently highlighted." : OK
  If LMemo.SelAvail Then
    LMemo.ExecuteCommand( ecDeleteChar , #0, Nil );
  // Paste, same comment as previously, here it's just an example...
  LMemo.ExecuteCommand( ecPaste, #0, Nil );
End;

Это должно быть немного изменено в соответствии с вашим контекстом.

person az01    schedule 19.06.2012

arrow_upward
2
arrow_downward

Ответ AZ01 не сделал именно то, что я хотел, но указал мне правильное направление. Вот код, который я в итоге использовал:

procedure TfrmTemplateEdit.memTemplateDragDrop(Sender, Source: TObject; X,
  Y: Integer);
var
  InsertText: String;
  ASynEdit: TSynEdit;
  OldSelStart, DropIndex: Integer;
  LCoord: TBufferCoord;
begin
  // Set the Insert Text
  InsertText := 'The text to insert';

  // Set the SynEdit memo
  ASynEdit := TSynEdit(Sender);

  // Get the position on the mouse
  ASynEdit.GetPositionOfMouse(LCoord);

  // Find the index of the mouse position
  DropIndex := ASynEdit.RowColToCharIndex(LCoord);

  // Delete any selected text
  If (ASynEdit.SelAvail) and
     (DropIndex >= ASynEdit.SelStart) and
     (DropIndex <= ASynEdit.SelEnd) then
  begin
    // Store the old selection start
    OldSelStart := ASynEdit.SelStart;

    // Delete the text
    ASynEdit.ExecuteCommand(ecDeleteChar, #0, Nil);

    // Move the caret
    ASynEdit.SelStart := OldSelStart;
  end
  else
  begin
    // Position the caret at the mouse location
    ASynEdit.CaretXY := LCoord;
  end;

  // Insert the text into the memo
  ASynEdit.ExecuteCommand(ecImeStr, #0, PWideChar(InsertText));

  // Set the selection start and end points to selected the dropped text
  ASynEdit.SelStart := ASynEdit.SelStart - length(InsertText);
  ASynEdit.SelEnd := ASynEdit.SelStart + length(InsertText);

  // Set the focus to the SynEdit
  ASynEdit.SetFocus;
end;

Код работает правильно с выбором, вкладками и отменой.

person norgepaul    schedule 27.06.2012