Можно ли превосходить ods со значениями в каждой ячейке в SAS?

Вместо этого попробуйте создать выходную таблицу и экспортировать ее с помощью proc export. Например:

proc freq data=sashelp.cars noprint;
    tables make / out=freq_table;
run;

proc export 
    data = freq_table
    file = "/folder/myfile.xlsx"
    dbms = xlsx
    replace
    ;
run;

Если вы хотите, чтобы отчет выглядел индивидуально, вам нужно использовать proc report в выходной таблице вместо ods excel.

Похоже, вы создаете перекрестную таблицу в Proc FREQ.

Вы можете собирать данные ODS, которые используются для создания вывода, который вам не нравится, и манипулировать им таким образом, чтобы создавать вывод, который вам нравится.

ODS OUTPUT при транспонировании создает таблицу, которую можно просто распечатать и которая будет содержать нужные вам повторения.

Пример:

ods listing;
ods select none;
ods output CrossTabFreqs=ctf;
proc freq data=sashelp.baseball;
  table position * division;
  where position like '%B';
  title "FREQ";
run;
ods select all;

data have;
  set ctf;
  if substr(_type_,1,1) = '0' then position = 'Total';
  if substr(_type_,2,1) = '0' then division = 'Total';
run;

proc transpose data=have out=want;
  by position notsorted;
  var frequency percent rowpercent colpercent;
  id division;
run; 

ods excel file='ct.xlsx' style=plateau;

proc print data=want(where=(N(east,west,total)));
run;

ods _all_ close;

Примечание:

Если вы зафиксируете вывод перекрестной таблицы (согласно Stu), вам, вероятно, придется создать сводную таблицу в Excel, и даже это приведет к созданию объединенных ячеек, которые вам не нравятся. Сводная таблица в Excel имеет встроенный фильтрующий пользовательский интерфейс.