Perl: числовая сортировка массивов в хеше

У меня есть хэш массивов, и мне нужно отсортировать его сначала по ключам, а потом по значениям в массиве.

Вот мой простой код:

my %myhash;
$line1 = "col1 0.999";
$line2 = "col2 0.899";
$line3 = "col2 -0.52";
$line4 = "col2 1.52";

#insert into hash
@cols = split(" ", $line1);
push @{ $myhash{$cols[0]} }, $line1;
@cols = split(" ", $line2);
push @{ $myhash{$cols[0]} }, $line2;
@cols = split(" ", $line3);
push @{ $myhash{$cols[0]} }, $line3;
@cols = split(" ", $line4);
push @{ $myhash{$cols[0]} }, $line4;

foreach $k (sort {$a <=> $b} (keys %myhash)) {
   foreach $v(sort {$a <=> $b}(@{$myhash{$k}}))
   {
       print $k." : $v \n";     
   }
}

Но я получаю следующий вывод:

col1 : col1 0.999
col2 : col2 0.899
col2 : col2 -0.52
col2 : col2 1.52

Таким образом, ключи отсортированы нормально, а значения — нет. Мне нужно, чтобы они вышли вот так:

col1 : col1 0.999
col2 : col2 -0.52
col2 : col2 0.899
col2 : col2 1.52

Что не так с моим кодом?


arrays sorting hash perl numerical
person user961627    schedule 27.10.2011    source источник
comment
Ваши значения содержат col2 1.52, включая значение col2. Это то, что сбивает сортировку.   -  person Konerak    schedule 27.10.2011
comment
Почему вы сохраняете имя colN в значениях? Какой порядок ключей вам нужен (числовой или строковый)?   -  person Mat    schedule 27.10.2011
comment
ах точно! спасибо я этого не понял.   -  person user961627    schedule 27.10.2011
comment
Вот почему вы всегда должны использовать предупреждения об использовании. В этот момент ошибка становится очевидной, поскольку Perl громко жалуется на ошибку.   -  person bot403    schedule 27.10.2011

Ответы (2)


arrow_upward
6
arrow_downward

Не уверен, почему вы строите хэш. Все, что вам нужно, это быстрый шварцевский Преобразовать.

#!/usr/bin/perl

use strict;
use warnings;

my $line1 = "col1 0.999";
my $line2 = "col2 0.899";
my $line3 = "col2 -0.52";
my $line4 = "col2 1.52";

my @sorted = map { join ' ', @$_ }
             sort { $a->[0] cmp $b->[0] or $a->[1] <=> $b->[1] }
             map { [ split ] } ($line1, $line2, $line3, $line4);

print "$_\n" for @sorted;

Кроме того, наличие переменных с именем $lineX является чем-то вроде красного флага. Вероятно, вам следует хранить эти значения в массиве.

person Dave Cross    schedule 27.10.2011
comment
У меня есть строки в массиве, просто тестирую здесь. Кстати, это отлично работает и намного аккуратнее! Только вот вопрос, как это будет работать в обратную сторону? Как в порядке убывания? - person user961627; 27.10.2011
comment
Если вы хотите изменить порядок сравнения одного вида, но не другого, просто поменяйте местами использование $a и $b. Самый простой способ обратить всю сортировку — поставить reverse перед вызовом sort. - person Dave Cross; 27.10.2011
comment
Хорошо, я думаю, что что-то пошло не так. Я повторно разместил вопрос здесь: stackoverflow.com/questions/7953491/ - person user961627; 31.10.2011

arrow_upward
3
arrow_downward

Вы уверены, что хотите снова использовать строку cols в значениях? Если нет, попробуйте это:

my %myhash;
$line1 = "col1 0.999";
$line2 = "col2 0.899";
$line3 = "col2 -0.52";
$line4 = "col2 1.52";

#insert into hash
@cols = split(" ", $line1);
push @{ $myhash{$cols[0]} }, $cols[1];
@cols = split(" ", $line2);
push @{ $myhash{$cols[0]} }, $cols[1];
@cols = split(" ", $line3);
push @{ $myhash{$cols[0]} }, $cols[1];
@cols = split(" ", $line4);
push @{ $myhash{$cols[0]} }, $cols[1];

foreach $k (sort {$a <=> $b} (keys %myhash)) {
   foreach $v(sort {$a <=> $b}(@{$myhash{$k}}))
   {
       print $k." : $v \n";
   }
}

В противном случае напишите функцию сортировки для второго foreach, чтобы игнорировать слово «cols» и использовать для сортировки только второе слово.

Редактировать:

Ну, я хотел уклониться от написания этого сам, но, поскольку вы спросили;) это объясняет суть:

foreach $k (sort {$a <=> $b} (keys %myhash)) {
   foreach $v(sort mysorter (@{$myhash{$k}})) #mysorter is a sub, defined further on
   {
       print $k." : $v \n";
   }
}

sub mysorter {
  my $c = $a;
  my $d = $b;

  $c =~ s/(.*) (.*)/\2/gi;
  $d =~ s/(.*) (.*)/\2/gi;

  return $c <=> $d;
}
person Konerak    schedule 27.10.2011
comment
Мне тоже нужна струнная часть. На самом деле это небольшой тест, в реальной программе мне нужно отсортировать целые строковые строки по одному столбцу в них, который оказывается числовым. Но спасибо - кажется, я знаю, что теперь делать. - person user961627; 27.10.2011
comment
Хорошо, на самом деле... у меня проблемы с этим. Каким будет правильный способ игнорировать слово cols во время сортировки? - person user961627; 27.10.2011
comment
@ user961627 - проще всего написать собственную функцию сортировки. Я отредактировал свой ответ, включив в него небольшой пример. Подробнее см. в сортировке perldoc. - person Konerak; 27.10.2011