Автоматизация VBA Internet Explorer «Отказано в доступе»

После тестирования всех предложенных выше исправлений и даже больше, я уверен, что это странная ошибка с обработкой событий дочерних процессов, вызываемых IE всякий раз, когда на одном веб-сайте есть разные зоны безопасности.

Переходим к делу, вот решение:

'Craziest workaround ever due to bugged IE Eventhandling
Do While IE.ReadyState = 4: DoEvents: Loop 
Do Until IE.ReadyState = 4: DoEvents: Loop

Добавляйте этот фрагмент кода каждый раз после перехода на новую страницу или других событий, которые могут привести к перезагрузке веб-сайта, например нажатия кнопки отправки и т. п.

Дэн выше предложил свободно добавлять операторы DoEvents в ваш код, что не помогло мне на 100%. Вместо этого я предлагаю добавить приведенный выше код везде, где это применимо.

Престижность Дэну, без твоего комментария я бы никогда не понял!

Краткий обзор ПРЕИМУЩЕСТВ этого метода по сравнению с другими предлагаемыми исправлениями:

• Вы можете придерживаться поздней привязки, если хотите (Dim IE as Object)
• Вы можете придерживаться создания объекта InternetExplorer (в отличие от, например, InternetExplorerMedium)
• Вам не нужно изменять настройки зоны безопасности в IE
• Нет ненужного времени ожидания в вашем приложении
• Вы избавляетесь от ошибки 70 - Отказано в доступе
• Вы избавляетесь от потерянных сеансов, т. Е. «Ошибка времени выполнения« -2147417848 (80010108) »: ошибка автоматизации. Вызванный объект отключился от своих клиентов».
• Вы избавляетесь от проблем с интерфейсом, например, «Ошибка времени выполнения '-2147023179 (800706b5)': Ошибка автоматизации Интерфейс неизвестен»

Краткое изложение всего, что ВАМ НЕ НУЖНО при таком подходе:

• InternetExplorerMedium объекты
• Раннее связывание в целом
• Ссылка на Microsoft Internet Controls
• Ссылка на элементы управления и автоматизации Microsoft Shell
• Странная обработка ошибок
• Нет необходимости когда-либо проверять IE.Busy в вашем коде
• Application.wait или спящий режим вызывают ненужные предполагаемые задержки

Я включаю приведенное выше резюме только потому, что я видел все предложенные обходные пути и лично пробовал их, пока безуспешно.

Пример кода на основе вопроса OP:

Dim IE as Object    
Set IE = CreateObject("InternetExplorer.Application")

IE.Visible = True
IE.Navigate("http://www.google.com")

'Craziest workaround ever due to bugged IE Eventhandling
Do While IE.ReadyState = 4: DoEvents: Loop
Do Until IE.ReadyState = 4: DoEvents: Loop

IE.document.getElementsByTagName("Input")(3).Value = "Search Term"
IE.document.Forms(0).Submit     ' this previously crashed

Я очень надеюсь, что это поможет другим в будущем. Удачи всем, кто помог собрать решение вместе.

С наилучшими пожеланиями Патрик

Я получаю ту же ошибку при автоматизации IE, но вместо исправления я работал.

  Label1:
         If myIe Is Nothing Then
             Set myIe = CreateObject("InternetExplorer.Application") 
         End If

         myIe.Navigate URL:=imdbLink

    For Each link In myIe.document.Links
         If Right(link.href, 9) = "/keywords" And Left(link.href, 26) = "http://www.imdb.com/title/" Then
                    mKPlot = link.href 'ERROR GENERATES FROM THIS, SOMETIMES...
         End If
    next link



errHandler:
    If Err.Number = 70 Then
        Debug.Print "permission denied for: |" & title & "|"

        myIe.Quit
        Set myIe = Nothing

        Application.Wait Now + TimeValue("00:00:10")

        Resume Label1:

    End If

Не то гладкое исправление реестра, которое вы себе представляли, но оно работает для меня.

У меня была точно такая же проблема. Был скрипт для автоматизации IE, который год нормально работал. Затем ни с того ни с сего я начал получать эту «ошибку отказа в доступе». Я сделал две вещи, одна из которых устранила проблему, но я не знаю, какая именно.

1. Я удалил ссылку на «Microsoft Internet Controls», попытался скомпилировать проект, снова добавил ссылку на «Internet Controls» и скомпилировал проект.

2. Удалено ключевое слово «WithEvents» при объявлении объекта InternetExplorer, поскольку мне все равно не нужно было захватывать события событий из IE.

Я подозреваю, что это было первое, и что каким-то образом ссылка была повреждена, и ее удаление и повторное добавление устранили проблему.

Это распространенная проблема с автоматизацией Internet Explorer в VBA. Обычно это происходит после загрузки новой страницы. Мне удалось успешно использовать комбинацию DoEvents, Application.Wait и установить для моего объекта HTMLDocument значение Nothing после загрузки новой страницы.

Я представил пример кода ниже, чтобы продемонстрировать:

Option Explicit

Sub IEAutomation()

    Dim IE As InternetExplorer
    Dim html As HTMLDocument
    Dim i As HTMLHtmlElement
    Dim search_bar_id As String
    Dim submit_button_name As String
    Dim search_term As String

    'Define Variables
    search_bar_id = "lst-ib"
    submit_button_name = "btnK"
    search_term = "Learning VBA"

    'Create IE and Naviagate to Google
    Set IE = CreateObject("InternetExplorer.Application") 'Late Binding
    IE.Visible = True
    IE.navigate "http://www.google.com"

    'Wait for IE To Load
    Do While IE.readyState <> READYSTATE_COMPLETE: DoEvents: Loop

    'Create HTMLDocument Object
    Set html = IE.document

    'Enter Search Term into Search Bar and Click Submit Button
    html.getElementById(search_bar_id).innerText = search_term
    Application.Wait Now + TimeValue("0:00:01")
    html.getElementsByName(submit_button_name)(, 1).Click

    'Wait for New Page to Load (** DoEvents Helps with the Permission Issue **)
    Do While IE.readyState <> READYSTATE_COMPLETE: DoEvents: Loop

    'After Page Loads, Reset HTMLDocument Object and Wait 1 Second Before Recreating It
    Set html = Nothing
    Application.Wait Now + TimeValue("0:00:01") '<<< This seems to really help
    Set html = IE.document

    'Print All Elements In H3 Tags to Immediate Window in VBE
    For Each i In html.getElementsByTagName("H3")
        Debug.Print i.innerText
    Next i

End Sub

Решение сброса объекта HTMLDocument работает и для меня, т.е.

'After Page Loads, Reset HTMLDocument Object and Wait 1 Second Before recreating It
Set html = Nothing
Application.Wait Now + TimeValue("0:00:01") '<<< This seems to really help
Set html = IE.document

Ни одно из других решений не решило мою проблему.

Следующее сработало для меня. Я не тестировал его широко, но проблема не повторялась. Я получал ошибку с перерывами, но всегда в одном и том же месте.

Управление первым экземпляром IE, кажется, умирает. Однако можно создать другой экземпляр, ссылаясь на первый. Затем мертвый экземпляр можно закрыть, и мы продолжим.

Set IEa = CreateObject("InternetExplorer.Application")
Set IEa = IE
   'Where IE is the instance that's about to error
SendKeys ("%{F4}")
   'Closes the old window, IE.quit in the code wouldn't work
IEa.Visible = True

Надеюсь, это сработает для кого-то другого, я был очень расстроен.

Брайан

PS: мой первый пост на stackoverflow, я думаю, что сделал правильное форматирование

Попробуйте этот код для меня. Это позволяет избежать необходимости выбирать/щелкать любой элемент в браузере.

Я тестировал это для Индии

Sub Sample1() '<~~ Works as expected
    Dim IE As New InternetExplorer
    IE.Visible = True
    IE.Navigate ("http://www.google.co.in/#hl=en&q=" & "Search Term")
End Sub

Для Великобритании

Sub Sample2() '<~~ Works as expected
    Dim IE As New InternetExplorer
    IE.Visible = True
    IE.Navigate ("http://www.google.co.uk/#hl=en&q=" & "Search Term")
End Sub

Попробуйте это для США (не удалось протестировать, так как он перенаправляет мой запрос)

Sub Sample3()
    Dim IE As New InternetExplorer
    IE.Visible = True
    IE.Navigate ("http://www.google.com/#hl=en&q=" & "Search Term")
End Sub

У меня была такая же ошибка времени выполнения 70. Отказано в доступе при автоматизации управления веб-браузером в VBA под MS Access 2010. Моя цель состояла в том, чтобы установить innerHTML для редактируемого содержимого узла. Сначала все работало отлично, а потом по неизвестной причине я начал получать "Ошибка 70. Отказано в доступе". Интересно, что эта ошибка возникает из-за элемента управления веб-браузера IE, а не из MS Access. Иногда он не перехватывался обработчиком ошибок VBA On Error. Еще одна загадка заключается в том, что при пошаговом выполнении кода он будет работать, но при нормальной работе элемент управления Webbrowser просто не будет работать, но не вызовет ошибку. Однако это вызовет ошибку, если я установлю точку останова, а затем запрошу WebBrowser в непосредственной панели VBA с помощью кода, такого как: DIV.innerHTML

Вот код, который не удался:

Private Function SetInnerHTML(HTML As String) As String
Dim HTMLEmail As HTMLDocument
Dim DIV As HTMLDivElement
Set HTMLEmail = Me.Email_MainBrowser.Controls("MyBrowser").Object.Document
Set DIV = HTMLEmail.getElementById("MyText")
DIV.innerHTML = HTML ' This is the line that failed

Как и Деннис, ОП, я попытался добавить вызовы Sleep и добавил вызовы функций, чтобы убедиться, что браузер возвращает «состояние готовности». CurrentState = Me.Form («Email_MainBrowser»). Controls («MyBrowser»). ReadyState (CurrentState должен быть выполнить).

Вот что я пробовал, но проблема не решилась: 1) Декомпилировать и перекомпилировать приложение MS Access. 2) Добавлены вызовы функции сна Win32 для ожидания элемента управления WebBrowser. 3) Запрошен Webbrowser, чтобы убедиться, что он находится в состоянии завершения навигации.

И вот что это исправило: добавлено много "DoEvents" вокруг кода, ссылающегося и автоматизирующего управление веб-браузером:

Dim HTMLEmail As HTMLDocument
Dim DIV As HTMLDivElement
DoEvents
Set HTMLEmail = Me.Email_MainBrowser.Controls("MyBrowser").Object.Document
Set DIV = HTMLEmail.getElementById("MyText")
DoEvents
DIV.innerHTML = HTML
DoEvents

Я не определил минимальное количество необходимых DoEvents; это, вероятно, только один из стратегически расположенных. Я также по-прежнему проверяю, находится ли элемент управления веб-браузером в состоянии завершения навигации, но я уверен, что это ошибка глубоко в элементе управления веб-браузером. Тот, который, вероятно, никогда не будет исправлен.