Сопоставление шаблонов по «ИЛИ» двух новых типов в haskell

Я не слишком глубоко копался в вашем коде, но из вашего описания кажется, что вас может заинтересовать идея фантомного типа.

newtype Dd x = ToDd (Cudd.Cudd.DdNode)
data B
data Z

Теперь вы можете различать Dd B и Dd Z, когда хотите, и работать полиморфно с Dd x, когда вам все равно.

В современном GHC Haskell, если вы хотите указать, что B и Z являются единственными тегами, вы можете использовать расширения DataKinds и KindSignatures и сделать это следующим образом:

newtype Dd (x :: DdTag) = ToDd (Cudd.Cudd.DdNode)
data DdTag = B | Z

В этом контексте вы будете иметь дело с Dd 'B и Dd 'Z, где одинарная кавычка (произносится как тик) продвигает конструктор данных на уровень типа.

Чтобы написать функцию, которая ведет себя по-разному в зависимости от того, какой тег имеет тип, вам понадобится класс.

class Zoop tag where
  zoop :: Dd tag -> Int
  zeep :: Char -> Dd tag
  zaaaaap :: Dd tag -> Dd tag

Теперь вы можете написать экземпляр Zoop для B (или 'B) и один для Z (или 'Z), чтобы пользователи могли использовать метод для любого из них. Помните, однако, что типы стираются при компиляции, поэтому вам понадобится ограничение Zoop a каждый раз, когда вы захотите применить эти методы с полиморфными тегами.

Я бы пошел с чем-то очень похожим на ваш первый подход, но вам нужно переименовать конструкторы, отличные от конструкторов нового типа:

data Dd = FromBdd Bdd | FromZdd Zdd

printDdInfo :: Dd -> IO()
printDdInfo (FromZdd (ToZdd dd)) = do
    putStrLn "Hello, zdd!"
    Cudd.Cudd.cuddPrintDdInfo manager dd
printDdInfo (FromBdd (ToBdd dd)) = do
    putStrLn "Hello, bdd!"
    Cudd.Cudd.cuddPrintDdInfo manager dd

В качестве альтернативы, зная, что все разные типы dd используют одно и то же базовое представление, вы также можете отказаться от хранения новых типов и вместо этого настроить Dd независимо:

data DdKind = IsBdd | IsZdd

data Dd = Dd { ddKind :: DdKind
             , ddImplementation :: Cudd.Cudd.DdNode }

printDdInfo :: Dd -> IO()
printDdInfo (Dd ddk dd) = do
    putStrLn $ case ddk of
       IsBdd -> "Hello, bdd!"
       IsZdd -> "Hello, zdd!"
    Cudd.Cudd.cuddPrintDdInfo manager dd