Perl: сопоставление с первым элементом списков

Я только что немного поиграл, и кажется, что ()[0] в контексте списка интерпретируется как пустой список, а не как скаляр undef. Например, это:

my @arr = ()[0];
my $size = @arr;
print "$size\n";

печатает 0. Таким образом, $_ => ()[0] примерно эквивалентно просто $_.

Чтобы исправить это, вы можете использовать функцию scalar для принудительного скалярного контекста:

my %h = map {$_ => scalar((f($_))[0])} @a;

или вы можете добавить явное undef в конец списка:

my %h = map {$_ => (f($_), undef)[0]} @a;

или вы можете обернуть возвращаемое значение вашей функции в истинный массив (а не просто в плоский список):

my %h = map {$_ => [f($_)]->[0]} @a;

(Лично мне больше всего нравится последний вариант.)

Особое поведение фрагмента пустого списка описано в разделе "Slices" в perldata:

Фрагмент пустого списка по-прежнему остается пустым списком. […] Это упрощает написание циклов, которые завершаются, когда возвращается нулевой список:

while ( ($home, $user) = (getpwent)[7,0]) {
    printf "%-8s %s\n", $user, $home;
}

Я поддерживаю предложение Джонатана Леффлера - лучше всего было бы решить проблему с самого начала, если это вообще возможно:

sub f {

    # ... process @result

    return @result ? $result[0] : undef ;
}

Явное undef необходимо для решения проблемы с пустым списком.

Во-первых, большое спасибо всем ответившим! Теперь я чувствую, что должен предоставить фактические детали реальной задачи.

Я разбираю файл XML, содержащий набор элементов, каждый из которых выглядит так:

<element>
    <attr_1>value_1</attr_1>
    <attr_2>value_2</attr_2>
    <attr_3></attr_3>
</element>

Моя цель — создать хэш Perl для элемента, который содержит следующие ключи и значения:

('attr_1' => 'value_1',
 'attr_2' => 'value_2',
 'attr_3' =>  undef)

Давайте подробнее рассмотрим элемент <attr_1>. XML::DOM::Parser CPAN модуль, который я использую для парсинга, создает для них объект класса XML::DOM::Element, давайте для их ссылки дадим имя $attr. Имя элемента легко получить с помощью $attr->getNodeName, но для доступа к тексту, заключенному в теги <attr_1>, нужно сначала получить все дочерние элементы <attr_1>:

my @child_ref = $attr->getChildNodes;

Для <attr_1> и <attr_2> элементов ->getChildNodes возвращает список, содержащий ровно одну ссылку (на объект класса XML::DOM::Text), а для <attr_3> возвращает пустой список. Для <attr_1> и <attr_2> я должен получить значение $child_ref[0]->getNodeValue, а для <attr_3> я должен поместить undef в результирующий хэш, так как там нет текстовых элементов.

Таким образом, вы видите, что реализация функции f (метод ->getChildNodes в реальной жизни) не может контролироваться :-) В результате получается код, который я написал (подпрограмма снабжена списком ссылок XML::DOM::Element для элементов <attr_1>, <attr_2> и <attr_3>):

sub attrs_hash(@)
{
    my @keys = map {$_->getNodeName} @_;  # got ('attr_1', 'attr_2', 'attr_3')
    my @child_refs = map {[$_->getChildNodes]} @_;  # got 3 refs to list of XML::DOM::Text objects
    my @values = map {@$_ ? $_->[0]->getNodeValue : undef} @child_refs;  # got ('value_1', 'value_2', undef)

    my %hash;
    @hash{@keys} = @values;

    %hash;
}