Что означают числовые аргументы для meta_predicate в SWI-Prolog?

Это формулировка, которую легко понять только тогда, когда знаешь, что она означает, и, вероятно, ее следует переделать.

:-meta_predicate maplist(2, ?, ?).

... просто означает, что аргумент на месте «2» будет использоваться в качестве ядра предиката, который будет вызываться. У нас нет специального обозначения для этого (большая ошибка ИМХО), поэтому мы напишем это стандартно как терм вроде f(foo,bar), или f(foo), или f. Что метапредикат maplist/3 будет делать с этим термином? Что ж, он синтаксически преобразует его и прибавит "2" дополнительных аргумента на его конец (и только на его конец, что приводит к неловкости): f(foo,bar, ARG1,ARG2), или f(foo, ARG1,ARG2), или f(ARG1,ARG2). Затем maplist/3 вызовет его.

Например, для вышеупомянутого maplist/3 возьмите этот предикат с двумя аргументами:

myprint(X,Y) 
   :- format("~w\n",[(X,Y)]).

Его можно использовать в вызове maplist/3 следующим образом, без указания каких-либо аргументов:

maplist(myprint,[0,1,2,3],[a,b,c,d]).

и два аргумента, по одному из каждого списка, будут прикреплены к термину myprint до того, как этот термин будет посвящен в рыцари, чтобы стать предикатом, и будет называться:

?- maplist(myprint,[0,1,2,3],[a,b,c,d]).
0,a
1,b
2,c
3,d
true.

Это позволяет пропускать «частично заполненные вызовы». maplist/2 добавит 1 аргумент в конец своего первого аргумента, поэтому можно сказать:

?- maplist(myprint("foo+"),[a,b,c,d]).
foo+,a
foo+,b
foo+,c
foo+,d
true.

Вышеприведенное можно использовать в сочетании с library(yall) Пауло Моуры, который оборачивает цель в анонимный предикат, раскрывающий аргументы. Тогда можно гибко переставлять вещи

?- maplist([X,Y]>>format("~w\n",[(X,Y)]),[0,1,2,3],[a,b,c,d]).
0,a
1,b
2,c
3,d
true.

?- maplist([Y,X]>>format("~w\n",[(X,Y)]),[0,1,2,3],[a,b,c,d]).
a,0
b,1
c,2
d,3
true.

На самом деле library(yall) обеспечивает правильный синтаксис для лямбда-выражений, который жестоко отсутствует в стандарте ISO, чтобы явно показать отсутствующие параметры.

Давным-давно можно было вообразить такие выражения:

?- maplist(λX.verify(3,X), [1,2,3,4,5]).

или остаться в ASCIIland, что-то вроде:

?- maplist(\X.verify(3,X), [1,2,3,4,5]).

но этого не произошло.

Директива meta-predicate указывает количество аргументов, добавляемых к предикату при вызове. Вот простой пример:

:- meta_predicate foo(2, +).

foo(Pred, X) :-
    call(Pred, X, Y),
    format('~q(~q,~q)~n', [Pred, X, Y]).

some_pred(X, Y) :-
    Y is X + 1.

что дает следующий результат. Как видите, директива meta_predicate приводит к добавлению модуля в аргумент Pred (в данном случае user):

?- foo(some_pred, 5).
user:some_pred(5,6)

Нечто похожее на «замыкание» в других языках можно легко сделать, также используя директиву meta_predicate. Например, мы могли бы иметь

:-meta_predicate foo2(1). 

foo2(Pred):-
    call(Pred, Y),
    format('~q=~q',[Pred,Y]).

и назовите это:

?-foo2(some_pred(5)).