SQL Server: как прервать серию пакетов в Query Analyzer?

Вот как бы я это сделал:

PRINT 'This runs'
go

SELECT 0/0, 'This causes an error'
go
if (@@error <> 0)
    Begin
    set nocount on
    set noexec on
    End
GO

PRINT 'This should not run'
go

set noexec off
set nocount off
GO

Режим «noexec» помещает SSMS в состояние, в котором он просто компилирует T-SQL и фактически не выполняет его. Это похоже на случайное нажатие кнопки «Разобрать» на панели инструментов (Ctrl + F5) вместо «Выполнить» (F5).

Не забудьте снова отключить noexec в конце вашего скрипта. В противном случае пользователи будут сбиты с толку постоянным сообщением «Команда (и) успешно выполнена». Сообщения.

Я использую проверку на наличие ошибки @@ в следующем пакете вместо блоков TRY CATCH. Использование ошибки @@ в следующем пакете приведет к обнаружению ошибок компиляции, таких как «таблица не существует».

В дополнение к режиму noexec я также переключаю режим nocount. При включенном режиме noexec и выключенном nocount ваши запросы все равно будут сообщать о сообщении «(затронутых строк: 0)». Сообщение всегда содержит нулевые строки, потому что вы находитесь в режиме noexec. Однако включение nocount подавляет эти сообщения.

Также обратите внимание, что при запуске SQL Server 2005 команда, которую вы пропускаете, может по-прежнему выдавать сообщения об ошибках, если она ссылается на таблицу, которая не существует, и команду, если это первая команда в пакете. Принуждение команды быть второй командой в пакете с фиктивным оператором печати может подавить это. См. Ошибка MS # 569263, чтобы узнать больше.

Вы можете активировать опцию меню «Query, SQLCMD Mode» и поместить следующее в начало скрипта:

:on error exit

Это остановит выполнение при возникновении ошибки, даже если есть последующие пакеты.

Просто убедитесь, что вы случайно не запустили сценарий без включенного режима SQLCMD, потому что вы получите типичное поведение, при котором ошибки игнорируются.

Когда мне нужно это сделать, я выдаю RAISERROR серьезности 20. Это или выше убьет текущее соединение и предотвратит выполнение последующих «пакетов GO». Да, это может быть неудобно, но работает.

Создайте временную таблицу; и обновлять его после каждого шага (в случае успеха); а затем проверьте успешность предыдущего шага, сверяясь с таблицей.

create table #ScriptChecker (SuccessfullStep int)

-- Do Step One
Insert into #ScriptChecker
Select 1

-- Step 2
If exists (select * from #ScriptChecker where SuccessfullStep = 1)
-- Do Step 2 ...

основан на идее @ u07ch, но вставлять только при неудаче ...

create table #test (failure  int)

if not exists (select * from #test)
BEGIN
    print 'one' --sql here
END
go

if not exists (select * from #test)
BEGIN
    print 'two'--sql here
END
go

if not exists (select * from #test)
BEGIN
    print 'three' ---SQL SERVER 2000 version
    --error--
    SELECT 0/0, 'This causes an error'
    IF @@ERROR!=0
    BEGIN
        insert into #test values (1)
        PRINT 'ERROR'
    END
end 
go

if not exists (select * from #test)
BEGIN
    print 'three'  ---SQL SERVER 2005/2008 version
    BEGIN TRY
    --error--
        SELECT 0/0, 'This causes an error'
    END TRY
    BEGIN CATCH
        insert into #test values (1)
        PRINT 'ERROR'
    END CATCH
END
go

if not exists (select * from #test)
BEGIN
    --sql here
    print 'four'
END
go

выход 2000:

one
two
three

----------- --------------------
Msg 8134, Level 16, State 1, Line 7
Divide by zero error encountered.

(1 row(s) affected)

ERROR

результат 2005/2008:

one
two
three

----------- --------------------

(0 row(s) affected)

(1 row(s) affected)

ERROR

Эрланд Соммарског из группы разработчиков microsoft.public.sqlserver.programming пришел к очень хорошей идее:

В сценарии изменения, таком как тот, который вы опубликовали, вы должны быть защищенными и начинать каждый пакет с IF @@ trancount> 0.

С использованием

IF @@trancount > 0 

намного чище.